Модуль Queue

module Queue: sig .. end

Очереди с обслуживанием в порядке поступления (FIFO).

Этот модуль реализует очереди (FIFO) с изменением на месте. См. раздел с примерами ниже.

Предупреждение unsynchronized_access. Несинхронизированный доступ к очередям является ошибкой программирования.

Несинхронизированный доступ

Несинхронизированный доступ к очереди может привести к её некорректному состоянию. Поэтому конкурентный доступ к очередям необходимо синхронизировать (например, с помощью Mutex.t).

type !'a t

Тип очередей, содержащих элементы типа 'a.

exception Empty

Вызывается, когда к пустой очереди применяется Queue.take или Queue.peek.

val create : unit -> 'a t

Возвращает новую, изначально пустую очередь.

val add : 'a -> 'a t -> unit

add x q добавляет элемент x в конец очереди q.

val push : 'a -> 'a t -> unit

push — синоним add.

val take : 'a t -> 'a

take q удаляет и возвращает первый элемент очереди q или вызывает исключение Queue.Empty, если очередь пуста.

val take_opt : 'a t -> 'a option

take_opt q удаляет и возвращает первый элемент очереди q или возвращает None, если очередь пуста.

Начиная с версии 4.08

val pop : 'a t -> 'a

pop — синоним take.

val peek : 'a t -> 'a

peek q возвращает первый элемент очереди q, не удаляя его из очереди, или вызывает исключение Queue.Empty, если очередь пуста.

val peek_opt : 'a t -> 'a option

peek_opt q возвращает первый элемент очереди q, не удаляя его из очереди, или возвращает None, если очередь пуста.

Начиная с версии 4.08

val top : 'a t -> 'a

top — синоним peek.

val drop : 'a t -> unit

drop q удаляет первый элемент очереди q или вызывает исключение Queue.Empty, если очередь пуста.

Начиная с версии 5.3

val clear : 'a t -> unit

Удаляет все элементы из очереди.

val copy : 'a t -> 'a t

Возвращает копию указанной очереди.

val is_empty : 'a t -> bool

Возвращает true, если указанная очередь пуста, и false в противном случае.

val length : 'a t -> int

Возвращает количество элементов в очереди.

val iter : ('a -> unit) -> 'a t -> unit

iter f q по очереди применяет f ко всем элементам q, от самого давно добавленного до самого недавно добавленного. Очередь не изменяется.

val fold : ('acc -> 'a -> 'acc) -> 'acc -> 'a t -> 'acc

fold f accu q эквивалентно List.fold_left f accu l, где l — список элементов q. Очередь остаётся неизменной.

val transfer : 'a t -> 'a t -> unit

transfer q1 q2 добавляет все элементы q1 в конец очереди q2, а затем очищает q1. Это эквивалентно последовательности iter (fun x -> add x q2) q1; clear q1, но выполняется за постоянное время.

Итераторы

val to_seq : 'a t -> 'a Seq.t

Перебирает очередь от начала к концу. Поведение не определено, если во время перебора очередь изменяется.

Начиная с версии 4.07

val add_seq : 'a t -> 'a Seq.t -> unit

Добавляет элементы последовательности в конец очереди.

Начиная с версии 4.07

val of_seq : 'a Seq.t -> 'a t

Создаёт очередь из последовательности.

Начиная с версии 4.07

Примеры

Простой пример

Простой пример:

    # let q = Queue.create ()
    val q : '_weak1 Queue.t = <abstr>


    # Queue.push 1 q; Queue.push 2 q; Queue.push 3 q
    - : unit = ()

    # Queue.length q
    - : int = 3

    # Queue.pop q
    - : int = 1

    # Queue.pop q
    - : int = 2

    # Queue.pop q
    - : int = 3

    # Queue.pop q
    Exception: Stdlib.Queue.Empty.

Поиск в графе

В качестве более сложного примера рассмотрим классическое применение очередей в алгоритме BFS (поиск в ширину) для обхода графа.

     type graph = {
       edges: (int, int list) Hashtbl.t
     }

    (* Search in graph [g] using BFS, starting from node [start].
       It returns the first node that satisfies [p], or [None] if
       no node reachable from [start] satisfies [p].
    *)
    let search_for ~(g:graph) ~(start:int) (p:int -> bool) : int option =
      let to_explore = Queue.create() in
      let explored = Hashtbl.create 16 in

      Queue.push start to_explore;
      let rec loop () =
        if Queue.is_empty to_explore then None
        else
          (* node to explore *)
          let node = Queue.pop to_explore in
          explore_node node

      and explore_node node =
        if not (Hashtbl.mem explored node) then (
          if p node then Some node (* found *)
          else (
            Hashtbl.add explored node ();
            let children =
              Hashtbl.find_opt g.edges node
              |> Option.value ~default:[]
            in
            List.iter (fun child -> Queue.push child to_explore) children;
            loop()
          )
        ) else loop()
      in
      loop()

    (* a sample graph *)
    let my_graph: graph =
      let edges =
        List.to_seq [
          1, [2;3];
          2, [10; 11];
          3, [4;5];
          5, [100];
          11, [0; 20];
        ]
        |> Hashtbl.of_seq
      in {edges}

    # search_for ~g:my_graph ~start:1 (fun x -> x = 30)
    - : int option = None

    # search_for ~g:my_graph ~start:1 (fun x -> x >= 15)
    - : int option = Some 20

    # search_for ~g:my_graph ~start:1 (fun x -> x >= 50)
    - : int option = Some 100