Методы

Напомним из Функций, что функция — это объект, который сопоставляет кортеж аргументов со значением возврата или выбрасывает исключение, если соответствующее значение вернуть невозможно. Часто для одной и той же концептуальной функции или операции реализация существенно отличается для различных типов аргументов: сложение двух целых чисел сильно отличается от сложения двух чисел с плавающей точкой, и оба отличаются от сложения целого числа с числом с плавающей точкой. Несмотря на различия в реализации, все эти операции попадают под общее понятие «сложение». Соответственно, в Julia эти поведения относятся к одному объекту: функция +.

Для удобства использования множества различных реализаций одного понятия функциям необязательно определять все сразу, но можно определить их по частям, предоставляя определённое поведение для определенных комбинаций типов и количества аргументов. Определение одного возможного поведения функции называется методом. До сих пор мы приводили примеры функций, определённых с одним методом, применимым ко всем типам аргументов. Однако сигнатуры определений методов могут быть аннотированы для указания типов аргументов помимо их количества, и может быть предоставлено более одного определения метода. Когда функция применяется к определенному кортежу аргументов, применяется наиболее специфичный метод, применимый к этим аргументам. Таким образом, общее поведение функции является набором поведений её различных определений методов. Если набор методов хорошо спроектирован, даже если реализации методов могут быть сильно различаться, внешнее поведение функции будет выглядеть бесшовным и согласованным.

Выбор метода, который следует выполнить при применении функции, называется диспетчеризацией. Julia позволяет процессу диспетчеризации выбрать, какой из методов функции следует вызвать, в зависимости от количества переданных аргументов и типов всех аргументов функции. Это отличается от традиционных объектно-ориентированных языков, где диспетчеризация происходит только на основе первого аргумента, который часто имеет специальный синтаксис аргумента и иногда подразумевается, а не явно записывается как аргумент. ^[1] Использование всех аргументов функции для выбора метода, который необходимо вызвать, а не только первого, известно как множественная диспетчеризация. Множественная диспетчеризация особенно полезна для математического кода, где мало смысла искусственно считать операции «принадлежащими» одному аргументу больше, чем любому другому: относится ли операция сложения в x + y к x больше, чем к y? Реализация математического оператора, как правило, зависит от типов всех его аргументов. Однако множественная диспетчеризация оказывается мощным и удобным подходом к структурированию и организации программ не только для математических операций.

Определение методов

До сих пор в наших примерах мы определяли только функции с одним методом, имеющим неограниченные типы аргументов. Такие функции ведут себя так же, как и в традиционных языках с динамической типизацией. Тем не менее, мы практически постоянно использовали множественную диспетчеризацию и методы, не осознавая этого: все стандартные функции и операторы Julia, такие как упомянутая функция +, имеют множество методов, определяющих их поведение для различных возможных комбинаций типов и количества аргументов.

При определении функции можно по желанию ограничить типы параметров, к которым она применима, используя оператор :: проверки типа, введённый в разделе Составные типы:

julia> f(x::Float64, y::Float64) = 2x + y
f (generic function with 1 method)

Это определение функции применяется только к вызовам, где x и y являются значениями типа Float64:

julia> f(2.0, 3.0)
7.0

При применении к другим типам аргументов произойдет MethodError:

julia> f(2.0, 3)
ERROR: MethodError: no method matching f(::Float64, ::Int64)
Closest candidates are:
  f(::Float64, !Matched::Float64) at none:1

julia> f(Float32(2.0), 3.0)
ERROR: MethodError: no method matching f(::Float32, ::Float64)
Closest candidates are:
  f(!Matched::Float64, ::Float64) at none:1

julia> f(2.0, "3.0")
ERROR: MethodError: no method matching f(::Float64, ::String)
Closest candidates are:
  f(::Float64, !Matched::Float64) at none:1

julia> f("2.0", "3.0")
ERROR: MethodError: no method matching f(::String, ::String)

Как видите, аргументы должны быть точно типа Float64. Другие числовые типы, такие как целые числа или 32-битные числа с плавающей точкой, не преобразуются автоматически в 64-битные числа с плавающей точкой, а строки не анализируются как числа. Поскольку Float64 — это конкретный тип, а конкретные типы не могут быть унаследованы в Julia, такое определение может быть применено только к аргументам, которые точно являются типа Float64. Однако часто бывает полезно писать более общие методы, где объявленные типы параметров являются абстрактными:

julia> f(x::Number, y::Number) = 2x - y
f (generic function with 2 methods)

julia> f(2.0, 3)
1.0

Это определение метода применяется к любой паре аргументов, которые являются экземплярами Number. Они не обязательно должны быть одного типа, если только каждый из них является числовым значением. Проблема обработки различных числовых типов делегируется арифметическим операциям в выражении 2x - y.

