Control.Category

class Category (cat :: k -> k -> Type) where Источник

Класс для категорий.

В математике, категория определяется как набор объектов и набор морфизмов между объектами, вместе с тождественным морфизмом id для каждого объекта и операцией (.) для композиции совместимых морфизмов.

Этот класс определен аналогичным образом. Множество морфизмов представлено параметром типа cat, который имеет вид k -> k -> Type для некоторой переменной вида k , представляющей множество объектов; большинство времени выбор k будет Type.

Примеры

instance Category (->) where
  id = \x -> x
  f . g = \x -> f (g x)

data Iso a b = Iso (a -> b) (b -> a)

instance Category Iso where
  id = Iso id id
  Iso f1 g1 . Iso f2 g2 = Iso (f1 . f2) (g2 . g1)

newtype f ~> g = NatTransform (forall x. f x -> g x)

instance Category (~>) where
  id = NatTransform id
  NatTransform f . NatTransform g = NatTransform (f . g)

type data Door = DoorOpen | DoorClosed

data Action (before :: Door) (after :: Door) where
  DoNothing :: Action door door
  OpenDoor :: Action start DoorClosed -> Action start DoorOpen
  CloseDoor :: Action start DoorOpen -> Action start DoorClosed

instance Category Action where
  id = DoNothing

  DoNothing . action = action
  OpenDoor rest . action = OpenDoor (rest . action)
  CloseDoor rest . action = CloseDoor (rest . action)

(<<<) :: forall {k} cat (b :: k) (c :: k) (a :: k). Category cat => cat b c -> cat a b -> cat a c infixr 1 Источник

Композиция справа налево. Это синоним для (.), но может быть полезно для того, чтобы сделать порядок композиции более очевидным.

(>>>) :: forall {k} cat (a :: k) (b :: k) (c :: k). Category cat => cat a b -> cat b c -> cat a c infixr 1 Источник

Композиция слева направо. Это полезно, если вы хотите написать морфизм как конвейер, идущий слева направо.

Примечание о конфликтах имен

Методы из Category конфликтуют с id и . из прелюдии; вам, вероятно, потребуется либо импортировать этот модуль с квалификатором, либо скрыть функции прелюдии:

import Prelude hiding (id, (.))