Определение JavaScript-ресурсов в QML

Логика программы для приложения QML может быть определена на JavaScript. JavaScript-код может быть определен непосредственно в документах QML или отделен в файлы JavaScript (известные как JavaScript Resources в QML).

В QML поддерживаются два разных типа JavaScript-ресурсов: файлы реализации с «кодом позади» и общие (библиотечные) файлы. Оба типа JavaScript-ресурсов могут быть импортированы другими JavaScript-ресурсами или включены в модули QML.

Ресурс реализации с «кодом позади»

Большинство файлов JavaScript, импортированных в документ QML, являются состоятельными реализациями для документа QML, их импортирующего. В этих случаях каждый экземпляр типа QML-объекта, определенного в документе, требует отдельной копии JavaScript-объектов и состояния для правильной работы.

По умолчанию при импорте файлов JavaScript предоставляется уникальная, изолированная копия для каждого экземпляра QML-компонента. Если этот файл JavaScript не импортирует никакие ресурсы или модули с инструкцией .import, его код будет выполняться в той же области видимости, что и экземпляр QML-компонента, и, следовательно, может получать доступ к и манипулировать объектами и свойствами, объявленными в этом QML-компоненте. В противном случае у него будет своя уникальная область видимости, и объекты и свойства QML-компонента должны передаваться функциям JavaScript-файла в качестве параметров, если они необходимы.

Вот пример ресурса реализации с «кодом позади»:

// MyButton.qml
import QtQuick 2.0
import "my_button_impl.js" as Logic // A new instance of this JavaScript resource
                                    // is loaded for each instance of Button.qml.

Rectangle {
    id: rect
    width: 200
    height: 100
    color: "red"

    MouseArea {
        id: mousearea
        anchors.fill: parent
        onClicked: Logic.onClicked(rect)
    }
}

// my_button_impl.js
var clickCount = 0;   // this state is separate for each instance of MyButton
function onClicked(button) {
    clickCount += 1;
    if ((clickCount % 5) == 0) {
        button.color = Qt.rgba(1,0,0,1);
    } else {
        button.color = Qt.rgba(0,1,0,1);
    }
}

В целом, простая логика должна быть определена непосредственно в файле QML, но более сложная логика должна быть отделена в ресурсы реализации с «кодом позади» для поддержания и удобочитаемости.

Общие JavaScript-ресурсы (библиотеки)

По умолчанию файлы JavaScript, импортированные из QML, делят свой контекст с QML-компонентом. Это означает, что JavaScript-файлы имеют доступ к тем же QML-объектам и могут их изменять. Вследствие этого каждый импорт должен иметь уникальную копию этих файлов.

Предыдущий раздел охватывает состоятельные импорты файлов JavaScript. Однако некоторые файлы JavaScript являются бессостоятельными и действуют скорее как повторно используемые библиотеки, в том смысле, что они предоставляют набор вспомогательных функций, которые не требуют ничего от места их импорта. Вы можете значительно сэкономить память и ускорить создание экземпляров QML-компонентов, если пометить такие библиотеки специальным пragma, как показано в следующем примере.

// factorial.js
.pragma library

var factorialCount = 0;

function factorial(a) {
    a = parseInt(a);

    // factorial recursion
    if (a > 0)
        return a * factorial(a - 1);

    // shared state
    factorialCount += 1;

    // recursion base-case.
    return 1;
}

function factorialCallCount() {
    return factorialCount;
}

Объявление pragma должно появиться перед любым JavaScript-кодом, за исключением комментариев.

Обратите внимание, что несколько QML-документов могут импортировать "factorial.js" и вызывать функции factorial и factorialCallCount, которые оно предоставляет. Состояние JavaScript-импорта разделяется между QML-документами, которые его импортируют, и, следовательно, возвращаемое значение функции factorialCallCount может быть отличным от нуля при вызове в QML-документе, который никогда не вызывал функцию factorial.

Например:

// Calculator.qml
import QtQuick 2.0
import "factorial.js" as FactorialCalculator // This JavaScript resource is only
                                             // ever loaded once by the engine,
                                             // even if multiple instances of
                                             // Calculator.qml are created.

Text {
    width: 500
    height: 100
    property int input: 17
    text: "The factorial of " + input + " is: " + FactorialCalculator.factorial(input)
}

Поскольку они являются общими, файлы .pragma library не могут напрямую получать доступ к объектам или свойствам экземпляров QML-компонентов, хотя QML-значения могут передаваться в качестве параметров функций.