Тип QML WebEngineHistory

Предоставляет модели данных, представляющие историю страниц веб-движка. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• backItems : WebEngineHistoryModel
• forwardItems : WebEngineHistoryModel
• items : WebEngineHistoryModel

Методы

• void clear()

Подробное описание

К типу WebEngineHistory можно получить доступ, используя свойство WebEngineView.history.

Тип WebEngineHistory предоставляет следующие объекты модели данных WebEngineHistoryModel:

• backItems, содержащий URL посещенных страниц.
• forwardItems, содержащий URL страниц, которые были посещены после текущей страницы.
• items, содержащий URL элементов «Назад» и «Вперед», а также URL текущей страницы.

Самый простой способ использования этих моделей — использовать их в ListView, как показано в следующем фрагменте кода:

ListView {
    id: historyItemsList
    anchors.fill: parent
    model: webEngineView.history.items
    delegate:
        Text {
            color: "black"
            text: model.title + " - " + model.url + " (" + model.offset + ")"
        }
}

ListView отображает содержимое соответствующей модели. Делегат отвечает за формат элементов списка. Внешний вид каждого элемента списка в делегате может быть определен отдельно (он не специфичен для веб-движка).

Роли модели title, url и icon задают заголовок, URL-адрес и значок закладки посещенной страницы. Роль offset указывает положение страницы относительно текущей страницы (0). Положительное число означает, что страница была посещена после текущей страницы, а отрицательное число — что страница была посещена до текущей страницы.

Модели данных также можно использовать для создания меню, как показано в следующем фрагменте кода:

    menuBar: ToolBar {
        id: navigationBar
        RowLayout {
            anchors.fill: parent
            ToolButton {
                enabled: currentWebView && (currentWebView.canGoBack || currentWebView.canGoForward)
                onClicked: historyMenu.open()
                text: qsTr("▼")
                Menu {
                    id: historyMenu
                    Instantiator {
                        model: currentWebView && currentWebView.history.items
                        MenuItem {
                            text: model.title
                            onTriggered: currentWebView.goBackOrForward(model.offset)
                            checkable: !enabled
                            checked: !enabled
                            enabled: model.offset
                        }

                        onObjectAdded: function(index, object) {
                            historyMenu.insertItem(index, object)
                        }
                        onObjectRemoved: function(index, object) {
                            historyMenu.removeItem(object)
                        }
                    }
                }

Для получения полного примера см. WebEngine Quick Nano Browser.

См. такжеWebEngineHistoryModel.

Документация по свойствам

[только для чтения] backItems : WebEngineHistoryModel

URL посещенных страниц.

[только для чтения] forwardItems : WebEngineHistoryModel

URL страниц, которые были посещены после текущей страницы.

[только для чтения] items : WebEngineHistoryModel

URL элементов «Назад», «Вперед» и текущего элемента в истории.

Документация по методам

[since QtWebEngine 1.11] void clear()

Очищает историю.

Этот метод был представлен в QtWebEngine 1.11.