Чтобы определить функцию с несколькими методами, просто определите функцию несколько раз с разным количеством и типами аргументов. Первое определение метода создает объект функции, а последующие определения методов добавляют новые методы к существующему объекту функции. При применении функции будет выполнен наиболее специфичный метод, соответствующий количеству и типам аргументов. Таким образом, два определения методов выше, взятые вместе, определяют поведение f для всех пар экземпляров абстрактного типа Number — но с другим поведением, специфичным для пар значений Float64. Если один из аргументов является 64-битным числом с плавающей точкой, а другой нет, то метод f(Float64,Float64) не может быть вызван, и необходимо использовать более общий метод f(Number,Number):

julia> f(2.0, 3.0)
7.0

julia> f(2, 3.0)
1.0

julia> f(2.0, 3)
1.0

julia> f(2, 3)
1

Определение 2x + y используется только в первом случае, а определение 2x - y — во всех остальных. Автоматическое преобразование или приведение аргументов функций никогда не выполняется: все преобразования в Julia являются неволшебными и полностью явными. Преобразование и продвижение, однако, показывает, как разумное применение достаточно сложной технологии может быть незаметно подобно волшебству. ^[Clarke61]

Для значений, отличных от числовых, и для меньшего или большего количества аргументов функция f остаётся неопределенной, и её применение по-прежнему приведёт к MethodError:

julia> f("foo", 3)
ERROR: MethodError: no method matching f(::String, ::Int64)
Closest candidates are:
  f(!Matched::Number, ::Number) at none:1

julia> f()
ERROR: MethodError: no method matching f()
Closest candidates are:
  f(!Matched::Float64, !Matched::Float64) at none:1
  f(!Matched::Number, !Matched::Number) at none:1

Вы легко можете увидеть, какие методы существуют для функции, введя сам объект функции в интерактивной сессии:

julia> f
f (generic function with 2 methods)

Этот вывод показывает, что f — это объект функции с двумя методами. Чтобы узнать, каковы сигнатуры этих методов, используйте функцию methods:

julia> methods(f)
# 2 methods for generic function "f":
[1] f(x::Float64, y::Float64) in Main at none:1
[2] f(x::Number, y::Number) in Main at none:1

что показывает, что у f два метода: один, принимающий два Float64 аргумента, и один, принимающий аргументы типа Number. Он также указывает файл и строку, где были определены методы: поскольку эти методы были определены в REPL, мы получаем видимую строку none:1.

При отсутствии объявления типа с ::, тип параметра метода по умолчанию — Any, что означает, что он неограничен, поскольку все значения в Julia являются экземплярами абстрактного типа Any. Таким образом, мы можем определить универсальный метод для f следующим образом:

julia> f(x,y) = println("Whoa there, Nelly.")
f (generic function with 3 methods)

julia> methods(f)
# 3 methods for generic function "f":
[1] f(x::Float64, y::Float64) in Main at none:1
[2] f(x::Number, y::Number) in Main at none:1
[3] f(x, y) in Main at none:1

julia> f("foo", 1)
Whoa there, Nelly.

Этот универсальный метод менее специфичен, чем любое другое возможное определение метода для пары значений параметров, поэтому он будет вызван только для пар аргументов, к которым не применима ни одна другая методика.

Обратите внимание, что в сигнатуре третьего метода тип аргументов x и y не указан. Это сокращённый способ выражения f(x::Any, y::Any).

Хотя это кажется простым понятием, множественная диспетчеризация по типам значений, пожалуй, является самой мощной и центральной особенностью языка Julia. Основные операции, как правило, имеют десятки методов:

julia> methods(+)
# 180 methods for generic function "+":
[1] +(x::Bool, z::Complex{Bool}) in Base at complex.jl:227
[2] +(x::Bool, y::Bool) in Base at bool.jl:89
[3] +(x::Bool) in Base at bool.jl:86
[4] +(x::Bool, y::T) where T<:AbstractFloat in Base at bool.jl:96
[5] +(x::Bool, z::Complex) in Base at complex.jl:234
[6] +(a::Float16, b::Float16) in Base at float.jl:373
[7] +(x::Float32, y::Float32) in Base at float.jl:375
[8] +(x::Float64, y::Float64) in Base at float.jl:376
[9] +(z::Complex{Bool}, x::Bool) in Base at complex.jl:228
[10] +(z::Complex{Bool}, x::Real) in Base at complex.jl:242
[11] +(x::Char, y::Integer) in Base at char.jl:40
[12] +(c::BigInt, x::BigFloat) in Base.MPFR at mpfr.jl:307
[13] +(a::BigInt, b::BigInt, c::BigInt, d::BigInt, e::BigInt) in Base.GMP at gmp.jl:392
[14] +(a::BigInt, b::BigInt, c::BigInt, d::BigInt) in Base.GMP at gmp.jl:391
[15] +(a::BigInt, b::BigInt, c::BigInt) in Base.GMP at gmp.jl:390
[16] +(x::BigInt, y::BigInt) in Base.GMP at gmp.jl:361
[17] +(x::BigInt, c::Union{UInt16, UInt32, UInt64, UInt8}) in Base.GMP at gmp.jl:398
...
[180] +(a, b, c, xs...) in Base at operators.jl:424

