Тип QML ActionGroup

Группирует действия вместе. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• actions : список<Action>
• checkedAction : Action
• enabled : bool
• exclusive : bool

Присоединенные свойства

• group : ActionGroup

Сигналы

• triggered(Action action)

Методы

• void addAction(Action action)
• void removeAction(Action action)

Подробное описание

ActionGroup — это невидимая группа действий. Взаимоисключающая группа действий используется для действий, где можно выбрать только один из вариантов одновременно.

Самый простой способ использовать ActionGroup — объявить действия как дочерние элементы группы.

ActionGroup {
    id: alignmentGroup

    Action {
        checked: true
        checkable: true
        text: qsTr("Left")
    }

    Action {
        checkable: true
        text: qsTr("Center")
    }

    Action {
        checkable: true
        text: qsTr("Right")
    }
}

В качестве альтернативы, присоединенное свойство group позволяет объявить действия в другом месте и назначить их конкретной группе.

ActionGroup { id: alignmentGroup }

Action {
    checked: true
    checkable: true
    text: qsTr("Left")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Center")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Right")
    ActionGroup.group: alignmentGroup
}

Более сложные случаи использования могут быть обработаны с помощью методов addAction() и removeAction().

См. также Action и ButtonGroup.

Документация по свойствам

[default] actions : список<Action>

Это свойство содержит список действий в группе.

См. также group.

checkedAction : Action

Это свойство содержит текущее выбранное действие в исключающей группе или null , если его нет или группа не исключающая.

По умолчанию это первое выбранное действие, добавленное в исключающую группу действий.

См. также exclusive.

enabled : bool

Это свойство содержит значение, определяющее, включена ли группа действий. Значение по умолчанию — true.

Если это свойство false, все действия в группе отключены. Если это свойство true, все действия в группе включены, если не отключены явно.

exclusive : bool

Это свойство содержит значение, определяющее, является ли группа действий исключающей. Значение по умолчанию — true.

Если это свойство true, тогда только одно действие в группе может быть выбрано в любой момент. Пользователь может вызвать любое действие, чтобы выбрать его, и это действие заменит существующее как выбранное действие в группе.

В исключающей группе пользователь не может сбросить текущее выбранное действие, вызвав его; вместо этого необходимо вызвать другое действие в группе, чтобы установить новое выбранное действие для этой группы.

В неисключающей группе выбор и отмена выбора действий не влияют на другие действия в группе. Кроме того, значение свойства checkedAction равно null.

Документация по присоединенным свойствам

ActionGroup.group : ActionGroup

Это свойство присоединяет действие к группе действий.

ActionGroup { id: group }

Action {
    checked: true
    text: qsTr("Option A")
    ActionGroup.group: group
}

Action {
    text: qsTr("Option B")
    ActionGroup.group: group
}

См. также actions.

Документация по сигналам

triggered(Action action)

Этот сигнал излучается, когда действие action в группе было выполнено.

Этот сигнал удобен для реализации обработчика общего сигнала для всех действий в одной группе.

ActionGroup {
    onTriggered: console.log("triggered:", action.text)

    Action { text: "First" }
    Action { text: "Second" }
    Action { text: "Third" }
}

См. также Action::triggered().

Документация по методам

void addAction(Action action)

Добавляет action в группу действий.

Примечание: Ручное добавление объектов в группу действий обычно не требуется. Свойство actions и присоединенное свойство group обеспечивают удобную и декларативную синтаксическую конструкцию.

См. также actions и group.

void removeAction(Action action)

Удаляет action из группы действий.

Примечание: Ручное удаление объектов из группы действий обычно не требуется. Свойство actions и присоединенное свойство group обеспечивают удобную и декларативную синтаксическую конструкцию.

См. также actions и group.