Тип QML DelegateModel

Инкапсулирует модель и делегат. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• delegate : Component
• filterOnGroup : string
• groups : list<DelegateModelGroup>
• items : DelegateModelGroup
• model : model
• parts : object
• persistedItems : DelegateModelGroup
• rootIndex : QModelIndex

Присоединённые свойства

• groups : stringlist
• inItems : int
• inPersistedItems : int
• isUnresolved : bool
• itemsIndex : int
• model : int
• persistedItemsIndex : int

Методы

• QModelIndex modelIndex(int index)
• QModelIndex parentModelIndex()

Подробное описание

Тип DelegateModel инкапсулирует модель и делегат, который будет создан для элементов в модели.

Обычно нет необходимости создавать DelegateModel. Однако он может быть полезен для манипулирования и доступа к modelIndex при использовании подкласса QAbstractItemModel в качестве модели. Также DelegateModel используется совместно с Package для предоставления делегатов нескольким представлениям и с DelegateModelGroup для сортировки и фильтрации элементов делегата.

В примере ниже показано использование DelegateModel с ListView.

import QtQuick 2.0
import QtQml.Models 2.2

Rectangle {
    width: 200; height: 100

    DelegateModel {
        id: visualModel
        model: ListModel {
            ListElement { name: "Apple" }
            ListElement { name: "Orange" }
        }
        delegate: Rectangle {
            height: 25
            width: 100
            Text { text: "Name: " + name}
        }
    }

    ListView {
        anchors.fill: parent
        model: visualModel
    }
}

Примечание: Этот тип также доступен как VisualDataModel в модуле Qt QML по соображениям совместимости.

Документация по свойствам

count : int

delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, созданный представлением. Индекс представлен как доступное index свойство. Свойства модели также доступны в зависимости от типа модели данных.

filterOnGroup : string

Это свойство содержит имя группы, используемой для фильтрации визуальной модели данных.

Только элементы, принадлежащие этой группе, видны в представлении.

По умолчанию это группа items.

groups : list<DelegateModelGroup>

Это свойство содержит определения групп модели делегата.

Группы определяют подмножество элементов в модели делегата и могут использоваться для фильтрации модели.

Для каждой группы, определённой в DelegateModel, к каждому элементу делегата добавляются два присоединённых свойства. Первое из них в форме DelegateModel.inGroupName показывает, принадлежит ли элемент группе, а второе DelegateModel.groupNameIndex содержит индекс элемента в этой группе.

Следующий пример иллюстрирует использование групп для выбора элементов в модели.

import QtQuick 2.0
import QtQml.Models 2.2

Rectangle {
    width: 200; height: 100

    DelegateModel {
        id: visualModel
        model: ListModel {
            ListElement { name: "Apple" }
            ListElement { name: "Orange" }
        }

        groups: [
            DelegateModelGroup { name: "selected" }
        ]

        delegate: Rectangle {
            id: item
            height: 25
            width: 200
            Text {
                text: {
                    var text = "Name: " + name
                    if (item.DelegateModel.inSelected)
                        text += " (" + item.DelegateModel.selectedIndex + ")"
                    return text;
                }
            }
            MouseArea {
                anchors.fill: parent
                onClicked: item.DelegateModel.inSelected = !item.DelegateModel.inSelected
            }
        }
    }

    ListView {
        anchors.fill: parent
        model: visualModel
    }
}

items : DelegateModelGroup

Это свойство содержит групповые параметры визуальной модели данных по умолчанию, к которым добавляются все новые элементы.

model : model

Это свойство содержит модель, предоставляющую данные для DelegateModel.

Модель предоставляет набор данных, используемых для создания элементов представления. Для больших или динамических наборов данных модель обычно предоставляется объектом модели C++. Объект модели C++ должен быть подклассом QAbstractItemModel или простым списком.

Модели также могут быть созданы непосредственно в QML, используя ListModel или XmlListModel.

См. также Модели данных.

parts : object

Свойство parts выбирает DelegateModel, который создаёт делегаты из части с указанным именем. Это используется совместно с типом Package.

Например, код ниже выбирает модель, которая создаёт делегаты с именем list из Package:

DelegateModel {
    id: visualModel
    delegate: Package {
        Item { Package.name: "list" }
    }
    model: myModel
}

ListView {
    width: 200; height:200
    model: visualModel.parts.list
}

См. также Package.

persistedItems : DelegateModelGroup

Это свойство содержит группу сохранённых элементов визуальной модели данных.

Элементы в этой группе не уничтожаются при освобождении представлением, вместо этого они сохраняются до удаления из группы.