Множественная диспетчеризация вместе с гибкой параметрической системой типов предоставляют Julia возможность абстрактно выражать алгоритмы высокого уровня, отвязанные от деталей реализации, но при этом генерировать эффективный специализированный код для обработки каждого случая во время выполнения.

Неясности методов

Можно определить набор методов функции таким образом, что для некоторых комбинаций аргументов не будет уникального наиболее специфичного метода:

julia> g(x::Float64, y) = 2x + y
g (generic function with 1 method)

julia> g(x, y::Float64) = x + 2y
g (generic function with 2 methods)

julia> g(2.0, 3)
7.0

julia> g(2, 3.0)
8.0

julia> g(2.0, 3.0)
ERROR: MethodError: g(::Float64, ::Float64) is ambiguous. Candidates:
  g(x::Float64, y) in Main at none:1
  g(x, y::Float64) in Main at none:1
Possible fix, define
  g(::Float64, ::Float64)

Здесь вызов g(2.0, 3.0) может быть обработан либо методом g(Float64, Any), либо методом g(Any, Float64), и ни один из них не является более специфичным, чем другой. В таких случаях Julia поднимает MethodError, а не произвольно выбирает метод. Вы можете избежать неоднозначности метода, указав соответствующий метод для случая пересечения:

julia> g(x::Float64, y::Float64) = 2x + 2y
g (generic function with 3 methods)

julia> g(2.0, 3)
7.0

julia> g(2, 3.0)
8.0

julia> g(2.0, 3.0)
10.0

Рекомендуется определить метод устранения неоднозначности первым, так как в противном случае неоднозначность существует, по крайней мере временно, до определения более специфичного метода.

В более сложных случаях разрешение неоднозначностей методов включает определённый элемент проектирования; эта тема рассматривается далее ниже.

Параметрические методы

Определения методов могут необязательно иметь параметры типа, квалифицирующие сигнатуру:

julia> same_type(x::T, y::T) where {T} = true
same_type (generic function with 1 method)

julia> same_type(x,y) = false
same_type (generic function with 2 methods)

Первый метод применяется, когда оба аргумента имеют один и тот же конкретный тип, независимо от того, какой это тип, в то время как второй метод действует как универсальный, охватывающий все остальные случаи. Таким образом, в целом это определяет булеву функцию, которая проверяет, являются ли её два аргумента одного типа:

julia> same_type(1, 2)
true

julia> same_type(1, 2.0)
false

julia> same_type(1.0, 2.0)
true

julia> same_type("foo", 2.0)
false

julia> same_type("foo", "bar")
true

julia> same_type(Int32(1), Int64(2))
false

Такие определения соответствуют методам, сигнатуры типов которых являются UnionAll типами (см. Типы UnionAll).

Такой способ определения поведения функции с помощью диспетчеризации довольно распространен — даже идиоматичен — в Julia. Параметры типа метода не ограничены использованием в качестве типов аргументов: они могут быть использованы в любом месте, где в сигнатуре функции или теле функции требуется значение. Вот пример, где параметр типа метода T используется в качестве параметра типа параметрического типа Vector{T} в сигнатуре метода:

julia> myappend(v::Vector{T}, x::T) where {T} = [v..., x]
myappend (generic function with 1 method)

julia> myappend([1,2,3],4)
4-element Vector{Int64}:
 1
 2
 3
 4

julia> myappend([1,2,3],2.5)
ERROR: MethodError: no method matching myappend(::Vector{Int64}, ::Float64)
Closest candidates are:
  myappend(::Vector{T}, !Matched::T) where T at none:1
Stacktrace:
[...]

julia> myappend([1.0,2.0,3.0],4.0)
4-element Vector{Float64}:
 1.0
 2.0
 3.0
 4.0

julia> myappend([1.0,2.0,3.0],4)
ERROR: MethodError: no method matching myappend(::Vector{Float64}, ::Int64)
Closest candidates are:
  myappend(::Vector{T}, !Matched::T) where T at none:1
Stacktrace:
[...]

Как вы можете видеть, тип добавляемого элемента должен совпадать с типом элементов вектора, к которому он добавляется, иначе возникает MethodError. В следующем примере параметр типа метода T используется в качестве возвращаемого значения:

julia> mytypeof(x::T) where {T} = T
mytypeof (generic function with 1 method)

julia> mytypeof(1)
Int64

julia> mytypeof(1.0)
Float64

Так же, как вы можете установить ограничения на подтипы для параметров типа в объявлениях типов (см. Параметрические типы), вы также можете ограничить параметры типа методов:

julia> same_type_numeric(x::T, y::T) where {T<:Number} = true
same_type_numeric (generic function with 1 method)

julia> same_type_numeric(x::Number, y::Number) = false
same_type_numeric (generic function with 2 methods)

julia> same_type_numeric(1, 2)
true

julia> same_type_numeric(1, 2.0)
false

julia> same_type_numeric(1.0, 2.0)
true

