Тип WorkerScript QML

Позволяет использовать потоки в приложении Qt Quick. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• ready : bool
• source : url

Сигналы

• message(jsobject msg)

Методы

• sendMessage(jsobject message)

Подробное описание

Используйте WorkerScript для выполнения операций в новом потоке. Это полезно для выполнения операций в фоновом режиме, чтобы основной поток GUI не блокировался.

Сообщения могут передаваться между новым потоком и родительским потоком с помощью sendMessage() и обработчика onMessage().

Пример:

import QtQuick 2.0

Rectangle {
    width: 300; height: 300

    Text {
        id: myText
        text: 'Click anywhere'
    }

    WorkerScript {
        id: myWorker
        source: "script.mjs"

        onMessage: (messageObject)=> myText.text = messageObject.reply
    }

    MouseArea {
        anchors.fill: parent
        onClicked: (mouse)=> myWorker.sendMessage({ 'x': mouse.x, 'y': mouse.y })
    }
}

Вышеприведенный скрипт рабочего потока указывает на файл JavaScript, "script.mjs", который обрабатывает операции, которые необходимо выполнить в новом потоке. Вот script.mjs:

WorkerScript.onMessage = function(message) {
    // ... long-running operations and calculations are done here
    WorkerScript.sendMessage({ 'reply': 'Mouse is at ' + message.x + ',' + message.y })
}

Когда пользователь нажимает в любом месте прямоугольника, sendMessage() вызывается, активируя обработчик WorkerScript.onMessage() в script.mjs. Это, в свою очередь, отправляет ответное сообщение, которое затем получает обработчик onMessage() в myWorker.

В примере используется скрипт, являющийся модулем ECMAScript, потому что он имеет расширение ".mjs". Он может использовать операторы import для доступа к функциональности из других модулей и выполняется в режиме строгой проверки JavaScript.

Если у скрипта рабочего потока расширение ".js", то он считается содержащим простые операторы JavaScript и выполняется в режиме без строгой проверки.

Ограничения

Поскольку функция WorkerScript.onMessage() выполняется в отдельном потоке, файл JavaScript оценивается в контексте, отличном от основного движка QML. Это означает, что в отличие от обычного файла JavaScript, импортированного в QML, script.mjs в приведенном выше примере не может получить доступ к свойствам, методам или другим атрибутам элемента QML, а также не может получить доступ к свойствам контекста, заданным для объекта QML через QQmlContext.

Кроме того, существуют ограничения на типы значений, которые могут передаваться в скрипт рабочего потока и из него. Подробности см. в документации sendMessage().

Скрипты рабочих потоков, являющиеся обычными источниками JavaScript, не могут использовать синтаксис .import. Скрипты, являющиеся модулями ECMAScript, могут свободно использовать операторы import и export.

См. также Примеры Qt Quick — Потоки и Пример Threaded ListModel.

Документация по свойствам

ready : bool

Это указывает, был ли инициализирован WorkerScript и готов ли он к приёму сообщений через WorkerScript.sendMessage().

source : url

Здесь хранится URL-адрес файла JavaScript, реализующего обработчик WorkerScript.onMessage() для операций в потоке.

Если компонент имени файла в URL заканчивается на ".mjs", то скрипт анализируется как модуль ECMAScript и выполняется в режиме строгой проверки. В противном случае он рассматривается как обычный скрипт.

Документация по сигналам

message(jsobject msg)

Этот сигнал излучается, когда сообщение msg получено от скрипта рабочего потока в другом потоке через вызов sendMessage().

Примечание: Соответствующий обработчик — onMessage.

Документация по методам

sendMessage(jsobject message)

Отправляет заданное сообщение message в обработчик скрипта рабочего потока в другом потоке. Другой обработчик скрипта рабочего потока может получить это сообщение через обработчик onMessage().

Объект message может содержать только значения следующих типов:

• boolean, number, string
• объекты и массивы JavaScript
• объекты ListModel (любой другой тип QObject* не допускается)

Все объекты и массивы копируются в message. За исключением объектов ListModel, любые изменения, внесённые другим потоком в объект, переданный в message, не будут отражены в исходном объекте.