10.19 Расширенные операторы индексирования

• 10.19.1 Многомерная запись индексов

(Введено в версии 4.06)

Это расширение предоставляет синтаксический сахар для получения и установки элементов для пользовательских индексированных типов. Например, мы можем определить словари, похожие на python, с

module Dict = struct
include Hashtbl
let ( .%{} ) tabl index = find tabl index
let ( .%{}<- ) tabl index value = add tabl index value
end
let dict =
  let dict = Dict.create 10 in
  let () =
    dict.Dict.%{"one"} <- 1;
    let open Dict in
    dict.%{"two"} <- 2 in
  dict

# dict.Dict.%{"one"};;

- : int = 1

# let open Dict in dict.%{"two"};;

- : int = 2

10.19.1 Многомерная запись индексов

Поддержка многомерных индексов также реализована через второй вариант операторов индексирования

let (.%[;..]) = Bigarray.Genarray.get
let (.%{;..}) = Bigarray.Genarray.get
let (.%(;..)) = Bigarray.Genarray.get

который используется, когда литералы индексов содержат список выражений, разделённых точкой с запятой и имеющих два или более элемента:

let sum x y = x.%[1;2;3] + y.%[1;2]
(* is equivalent to *)
let sum x y = (.%[;..]) x [|1;2;3|] + (.%[;..]) y [|1;2|]

В частности, эта многомерная запись индексов позволяет единообразно обрабатывать индексирование Genarray и других реализаций многомерных массивов.

module A = Bigarray.Genarray
let (.%{;..}) = A.get
let (.%{;..}<- ) = A.set
let (.%{ }) a k = A.get a [|k|]
let (.%{ }<-) a k x = A.set a [|k|] x
let syntax_compare vec mat t3 t4 =
          vec.%{0} = A.get vec [|0|]
   &&   mat.%{0;0} = A.get mat [|0;0|]
   &&   t3.%{0;0;0} = A.get t3 [|0;0;0|]
   && t4.%{0;0;0;0} = t4.{0,0,0,0}

Обратите внимание, что различие между операторами многомерного и одиночного индекса чисто синтаксическое: операторы многомерного индекса ограничены выражениями индексов, которые содержат одну или более точек с запятой ;. Например,

  let pair vec mat = vec.%{0}, mat.%{0;0}

эквивалентно

  let pair vec mat = (.%{ }) vec 0, (.%{;..}) mat [|0;0|]

Обратите внимание, что в случае vec мы вызываем оператор одиночного индекса, (.%{}), а не вариант многомерного индекса, (.{;..}). По этой причине ожидается, что большинство пользователей операторов многомерного индекса должны одновременно определить вариант одиночного индекса

let (.%{;..}) = A.get
let (.%{ }) a k = A.get a [|k|]

для единообразной обработки обоих случаев.