julia> same_type_numeric("foo", 2.0)
ERROR: MethodError: no method matching same_type_numeric(::String, ::Float64)
Closest candidates are:
  same_type_numeric(!Matched::T, ::T) where T<:Number at none:1
  same_type_numeric(!Matched::Number, ::Number) at none:1

julia> same_type_numeric("foo", "bar")
ERROR: MethodError: no method matching same_type_numeric(::String, ::String)

julia> same_type_numeric(Int32(1), Int64(2))
false

Функция same_type_numeric ведет себя очень похоже на функцию same_type , определенную выше, но определена только для пар чисел.

Параметрические методы позволяют использовать ту же синтаксическую конструкцию, что и выражения where для записи типов (см. Типы UnionAll). Если есть только один параметр, можно опустить окружающие фигурные скобки (в where {T}), но часто предпочтительнее использовать их для большей ясности. Несколько параметров можно разделить запятыми, например, where {T, S<:Real}, или использовать вложенные where, например, where S<:Real where T.

Переопределение методов

При переопределении метода или добавлении новых методов важно понимать, что эти изменения не вступают в силу немедленно. Это ключевой момент для способности Julia статически выводить и компилировать код для высокой скорости, без обычных хитростей JIT и накладных расходов. Действительно, любое новое определение метода не будет видно текущей среде выполнения, включая задачи и потоки (и ранее определенные @generated функции). Давайте начнем с примера, чтобы понять, что это значит:

julia> function tryeval()
           @eval newfun() = 1
           newfun()
       end
tryeval (generic function with 1 method)

julia> tryeval()
ERROR: MethodError: no method matching newfun()
The applicable method may be too new: running in world age xxxx1, while current world is xxxx2.
Closest candidates are:
  newfun() at none:1 (method too new to be called from this world context.)
 in tryeval() at none:1
 ...

julia> newfun()
1

В этом примере обратите внимание, что новое определение для newfun было создано, но не может быть немедленно вызвано. Новая глобальная переменная немедленно видна функции tryeval, поэтому вы могли бы написать return newfun (без скобок). Но ни вы, ни ваши вызывающие функции, ни функции, которые они вызывают, и т. д. не могут вызвать это новое определение метода!

Но есть исключение: будущие вызовы к newfun из REPL работают как ожидается, имея возможность как увидеть, так и вызвать новое определение newfun.

Однако будущие вызовы к tryeval будут продолжать видеть определение newfun таким, как оно было в предыдущей строке в REPL, и, следовательно, до вызова tryeval.

Вы можете попробовать это самостоятельно, чтобы увидеть, как это работает.

Реализация этого поведения — это «счетчик возраста мира». Это монотонно возрастающее значение отслеживает каждую операцию определения метода. Это позволяет описать «множество определений методов, видимых данной среде выполнения», как одно число или «возраст мира». Это также позволяет сравнивать методы, доступные в двух мирах, просто сравнивая их порядковое значение. В приведенном выше примере мы видим, что «текущий мир» (в котором существует метод newfun), на один больше, чем «мир выполнения» локальной задачи, который был установлен при запуске выполнения tryeval.

Иногда необходимо обойти это (например, если вы реализуете вышеупомянутый REPL). К счастью, есть простое решение: вызовите функцию, используя Base.invokelatest:

julia> function tryeval2()
           @eval newfun2() = 2
           Base.invokelatest(newfun2)
       end
tryeval2 (generic function with 1 method)

julia> tryeval2()
2

Наконец, давайте рассмотрим несколько более сложных примеров, где это правило вступает в силу. Определите функцию f(x), которая изначально имеет один метод:

julia> f(x) = "original definition"
f (generic function with 1 method)

Запустите другие операции, которые используют f(x):

julia> g(x) = f(x)
g (generic function with 1 method)

julia> t = @async f(wait()); yield();

Теперь добавим новые методы к f(x):

julia> f(x::Int) = "definition for Int"
f (generic function with 2 methods)

julia> f(x::Type{Int}) = "definition for Type{Int}"
f (generic function with 3 methods)

Сравните, как эти результаты отличаются:

julia> f(1)
"definition for Int"

julia> g(1)
"definition for Int"

julia> fetch(schedule(t, 1))
"original definition"

julia> t = @async f(wait()); yield();

julia> fetch(schedule(t, 1))
"definition for Int"

Шаблоны проектирования с параметрическими методами

Хотя сложная логика диспетчеризации не требуется для производительности или удобства использования, иногда это может быть лучший способ выразить некоторый алгоритм. Вот несколько распространенных шаблонов проектирования, которые иногда возникают при использовании диспетчеризации таким образом.

Извлечение параметра типа из супертипа

Вот правильный шаблон кода для возврата типа элемента T любого произвольного подтипа AbstractArray , имеющего хорошо определенный тип элементов:

abstract type AbstractArray{T, N} end
eltype(::Type{<:AbstractArray{T}}) where {T} = T

