Тип QML Tumbler

Вращающийся диск элементов, которые можно выбрать. Подробнее...

• Список всех членов, включая наследуемые члены

Свойства

• count : int
• currentIndex : int
• currentItem : Item
• delegate : Component
• model : variant
• moving : bool
• visibleItemCount : int
• wrap : bool

Прикрепленные свойства

• displacement : real
• tumbler : Tumbler

Подробное описание

Tumbler {
    model: 5
    // ...
}

Tumbler позволяет пользователю выбрать опцию из вращающегося "диска" элементов. Это полезно, когда слишком много опций, чтобы использовать, например, RadioButton, и слишком мало опций, чтобы потребовалась редактируемая SpinBox. Это удобно тем, что оно не требует использования клавиатуры и перематывается в начале и в конце при большом количестве элементов.

API аналогичен представлениям, таким как ListView и PathView; можно установить model и delegate, а свойства count и currentItem обеспечивают чтение информации о представлении.

Однако, в отличие от представлений, таких как PathView и ListView, всегда есть текущий элемент (когда модель не пуста). Это означает, что когда count равно 0, currentIndex будет -1. Во всех остальных случаях он будет больше или равен 0.

По умолчанию, Tumbler перематывается при достижении верхней и нижней границ, если в модели элементов больше, чем видимых элементов; то есть, когда count больше, чем visibleItemCount:

import QtQuick 2.8
import QtQuick.Window 2.2
import QtQuick.Controls 2.1

Rectangle {
    width: frame.implicitWidth + 10
    height: frame.implicitHeight + 10

    function formatText(count, modelData) {
        var data = count === 12 ? modelData + 1 : modelData;
        return data.toString().length < 2 ? "0" + data : data;
    }

    FontMetrics {
        id: fontMetrics
    }

    Component {
        id: delegateComponent

        Label {
            text: formatText(Tumbler.tumbler.count, modelData)
            opacity: 1.0 - Math.abs(Tumbler.displacement) / (Tumbler.tumbler.visibleItemCount / 2)
            horizontalAlignment: Text.AlignHCenter
            verticalAlignment: Text.AlignVCenter
            font.pixelSize: fontMetrics.font.pixelSize * 1.25
        }
    }

    Frame {
        id: frame
        padding: 0
        anchors.centerIn: parent

        Row {
            id: row

            Tumbler {
                id: hoursTumbler
                model: 12
                delegate: delegateComponent
            }

            Tumbler {
                id: minutesTumbler
                model: 60
                delegate: delegateComponent
            }

            Tumbler {
                id: amPmTumbler
                model: ["AM", "PM"]
                delegate: delegateComponent
            }
        }
    }
}

См. также Настройка Tumbler и Элементы управления вводом.

Документация по свойствам

[только для чтения] count : int

Это свойство содержит количество элементов в модели.

currentIndex : int

Это свойство содержит индекс текущего элемента.

Значение этого свойства равно -1 когда count равно 0. Во всех остальных случаях оно будет больше или равно 0.

[только для чтения] currentItem : Item

Это свойство содержит элемент по текущему индексу.

delegate : Component

Это свойство содержит делегат, используемый для отображения каждого элемента.

model : variant

Это свойство содержит модель, предоставляющую данные для этого тумблера.

moving : bool

Это свойство описывает, перемещается ли тумблер в данный момент, из-за того, что пользователь либо перетаскивает его, либо делает щелчок.

Это свойство было добавлено в QtQuick.Controls 2.2 (Qt 5.9).

visibleItemCount : int

Это свойство содержит количество видимых элементов в тумблере. Оно должно быть нечетным числом, так как текущий элемент всегда находится по вертикали посередине.

wrap : bool

Это свойство определяет, будет ли тумблер перематываться, когда достигнет верхней или нижней границы.

Значение по умолчанию — false, когда count меньше visibleItemCount, так как взаимодействие с неперематывающимся тумблером проще, когда элементов всего несколько. Чтобы переопределить это поведение, явно задайте значение этого свойства. Чтобы вернуться к поведению по умолчанию, установите это свойство в значение undefined.

Это свойство было добавлено в QtQuick.Controls 2.1 (Qt 5.8).

Документация по прикрепленным свойствам

[только для чтения] Tumbler.displacement : real

Это прикрепленное свойство содержит значение от -visibleItemCount / 2 до visibleItemCount / 2, которое представляет, насколько далеко этот элемент находится от текущего элемента, при 0 представляя абсолютную текучесть.

Например, элемент ниже будет иметь 40% непрозрачности, когда он не является текущим элементом, и перейдет к 100% непрозрачности, когда он станет текущим элементом:

delegate: Text {
    text: modelData
    opacity: 0.4 + Math.max(0, 1 - Math.abs(Tumbler.displacement)) * 0.6
}

[только для чтения] Tumbler.tumbler : Tumbler

Это прикрепленное свойство содержит тумблер. Свойство может быть прикреплено к делегату тумблера. Значение — null если элемент не является делегатом тумблера.