Тип QML Tumbler

Вращающийся диск элементов, которые можно выбрать. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• currentIndex : int
• currentItem : Item
• delegate : Component
• model : variant
• moving : bool
• visibleItemCount : int
• wrap : bool

Присоединенные свойства

• displacement : real
• tumbler : Tumbler

Методы

• void positionViewAtIndex(int index, PositionMode mode)

Подробное описание

Tumbler {
    model: 5
    // ...
}

Tumbler позволяет пользователю выбрать вариант из вращающегося "диска" элементов. Это полезно, когда вариантов слишком много, чтобы использовать, например, RadioButton, и слишком мало, чтобы потребовалось использовать редактируемый SpinBox. Это удобно тем, что не требует использования клавиатуры и переходит к началу или концу при большом количестве элементов.

API похож на API представлений, таких как ListView и PathView; можно установить модель и представителя, а свойства count и currentItem предоставляют доступ к информации о представлении. Чтобы расположить представление на определенном индексе, используйте positionViewAtIndex().

Однако, в отличие от представлений, таких как PathView и ListView, всегда существует текущий элемент (когда модель не пуста). Это означает, что когда count равен 0, currentIndex будет -1. Во всех остальных случаях он будет больше или равен 0.

По умолчанию Tumbler переходит к началу или концу, если в модели элементов больше, чем видимых элементов; то есть когда count больше, чем visibleItemCount:

import QtQuick
import QtQuick.Window
import QtQuick.Controls

Rectangle {
    width: frame.implicitWidth + 10
    height: frame.implicitHeight + 10

    function formatText(count, modelData) {
        var data = count === 12 ? modelData + 1 : modelData;
        return data.toString().length < 2 ? "0" + data : data;
    }

    FontMetrics {
        id: fontMetrics
    }

    Component {
        id: delegateComponent

        Label {
            text: formatText(Tumbler.tumbler.count, modelData)
            opacity: 1.0 - Math.abs(Tumbler.displacement) / (Tumbler.tumbler.visibleItemCount / 2)
            horizontalAlignment: Text.AlignHCenter
            verticalAlignment: Text.AlignVCenter
            font.pixelSize: fontMetrics.font.pixelSize * 1.25
        }
    }

    Frame {
        id: frame
        padding: 0
        anchors.centerIn: parent

        Row {
            id: row

            Tumbler {
                id: hoursTumbler
                model: 12
                delegate: delegateComponent
            }

            Tumbler {
                id: minutesTumbler
                model: 60
                delegate: delegateComponent
            }

            Tumbler {
                id: amPmTumbler
                model: ["AM", "PM"]
                delegate: delegateComponent
            }
        }
    }
}

См. также Настройка Tumbler и Элементы управления вводом.

Документация по свойствам

[только для чтения] count : int

Это свойство содержит количество элементов в модели.

currentIndex : int

Это свойство содержит индекс текущего элемента.

Значение этого свойства равно -1 при count равном 0. Во всех остальных случаях он будет больше или равен 0.

См. также currentItem и positionViewAtIndex().

[только для чтения] currentItem : Item

Это свойство содержит элемент по текущему индексу.

См. также currentIndex и positionViewAtIndex().

delegate : Component

Это свойство содержит представителя, используемого для отображения каждого элемента.

model : variant

Это свойство содержит модель, которая предоставляет данные для этого Tumbler.

[с версии QtQuick.Controls 2.2 (Qt 5.9)] moving : bool

Это свойство описывает, перемещается ли в данный момент Tumbler из-за того, что пользователь перетаскивает или отпускает его.

Это свойство было введено в QtQuick.Controls 2.2 (Qt 5.9).

visibleItemCount : int

Это свойство содержит количество видимых элементов в Tumbler. Оно должно быть нечетным числом, так как текущий элемент всегда находится по вертикали посередине.

[с версии QtQuick.Controls 2.1 (Qt 5.8)] wrap : bool

Это свойство определяет, будет ли Tumbler переходить к началу или концу при достижении верхнего или нижнего края.

Значение по умолчанию равно false при count меньше visibleItemCount, так как взаимодействовать с непереходящим Tumbler, когда есть только несколько элементов, проще. Чтобы изменить это поведение, явно задайте значение этого свойства. Чтобы вернуться к стандартному поведению, установите это свойство в undefined.

Это свойство было введено в QtQuick.Controls 2.1 (Qt 5.8).

Документация по присоединенным свойствам

[только для чтения] Tumbler.displacement : real

Это присоединенное свойство содержит значение от -visibleItemCount / 2 до visibleItemCount / 2, которое показывает, насколько далеко этот элемент находится от текущего элемента, при 0 являясь полностью текущим.

Например, элемент будет на 40% непрозрачным, когда он не является текущим, и перейдет к 100% непрозрачности, когда станет текущим:

delegate: Text {
    text: modelData
    opacity: 0.4 + Math.max(0, 1 - Math.abs(Tumbler.displacement)) * 0.6
}

[только для чтения] Tumbler.tumbler : Tumbler

Это присоединенное свойство содержит Tumbler. Свойство может быть присоединено к представлению Tumbler. Значение равно null если элемент не является представлением Tumbler.

Документация по методам

[since QtQuick.Controls 2.5 (Qt 5.12)] void positionViewAtIndex(int index, PositionMode mode)

Располагает представление так, чтобы index находился в позиции, заданной mode.

Например:

positionViewAtIndex(10, Tumbler.Center)

Если wrap имеет значение true (по умолчанию), доступны режимы PathView's positionViewAtIndex(), в противном случае доступны режимы ListView's positionViewAtIndex().

Этот метод был введен в QtQuick.Controls 2.5 (Qt 5.12).

См. также currentIndex.