используя так называемую треугольную диспетчеризацию. Обратите внимание, что типы UnionAll , например, eltype(AbstractArray{T} where T <: Integer), не соответствуют вышеуказанному методу. Реализация eltype в Base добавляет метод по умолчанию к Any для таких случаев.

Одной из распространенных ошибок является попытка получить тип элемента с помощью интроспекции:

eltype_wrong(::Type{A}) where {A<:AbstractArray} = A.parameters[1]

Однако несложно создать случаи, когда это не сработает:

struct BitVector <: AbstractArray{Bool, 1}; end

Здесь мы создали тип BitVector , который не имеет параметров, но где тип элемента всё ещё полностью определен, с T равным Bool!

Еще одна ошибка — попытка пройти вверх по иерархии типов с помощью supertype:

eltype_wrong(::Type{AbstractArray{T}}) where {T} = T
eltype_wrong(::Type{AbstractArray{T, N}}) where {T, N} = T
eltype_wrong(::Type{A}) where {A<:AbstractArray} = eltype_wrong(supertype(A))

Хотя это работает для объявленных типов, это не работает для типов без супертипов:

julia> eltype_wrong(Union{AbstractArray{Int}, AbstractArray{Float64}})
ERROR: MethodError: no method matching supertype(::Type{Union{AbstractArray{Float64,N} where N, AbstractArray{Int64,N} where N}})
Closest candidates are:
  supertype(::DataType) at operators.jl:43
  supertype(::UnionAll) at operators.jl:48

Создание похожих типов с другим параметром типа

При создании обобщенного кода часто возникает необходимость создания подобного объекта с внесёнными изменениями в структуру типа, что также требует изменения параметров типа. Например, у вас может быть некий абстрактный массив с произвольным типом элементов, и вы хотите написать вычисление на нём со специфическим типом элементов. Мы должны реализовать метод для каждого подтипа AbstractArray{T} , описывающий, как выполнить преобразование этого типа. Нет общего преобразования одного подтипа в другой подтип с другим параметром. (Быстрый обзор: вы видите почему?)

Подтипы AbstractArray обычно реализуют два метода для достижения этого: метод преобразования входного массива в подтип определенного AbstractArray{T, N} абстрактного типа; и метод создания нового неинициализированного массива с определенным типом элементов. Примеры реализации этих методов можно найти в Julia Base. Вот базовый пример их использования, гарантирующий, что input и output являются одного типа:

input = convert(AbstractArray{Eltype}, input)
output = similar(input, Eltype)

В качестве расширения этого, в случаях, когда алгоритм требует копии входного массива, convert недостаточно, так как возвращаемое значение может ссылаться на исходный вход. Объединение similar (для создания выходного массива) и copyto! (для заполнения его входными данными) — обобщённый способ выражения требования к мутабельной копии входного аргумента:

copy_with_eltype(input, Eltype) = copyto!(similar(input, Eltype), input)

Итерационная диспетчеризация

Для диспетчеризации списка параметрических аргументов многоуровневого типа часто лучше всего разделить каждый уровень диспетчеризации на отдельные функции. Это может звучать похожим на подход к одноуровневой диспетчеризации, но, как мы увидим ниже, он всё ещё более гибкий.

Например, попытка диспетчеризации по типу элементов массива часто столкнётся с неоднозначными ситуациями. Вместо этого, код обычно сначала диспетчеризирует по типу контейнера, а затем рекурсивно переходит к более конкретному методу, основанному на eltype. В большинстве случаев алгоритмы удобно подходят для такого иерархического подхода, а в других случаях этот подход нужно решить вручную. Такая ветвящаяся диспетчеризация наблюдается, например, в логике суммирования двух матриц:

# First dispatch selects the map algorithm for element-wise summation.
+(a::Matrix, b::Matrix) = map(+, a, b)
# Then dispatch handles each element and selects the appropriate
# common element type for the computation.
+(a, b) = +(promote(a, b)...)
# Once the elements have the same type, they can be added.
# For example, via primitive operations exposed by the processor.
+(a::Float64, b::Float64) = Core.add(a, b)

Диспетчеризация на основе признаков

Естественным расширением итерационной диспетчеризации выше является добавление уровня к выбору метода, который позволяет выполнять диспетчеризацию по наборам типов, независимым от наборов, определённых иерархией типов. Мы могли бы создать такой набор, написав Union типов, но тогда этот набор не был бы расширяемым, так как типы Union не могут быть изменены после создания. Однако такой расширяемый набор можно запрограммировать с помощью шаблона проектирования, часто называемого «Священным признаком».

Этот шаблон реализуется путём определения обобщённой функции, которая вычисляет различное одиночное значение (или тип) для каждого набора признаков, к которому могут принадлежать аргументы функции. Если эта функция чистая, это не повлияет на производительность по сравнению с обычной диспетчеризацией.

