Тип QML ParentAnimation

Анимирует изменения значений родителя. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• newParent : Item
• target : Item
• via : Item

Подробное описание

ParentAnimation используется для анимирования изменения родителя для Item.

Например, следующий ParentChange меняет blueRect на дочерний элемент redRect при нажатии. Включение ParentAnimation, которое определяет NumberAnimation для применения во время перехода, гарантирует плавную анимацию элемента при перемещении к новому родителю:

import QtQuick 2.0

Item {
    width: 200; height: 100

    Rectangle {
        id: redRect
        width: 100; height: 100
        color: "red"
    }

    Rectangle {
        id: blueRect
        x: redRect.width
        width: 50; height: 50
        color: "blue"

        states: State {
            name: "reparented"
            ParentChange { target: blueRect; parent: redRect; x: 10; y: 10 }
        }

        transitions: Transition {
            ParentAnimation {
                NumberAnimation { properties: "x,y"; duration: 1000 }
            }
        }

        MouseArea { anchors.fill: parent; onClicked: blueRect.state = "reparented" }
    }
}

ParentAnimation может содержать любое количество анимаций. Эти анимации будут выполняться параллельно; для выполнения последовательно определите их внутри SequentialAnimation.

В некоторых случаях, например, при переназначении родителя между элементами с включенным обрезанием, полезно анимировать изменение родителя через другой элемент, у которого обрезание отключено. Такой элемент можно установить с помощью свойства via.

ParentAnimation обычно используется внутри Transition в сочетании с ParentChange. При использовании таким образом он анимирует все ParentChange, произошедшие во время изменения состояния. Это можно переопределить, задав конкретный целевой элемент с помощью свойства target.

См. также Анимация и переходы в Qt Quick и Примеры Qt Quick — Анимация.

Документация по свойствам

newParent : Item

Новый родитель, к которому следует выполнить анимацию.

Если ParentAnimation определён внутри Transition, это значение по умолчанию соответствует значению, определённому в конечном состоянии Transition.

target : Item

Элемент, который следует переназначить родителю.

При использовании в переходе, если целевой элемент не указан, все ParentChange события анимируются с помощью ParentAnimation.

via : Item

Элемент, через который следует переназначить родитель. Это обеспечивает возможность выполнения анимации без обрезания, когда у старого и нового родителей включено обрезание.

ParentAnimation {
    target: myItem
    via: topLevelItem
    // ...
}