Правила именования

В данном документе рассматриваются некоторые правила именования в коде Elixir, от регистра до знаков препинания.

Регистр

Разработчики Elixir должны использовать snake_case при определении переменных, имён функций, атрибутов модулей и т. д.:

some_map = %{this_is_a_key: "and a value"}
is_map(some_map)

Исключение составляют алиасы, часто используемые как имена модулей, которые должны быть написаны с заглавной буквы и в CamelCase, например OptionParser. В алиасах заглавные буквы сохраняются в аббревиатурах, например ExUnit.CaptureIO или Mix.SCM.

Атомы могут быть написаны как в :snake_case формате, так и в :CamelCase, хотя по соглашению следует использовать версию со snake_case во всем Elixir.

Как правило, имена файлов следуют snake_case соглашению модуля, который они определяют. Например, MyApp должен быть определён в файле my_app.ex. Однако это всего лишь соглашение. В конечном итоге можно использовать любое имя файла, так как они никак не влияют на скомпилированный код.

Подчеркивание (_foo)

Elixir использует подчеркивания в различных ситуациях.

Например, значение, которое не предназначено для использования, должно быть назначено _ или переменной, начинающейся с подчеркивания:

iex> {:ok, _contents} = File.read("README.md")

Имена функций также могут начинаться с подчеркивания. Такие функции никогда не импортируются по умолчанию:

iex> defmodule Example do
...>   def _wont_be_imported do
...>     :oops
...>   end
...> end

iex> import Example
iex> _wont_be_imported()
** (CompileError) iex:1: undefined function _wont_be_imported/0

Благодаря этому свойству, Elixir использует функции, начинающиеся с подчеркивания, для добавления метаданных времени компиляции к модулям. Такие функции чаще всего имеют __foo__ формат. Например, каждый модуль в Elixir имеет функцию __info__/1.

iex> String.__info__(:functions)
[at: 2, capitalize: 1, chunk: 2, ...]

Elixir также включает пять специальных форм, которые следуют формату с двойным подчеркиванием: __CALLER__/0, __DIR__/0, __ENV__/0 и __MODULE__/0 извлекают информацию о текущей среде во время компиляции, а __STACKTRACE__/0 — стек вызовов для текущего исключения.

Заключительный знак восклицания (foo!)

Заключительный знак восклицания указывает на функцию или макрос, где случаи неудачи вызывают исключение.

Многие функции представлены парами, например, File.read/1 и File.read!/1. File.read/1 вернёт кортеж успеха или неудачи, тогда как File.read!/1 вернёт простое значение или же вызовет исключение:

iex> File.read("file.txt")
{:ok, "file contents"}
iex> File.read("no_such_file.txt")
{:error, :enoent}

iex> File.read!("file.txt")
"file contents"
iex> File.read!("no_such_file.txt")
** (File.Error) could not read file no_such_file.txt: no such file or directory

Версия без ! предпочтительнее, когда вы хотите обработать разные результаты с помощью сопоставления шаблонов:

case File.read(file) do
  {:ok, body}      -> # do something with the `body`
  {:error, reason} -> # handle the error caused by `reason`
end

Однако, если вы ожидаете, что результат всегда будет успешным (например, если вы ожидаете, что файл всегда существует), вариант с восклицательным знаком может быть удобнее и выведет более информативное сообщение об ошибке (чем неудачное сопоставление шаблонов) в случае неудачи.

Другие примеры пар функций: Base.decode16/2 и Base.decode16!/2, File.cwd/0 и File.cwd!/0

Также есть некоторые функции без пар, без варианта без восклицательного знака. Знак восклицания всё ещё означает, что он вызовет исключение в случае неудачи. Примеры: Mix.Config.validate!/1, Protocol.assert_protocol!/1

В макрокоде восклицательный знак в Kernel.alias!/1 и Kernel.var!/2 означает, что гигиена макросов отключается.

Заключительный знак вопроса (foo?)

Функции, возвращающие булево значение, имеют имя с заключительным знаком вопроса.

Примеры: Keyword.keyword?/1, Mix.debug?/0, String.contains?/2

Однако функции, возвращающие булевы значения и допустимые в условиях, следуют другому соглашению, описанному ниже.

is_ префикс (is_foo)

Проверки типов и другие проверки на булевы значения, разрешённые в условиях, имеют is_ префикс.

Примеры: Integer.is_even/1, Kernel.is_list/1

Эти функции и макросы следуют соглашению Erlang с is_ префиксом, а не заключительным знаком вопроса, именно для указания, что они допустимы в условиях.

Обратите внимание, что проверки типов, которые не допустимы в условиях, не следуют этому соглашению. Примеры: Keyword.keyword?/1, Regex.regex?/1

Специальные имена

Некоторые имена имеют особое значение в Elixir. Мы подробнее рассмотрим эти случаи ниже.

length и size

Когда вы видите size в имени функции, это означает, что операция выполняется за константное время (также записывается как "O(1) время"), потому что размер хранится вместе со структурой данных.

Примеры: Kernel.map_size/1, Kernel.tuple_size/1

Когда вы видите length, операция выполняется за линейное время ("O(n) время"), потому что необходимо пройтись по всей структуре данных.

Примеры: Kernel.length/1, String.length/1

Другими словами, функции, использующие слово "size" в своём имени, будут выполняться за одинаковое время, независимо от того, мала или велика структура данных. Напротив, функции, содержащие "length" в своём имени, будут выполняться дольше по мере увеличения размера структуры данных.