Пример в предыдущем разделе пропустил детали реализации map и promote, которые оба работают с этими признаками. При итерировании по матрице, например, в реализации map, важным вопросом является порядок обхода данных. Когда подтипы AbstractArray реализуют признак Base.IndexStyle, другие функции, такие как map , могут диспетчеризировать по этой информации, чтобы выбрать лучший алгоритм (см. Интерфейс абстрактного массива). Это означает, что каждому подтипу не нужно реализовывать собственную версию map, так как общие определения + классы признаков позволят системе выбрать самую быструю версию. Вот примитивная реализация map , иллюстрирующая диспетчеризацию на основе признаков:

map(f, a::AbstractArray, b::AbstractArray) = map(Base.IndexStyle(a, b), f, a, b)
# generic implementation:
map(::Base.IndexCartesian, f, a::AbstractArray, b::AbstractArray) = ...
# linear-indexing implementation (faster)
map(::Base.IndexLinear, f, a::AbstractArray, b::AbstractArray) = ...

Этот подход на основе признаков также присутствует в механизме promote, используемом скалярным типом +. Он использует promote_type, который возвращает оптимальный общий тип для вычисления операции, учитывая два типа операндов. Это позволяет уменьшить проблему реализации каждой функции для каждой пары возможных аргументов типа до гораздо меньшей проблемы реализации операции преобразования из каждого типа в общий тип, плюс таблицы предпочтительных правил повышения по парам.

Вычисление типа выходных данных

Обсуждение повышения типа на основе свойств переходит к следующему шаблону проектирования: вычисление типа элемента выходных данных для матричной операции.

Для реализации примитивных операций, таких как сложение, мы используем функцию promote_type для вычисления желаемого типа выходных данных. (Как и прежде, мы видели это в работе в вызове promote в вызове +).

Для более сложных функций над матрицами может потребоваться вычислить ожидаемый тип возвращаемого значения для более сложной последовательности операций. Это часто выполняется следующими шагами:

1. Напишите небольшую функцию op, которая выражает набор операций, выполняемых ядром алгоритма.
2. Вычислите тип элемента R результирующей матрицы как promote_op(op, argument_types...), где argument_types вычисляется из eltype для каждого входного массива.
3. Создайте выходную матрицу как similar(R, dims), где dims — желаемые размеры выходного массива.

Для более конкретного примера псевдокод обобщенного умножения квадратных матриц может выглядеть следующим образом:

function matmul(a::AbstractMatrix, b::AbstractMatrix)
    op = (ai, bi) -> ai * bi + ai * bi

    ## this is insufficient because it assumes `one(eltype(a))` is constructable:
    # R = typeof(op(one(eltype(a)), one(eltype(b))))

    ## this fails because it assumes `a[1]` exists and is representative of all elements of the array
    # R = typeof(op(a[1], b[1]))

    ## this is incorrect because it assumes that `+` calls `promote_type`
    ## but this is not true for some types, such as Bool:
    # R = promote_type(ai, bi)

    # this is wrong, since depending on the return value
    # of type-inference is very brittle (as well as not being optimizable):
    # R = Base.return_types(op, (eltype(a), eltype(b)))

    ## but, finally, this works:
    R = promote_op(op, eltype(a), eltype(b))
    ## although sometimes it may give a larger type than desired
    ## it will always give a correct type

    output = similar(b, R, (size(a, 1), size(b, 2)))
    if size(a, 2) > 0
        for j in 1:size(b, 2)
            for i in 1:size(a, 1)
                ## here we don't use `ab = zero(R)`,
                ## since `R` might be `Any` and `zero(Any)` is not defined
                ## we also must declare `ab::R` to make the type of `ab` constant in the loop,
                ## since it is possible that typeof(a * b) != typeof(a * b + a * b) == R
                ab::R = a[i, 1] * b[1, j]
                for k in 2:size(a, 2)
                    ab += a[i, k] * b[k, j]
                end
                output[i, j] = ab
            end
        end
    end
    return output
end

Разделение логики преобразования и ядра

Один из способов значительно сократить время компиляции и сложность тестирования — изолировать логику преобразования к нужному типу и вычисления. Это позволяет компилятору специализировать и встраивать логику преобразования независимо от остальной части тела более крупного ядра.

Это распространенный шаблон, используемый при преобразовании из более широкого класса типов в конкретный тип аргумента, который фактически поддерживается алгоритмом:

complexfunction(arg::Int) = ...
complexfunction(arg::Any) = complexfunction(convert(Int, arg))

matmul(a::T, b::T) = ...
matmul(a, b) = matmul(promote(a, b)...)

Методы Varargs с параметрическими ограничениями

Параметры функции также могут использоваться для ограничения количества аргументов, которые могут быть переданы функции «varargs» (Функции Varargs). Обозначение Vararg{T,N} используется для обозначения такого ограничения. Например:

julia> bar(a,b,x::Vararg{Any,2}) = (a,b,x)
bar (generic function with 1 method)

julia> bar(1,2,3)
ERROR: MethodError: no method matching bar(::Int64, ::Int64, ::Int64)
Closest candidates are:
  bar(::Any, ::Any, ::Any, !Matched::Any) at none:1

julia> bar(1,2,3,4)
(1, 2, (3, 4))

