Тип QML SmoothedAnimation

Позволяет свойству плавно отслеживать значение. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• duration : int
• maximumEasingTime : int
• reversingMode : перечисление
• velocity : real

Подробное описание

SmoothedAnimation анимирует значение свойства до заданного целевого значения, используя кривую плавного ускорения/замедления. При изменении целевого значения кривые плавного ускорения/замедления, используемые для анимирования между старым и новым целевыми значениями, плавно соединяются, чтобы создать плавное перемещение к новому целевому значению, которое сохраняет текущую скорость.

Следующий пример показывает, как один Rectangle отслеживает положение другого с помощью SmoothedAnimation. Значения x и y зелёного прямоугольника привязаны к значениям красного прямоугольника. Всякий раз, когда эти значения изменяются, зелёный прямоугольник плавно анимируется в новое положение:

import QtQuick 2.0

Rectangle {
    width: 800; height: 600
    color: "blue"

    Rectangle {
        width: 60; height: 60
        x: rect1.x - 5; y: rect1.y - 5
        color: "green"

        Behavior on x { SmoothedAnimation { velocity: 200 } }
        Behavior on y { SmoothedAnimation { velocity: 200 } }
    }

    Rectangle {
        id: rect1
        width: 50; height: 50
        color: "red"
    }

    focus: true
    Keys.onRightPressed: rect1.x = rect1.x + 100
    Keys.onLeftPressed: rect1.x = rect1.x - 100
    Keys.onUpPressed: rect1.y = rect1.y - 100
    Keys.onDownPressed: rect1.y = rect1.y + 100
}

SmoothedAnimation можно настроить, установив скорость, с которой должна происходить анимация, или длительность анимации. Если заданы и скорость, и длительность, выбирается значение, приводящее к самой быстрой анимации для каждого изменения целевого значения.

Например, анимация от 0 до 800 займёт 4 секунды при скорости 200, 8 секунд при длительности 8000 и 4 секунды при установленных скорости 200 и длительности 8000. Анимация от 0 до 20000 займёт 10 секунд при скорости 200, 8 секунд при длительности 8000 и 8 секунд при установленных скорости 200 и длительности 8000.

По умолчанию скорость SmoothedAnimation составляет 200 единиц/секунда. Обратите внимание, что если диапазон анимируемого значения небольшой, скорость необходимо соответствующим образом скорректировать. Например, непрозрачность элемента изменяется в диапазоне от 0 до 1,0. Чтобы обеспечить плавную анимацию в этом диапазоне, скорость нужно установить на значение, например, 0,5 единицы/секунда. Анимация от 0 до 1,0 со скоростью 0,5 займёт 2000 мс.

Как и любой другой тип анимации, SmoothedAnimation можно применять различными способами, включая переходы, поведения и источники значений свойств. Документация по Анимации и переходы в Qt Quick демонстрирует множество способов создания анимации.

См. также SpringAnimation, NumberAnimation, Анимации и переходы в Qt Quick и Примеры Qt Quick - Анимация.

Документация по свойствам

duration : int

Это свойство содержит длительность анимации в мс, используемую при отслеживании источника.

Установка значения -1 (по умолчанию) отключает значение длительности.

Если значения скорости и длительности включены, анимация будет использовать то, что даёт более короткую длительность.

maximumEasingTime : int

Это свойство указывает максимальное время в мс, которое могут занимать любые «плавные переходы» при отслеживании. Установка этого свойства приводит к «выравниванию» скорости после определённого времени. Установка отрицательного значения возвращает к обычному режиму плавного перехода на протяжении всей длительности анимации.

Значение по умолчанию — -1.

reversingMode : перечисление

Устанавливает поведение SmoothedAnimation, если направление анимации меняется на обратное.

Возможные значения:

• SmoothedAnimation.Eased (по умолчанию) — анимация плавно замедлится, а затем изменит направление
• SmoothedAnimation.Immediate — анимация немедленно начнёт ускоряться в обратном направлении, начиная со скорости 0
• SmoothedAnimation.Sync — свойство немедленно устанавливается в целевое значение

velocity : real

Это свойство содержит среднюю скорость, разрешённую при отслеживании значения «to».

По умолчанию скорость SmoothedAnimation составляет 200 единиц/секунда.

Установка значения -1 отключает значение скорости.

Если значения скорости и длительности включены, анимация будет использовать то, что даёт более короткую длительность.