Тип QML PathAttribute

Указывает, как установить атрибут в заданной позиции в пути. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• name : строка
• value : вещественное

Подробное описание

Объект PathAttribute позволяет задавать атрибуты, состоящие из имени и значения, для различных точек вдоль пути. Атрибуты предоставляются делегату как Присоединенные свойства. Значение атрибута в любой конкретной точке вдоль пути интерполируется из PathAttributes, ограничивающих эту точку.

Ниже приведен пример пути с элементами, масштабированными до 30% с непрозрачностью 50% в верхней части пути и масштабированными на 100% с непрозрачностью 100% в нижней части. Обратите внимание на использование присоединенных свойств PathView.iconScale и PathView.iconOpacity для установки масштаба и непрозрачности делегата.

import QtQuick 2.0

Rectangle {
    width: 240; height: 200

    Component {
        id: delegate
        Item {
            width: 80; height: 80
            scale: PathView.iconScale
            opacity: PathView.iconOpacity
            Column {
                Image { anchors.horizontalCenter: nameText.horizontalCenter; width: 64; height: 64; source: icon }
                Text { id: nameText; text: name; font.pointSize: 16 }
            }
        }
    }

    PathView {
        anchors.fill: parent
        model: ContactModel {}
        delegate: delegate
        path: Path {
            startX: 120; startY: 100
            PathAttribute { name: "iconScale"; value: 1.0 }
            PathAttribute { name: "iconOpacity"; value: 1.0 }
            PathQuad { x: 120; y: 25; controlX: 260; controlY: 75 }
            PathAttribute { name: "iconScale"; value: 0.3 }
            PathAttribute { name: "iconOpacity"; value: 0.5 }
            PathQuad { x: 120; y: 100; controlX: -20; controlY: 75 }
        }
    }
}

См. также Path.

Документация по свойствам

name : строка

Это свойство содержит имя атрибута, который нужно изменить.

Этот атрибут будет доступен делегату как PathView.<name>

Обратите внимание, что использование существующего имени свойства элемента, такого как "opacity", в качестве атрибута разрешено. Это происходит потому, что атрибуты пути добавляют новое Присоединенное свойство, которое никоим образом не конфликтует с существующими свойствами.

value : вещественное

Это свойство содержит значение для атрибута.

Указанное значение может использоваться для влияния на визуальный вид элемента вдоль пути. Например, следующий путь задает атрибут с именем itemRotation, имеющий значение 0 в начале пути и значение 90 в конце пути.

Path {
    startX: 0
    startY: 0
    PathAttribute { name: "itemRotation"; value: 0 }
    PathLine { x: 100; y: 100 }
    PathAttribute { name: "itemRotation"; value: 90 }
}

В нашем делегате мы можем привязать свойство rotation к присоединенному свойству PathView.itemRotation, созданному для этого атрибута.

Rectangle {
    width: 10; height: 10
    rotation: PathView.itemRotation
}

По мере позиционирования каждого элемента вдоль пути он будет вращаться соответствующим образом: элемент в начале пути не будет вращаться, элемент в конце пути будет повернут на 90 градусов, а элемент посередине пути — на 45 градусов.