julia> bar(1,2,3,4,5)
ERROR: MethodError: no method matching bar(::Int64, ::Int64, ::Int64, ::Int64, ::Int64)
Closest candidates are:
  bar(::Any, ::Any, ::Any, ::Any) at none:1

Более полезно, можно ограничить методы varargs параметром. Например:

function getindex(A::AbstractArray{T,N}, indices::Vararg{Number,N}) where {T,N}

будет вызван только тогда, когда количество indices совпадает с размерностью массива.

Если необходимо ограничить только тип переданных аргументов, Vararg{T} можно эквивалентно записать как T.... Например, f(x::Int...) = x является сокращением для f(x::Vararg{Int}) = x.

Примечание об аргументах по умолчанию и ключевых аргументах

Как кратко упоминалось в Функции, аргументы по умолчанию реализуются как синтаксис для определения нескольких методов. Например, это определение:

f(a=1,b=2) = a+2b

преобразуется в следующие три метода:

f(a,b) = a+2b
f(a) = f(a,2)
f() = f(1,2)

Это означает, что вызов f() эквивалентен вызову f(1,2) В этом случае результат — 5, так как f(1,2) вызывает первый метод f выше. Однако это не всегда так. Если вы определите четвертый метод, более специализированный для целых чисел:

f(a::Int,b::Int) = a-2b

тогда результат как f() , так и f(1,2) равен -3. Другими словами, аргументы по умолчанию привязаны к функции, а не к какому-либо конкретному методу этой функции. От типов аргументов по умолчанию зависит, какой метод будет вызван. Если аргументы по умолчанию определены через глобальную переменную, тип аргумента по умолчанию может даже измениться во время выполнения.

Ключевые аргументы ведут себя совершенно иначе, чем обычные позиционные аргументы. В частности, они не участвуют в диспетчеризации методов. Методы диспетчеризуются только на основе позиционных аргументов, а ключевые аргументы обрабатываются после определения соответствующего метода.

Объекты, подобные функциям

Методы связаны с типами, поэтому любой произвольный объект Julia можно сделать «вызываемым», добавив методы к его типу. (Такие «вызываемые» объекты иногда называют «функторами»)

Например, вы можете определить тип, хранящий коэффициенты многочлена, но ведущий себя как функция, вычисляющая многочлен:

julia> struct Polynomial{R}
           coeffs::Vector{R}
       end

julia> function (p::Polynomial)(x)
           v = p.coeffs[end]
           for i = (length(p.coeffs)-1):-1:1
               v = v*x + p.coeffs[i]
           end
           return v
       end

julia> (p::Polynomial)() = p(5)

Обратите внимание, что функция задаётся типом, а не именем. Как и для обычных функций, существует краткая форма синтаксиса. В теле функции p будет ссылаться на объект, который был вызван. Объект, подобный функции, может быть использован следующим образом:

julia> p = Polynomial([1,10,100])
Polynomial{Int64}([1, 10, 100])

julia> p(3)
931

julia> p()
2551

Этот механизм также является ключевым для работы конструкторов типов и замыканий (внутренних функций, которые ссылаются на свою окружающую среду) в Julia.

Пустые обобщенные функции

Иногда бывает полезно ввести обобщенную функцию, ещё не добавив методы. Это можно использовать для отделения определений интерфейса от реализаций. Это также может быть сделано в целях документации или удобочитаемости кода. Синтаксис для этого — пустой блок function без кортежа аргументов:

function emptyfunc end

Проектирование методов и избежание неоднозначностей

Полиморфизм методов Julia — одно из самых мощных его свойств, но использование этой мощности может создать проблемы при проектировании. В частности, в более сложных иерархиях методов неоднозначности нередко возникают.

Выше отмечалось, что неоднозначности, такие как

f(x, y::Int) = 1
f(x::Int, y) = 2

можно разрешить, определив метод

f(x::Int, y::Int) = 3

Это часто правильная стратегия; однако в некоторых случаях следование этому совету бездумно может оказаться контрпродуктивным. В частности, чем больше методов у обобщенной функции, тем больше возможностей для неоднозначностей. Когда иерархии методов становятся сложнее этого простого примера, стоит подумать о других стратегиях.

Ниже мы обсудим конкретные проблемы и некоторые альтернативные способы решения таких проблем.

Аргументы Tuple и NTuple

Tuple (и NTuple) аргументы представляют собой особые проблемы. Например,

f(x::NTuple{N,Int}) where {N} = 1
f(x::NTuple{N,Float64}) where {N} = 2

являются неоднозначными из-за возможности N == 0: нет элементов, определяющих, какой вариант Int или Float64 должен быть вызван. Для разрешения неоднозначности один из подходов заключается в определении метода для пустого кортежа:

f(x::Tuple{}) = 3

В качестве альтернативы для всех методов, кроме одного, можно потребовать, чтобы в кортеже был хотя бы один элемент:

f(x::NTuple{N,Int}) where {N} = 1           # this is the fallback
f(x::Tuple{Float64, Vararg{Float64}}) = 2   # this requires at least one Float64