Элемент можно удалить из группы persistedItems, установив свойство DelegateModel.inPersistedItems в значение false. Если в этот момент на элемент не ссылается представление, он будет уничтожен. Добавление элемента в эту группу не создаст новый экземпляр.

Элементы, возвращаемые функцией QtQml.Models::DelegateModelGroup::create(), автоматически добавляются в эту группу.

rootIndex : QModelIndex

QAbstractItemModel предоставляет иерархическое дерево данных, тогда как QML работает только со списком данных. rootIndex позволяет предоставить потомков любого узла в QAbstractItemModel с помощью этой модели.

Это свойство влияет только на модели типа QAbstractItemModel, которые являются иерархическими (например, модель дерева).

Например, вот простой интерактивный файловый обозреватель. Когда нажимается имя каталога, свойство rootIndex представления устанавливается в узел QModelIndex нажатого каталога, тем самым обновляя представление для отображения содержимого нового каталога.

main.cpp:

int main(int argc, char ** argv)
{
    QApplication app(argc, argv);

    QQuickView view;

    QDirModel model;
    view.rootContext()->setContextProperty("dirModel", &model);

    view.setSource(QUrl::fromLocalFile("view.qml"));
    view.show();

    return app.exec();
}

view.qml:

import QtQuick 2.0
import QtQml.Models 2.2

ListView {
    id: view
    width: 300
    height: 400

    model: DelegateModel {
        model: dirModel

        delegate: Rectangle {
            width: 200; height: 25
            Text { text: filePath }

            MouseArea {
                anchors.fill: parent
                onClicked: {
                    if (model.hasModelChildren)
                        view.model.rootIndex = view.model.modelIndex(index)
                }
            }
        }
    }
}

Если model является подклассом QAbstractItemModel, делегат также может ссылаться на hasModelChildren свойство (необязательно с префиксом model.), которое указывает, имеет ли элемент модели делегата дочерние узлы.

См. также modelIndex() и parentModelIndex().

Документация по присоединённым свойствам

DelegateModel.groups : stringlist

Это присоединённое свойство содержит имена DelegateModelGroups, к которым принадлежит элемент.

Оно присоединяется к каждому экземпляру делегата.

DelegateModel.inItems : int

Это присоединённое свойство содержит значение, указывающее, принадлежит ли элемент группе items DelegateModelGroup по умолчанию.

Изменение этого свойства добавит или удалит элемент из группы items.

Оно присоединяется к каждому экземпляру делегата.

DelegateModel.inPersistedItems : int

Это присоединённое свойство содержит значение, указывающее, принадлежит ли элемент группе persistedItems DelegateModelGroup.

Изменение этого свойства добавит или удалит элемент из группы items. Изменяйте с осторожностью, так как удаление элемента из группы persistedItems приведёт к уничтожению текущего экземпляра, если на него не ссылается модель.

Оно присоединяется к каждому экземпляру делегата.

DelegateModel.isUnresolved : bool

Это присоединённое свойство содержит значение, указывающее, связан ли визуальный элемент с индексом модели данных. Возвращает true, если элемент не связан с моделью, и false, если связан.

Неразрешённый элемент может быть привязан к модели данных с помощью функции DelegateModelGroup::resolve().

Он прикреплён к каждому экземпляру делегата.

DelegateModel.itemsIndex : int

Это присоединённое свойство содержит индекс элемента в стандартном items DelegateModelGroup.

Он прикреплён к каждому экземпляру делегата.

DelegateModel.model : int

Это присоединённое свойство содержит визуальную модель данных, к которой принадлежит данный экземпляр делегата.

Он прикреплён к каждому экземпляру делегата.

DelegateModel.persistedItemsIndex : int

Это присоединённое свойство содержит индекс элемента в persistedItems DelegateModelGroup.

Он прикреплён к каждому экземпляру делегата.

Документация методов

QModelIndex modelIndex(int index)

QAbstractItemModel предоставляет иерархическое дерево данных, в то время как QML работает только со списками. Данная функция помогает в использовании древовидных моделей в QML.

Возвращает QModelIndex для указанного индекса. Это значение может быть присвоено rootIndex.

См. также rootIndex.

QModelIndex parentModelIndex()

QAbstractItemModel предоставляет иерархическое дерево данных, в то время как QML работает только со списками. Данная функция помогает в использовании древовидных моделей в QML.

Возвращает QModelIndex для родительского элемента текущего rootIndex. Это значение может быть присвоено rootIndex.

См. также rootIndex.