Ортогонализируйте свой дизайн

Когда вы можете быть склонны к диспетчеризации по двум или более аргументам, подумайте, может ли функция-обёртка упростить конструкцию. Например, вместо написания нескольких вариантов:

f(x::A, y::A) = ...
f(x::A, y::B) = ...
f(x::B, y::A) = ...
f(x::B, y::B) = ...

можно рассмотреть определение

f(x::A, y::A) = ...
f(x, y) = f(g(x), g(y))

где g преобразует аргумент в тип A. Это очень специфический пример более общего принципа ортогонального проектирования, при котором отдельные концепции назначаются отдельным методам. Здесь g , скорее всего, потребует fallback-определения

g(x::A) = x

Связанная стратегия использует promote , чтобы привести x и y к общему типу:

f(x::T, y::T) where {T} = ...
f(x, y) = f(promote(x, y)...)

Одна из опасностей этого дизайна — возможность того, что если нет подходящего метода преобразования x и y в один тип, второй метод будет рекурсивно вызывать себя бесконечно и вызовет переполнение стека.

Диспетчеризация по одному аргументу за раз

Если вам нужно выполнить диспетчеризацию по нескольким аргументам, и существует много обращений к методам с множеством комбинаций, чтобы сделать практичным определение всех возможных вариантов, то рассмотрите «каскад имён», в котором (например) вы выполняете диспетчеризацию по первому аргументу, а затем вызываете внутренний метод:

f(x::A, y) = _fA(x, y)
f(x::B, y) = _fB(x, y)

Затем внутренние методы _fA и _fB могут выполнять диспетчеризацию по y , не беспокоясь о неоднозначностях друг с другом по отношению к x.

Обратите внимание, что эта стратегия имеет по крайней мере один существенный недостаток: во многих случаях пользователи не могут далее настраивать поведение f , определяя дальнейшую специализацию вашей экспортируемой функции f. Вместо этого они должны определить специализации для ваших внутренних методов _fA и _fB, и это размывает границы между экспортируемыми и внутренними методами.

Абстрактные контейнеры и типы элементов

По возможности старайтесь избегать определения методов, которые выполняют диспетчеризацию по конкретным типам элементов абстрактных контейнеров. Например,

-(A::AbstractArray{T}, b::Date) where {T<:Date}

порождает неоднозначности для тех, кто определяет метод

-(A::MyArrayType{T}, b::T) where {T}

Лучший подход — избегать определения любого из этих методов: вместо этого полагайтесь на обобщённый метод -(A::AbstractArray, b) и убедитесь, что этот метод реализован с помощью обобщенных вызовов (например, similar и - ), которые выполняют правильные действия для каждого типа контейнера и типа элемента отдельно. Это просто более сложный вариант совета об ортогонализации ваших методов.

Когда этот подход невозможен, возможно, стоит начать обсуждение с другими разработчиками о разрешении неоднозначности; просто потому, что один метод был определён первым, не обязательно означает, что он не может быть изменён или удалён. В крайнем случае, один разработчик может определить метод «пластырь»

-(A::MyArrayType{T}, b::Date) where {T<:Date} = ...

который решает неоднозначность грубой силой.

Сложные «каскады» методов с аргументами по умолчанию

Если вы определяете метод «cascade», который предоставляет значения по умолчанию, будьте осторожны, удаляя аргументы, соответствующие потенциальным значениям по умолчанию. Например, предположим, что вы пишете алгоритм цифрового фильтрации, и у вас есть метод, который обрабатывает края сигнала, применяя заполнение:

function myfilter(A, kernel, ::Replicate)
    Apadded = replicate_edges(A, size(kernel))
    myfilter(Apadded, kernel)  # now perform the "real" computation
end

Это вызовет конфликт с методом, который предоставляет значение заполнения по умолчанию:

myfilter(A, kernel) = myfilter(A, kernel, Replicate()) # replicate the edge by default

Вместе эти два метода генерируют бесконечную рекурсию, с A постоянно увеличивающейся.

Лучшим дизайном будет определение вашей иерархии вызовов следующим образом:

struct NoPad end  # indicate that no padding is desired, or that it's already applied

myfilter(A, kernel) = myfilter(A, kernel, Replicate())  # default boundary conditions

function myfilter(A, kernel, ::Replicate)
    Apadded = replicate_edges(A, size(kernel))
    myfilter(Apadded, kernel, NoPad())  # indicate the new boundary conditions
end

# other padding methods go here

function myfilter(A, kernel, ::NoPad)
    # Here's the "real" implementation of the core computation
end

NoPad указывается в той же позиции аргумента, что и любой другой тип заполнения, поэтому он поддерживает хорошо организованную иерархию диспетчеризации с меньшей вероятностью возникновения неоднозначностей. Кроме того, он расширяет интерфейс «публичный» myfilter: пользователь, который хочет явно контролировать заполнение, может вызвать вариант NoPad напрямую.