Тип QML DelegateModel

Инкапсулирует модель и делегат. Подробнее...

Заявление об импорте: import QtQml.Models 2.12

Список всех членов, включая унаследованные

Свойства

count : int
delegate : Component
filterOnGroup : string
groups : list<DelegateModelGroup>
items : DelegateModelGroup
model : model
parts : object
persistedItems : DelegateModelGroup
rootIndex : QModelIndex

Присоединённые свойства

groups : stringlist
inItems : int
inPersistedItems : int
isUnresolved : bool
itemsIndex : int
model : model
persistedItemsIndex : int

Методы

QModelIndex modelIndex(int index)
QModelIndex parentModelIndex()

Подробное описание

Тип DelegateModel инкапсулирует модель и делегат, который будет экземпляризован для элементов в модели.

Обычно нет необходимости создавать DelegateModel. Однако он может быть полезен для управления и доступа к modelIndex, когда используется подкласс QAbstractItemModel в качестве модели. Кроме того, DelegateModel используется вместе с Package для предоставления делегатов нескольким представлениям и с DelegateModelGroup для сортировки и фильтрации элементов делегата.

В приведенном ниже примере показано использование DelegateModel с ListView.

import QtQuick 2.0
import QtQml.Models 2.2

Rectangle {
    width: 200; height: 100

    DelegateModel {
        id: visualModel
        model: ListModel {
            ListElement { name: "Apple" }
            ListElement { name: "Orange" }
        }
        delegate: Rectangle {
            height: 25
            width: 100
            Text { text: "Name: " + name}
        }
    }

    ListView {
        anchors.fill: parent
        model: visualModel
    }
}

Документация по свойствам

count : int

delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, экземпляризуемый представлением. Индекс доступен как доступное index свойство. Свойства модели также доступны в зависимости от типа модели данных.

filterOnGroup : string

Это свойство содержит имя группы, которое используется для фильтрации модели делегата.

Только элементы, принадлежащие этой группе, будут видны представлению.

По умолчанию это группа items.

groups : list<DelegateModelGroup>

Это свойство содержит определения групп модели делегата.

Группы определяют подмножество элементов в модели делегата и могут использоваться для фильтрации модели.

Для каждой группы, определенной в DelegateModel, к каждому элементу делегата добавляются два присоединённых свойства. Первое в формате DelegateModel.inGroupName указывает, принадлежит ли элемент группе, а второе DelegateModel.groupNameIndex содержит индекс элемента в этой группе.

Следующий пример иллюстрирует использование групп для выбора элементов в модели.

import QtQuick 2.0
import QtQml.Models 2.2

Rectangle {
    width: 200; height: 100

    DelegateModel {
        id: visualModel
        model: ListModel {
            ListElement { name: "Apple" }
            ListElement { name: "Orange" }
        }

        groups: [
            DelegateModelGroup { name: "selected" }
        ]

        delegate: Rectangle {
            id: item
            height: 25
            width: 200
            Text {
                text: {
                    var text = "Name: " + name
                    if (item.DelegateModel.inSelected)
                        text += " (" + item.DelegateModel.selectedIndex + ")"
                    return text;
                }
            }
            MouseArea {
                anchors.fill: parent
                onClicked: item.DelegateModel.inSelected = !item.DelegateModel.inSelected
            }
        }
    }

    ListView {
        anchors.fill: parent
        model: visualModel
    }
}

items : DelegateModelGroup

Это свойство содержит группу по умолчанию, в которую добавляются все новые элементы.

model : model

Это свойство содержит модель, предоставляющую данные для DelegateModel.

Модель предоставляет набор данных, который используется для создания элементов для представления. Для больших или динамических наборов данных модель обычно предоставляется объектом C++ модели. Объект C++ модели должен быть подклассом QAbstractItemModel или простым списком.

Модели также могут создаваться непосредственно в QML, используя ListModel или XmlListModel.

См. также Модели данных.

parts : object

Свойство parts выбирает DelegateModel, который создаёт делегаты из части с указанным именем. Это используется в сочетании с типом Package.

Например, код ниже выбирает модель, которая создаёт делегаты с именем list из Package:

DelegateModel {
    id: visualModel
    delegate: Package {
        Item { Package.name: "list" }
    }
    model: myModel
}

ListView {
    width: 200; height:200
    model: visualModel.parts.list
}

См. также Package.

persistedItems : DelegateModelGroup

Это свойство содержит группу сохранённых элементов модели делегата.

Элементы в этой группе не уничтожаются при высвобождении представлением, а сохраняются до удаления из группы.

Элемент можно удалить из группы persistedItems, установив свойство DelegateModel.inPersistedItems в false. Если к элементу нет ссылок со стороны представления в этот момент, он будет уничтожен. Добавление элемента в эту группу не создаст новый экземпляр.

Элементы, возвращаемые функцией QtQml.Models::DelegateModelGroup::create(), автоматически добавляются в эту группу.

rootIndex : QModelIndex

QAbstractItemModel предоставляет иерархическое дерево данных, тогда как QML работает только со списовыми данными. rootIndex позволяет предоставить потомков любого узла в QAbstractItemModel с помощью этой модели.

Это свойство влияет только на модели типа QAbstractItemModel, которые являются иерархическими (например, модель дерева).

Например, вот простой интерактивный файловый обозреватель. Когда нажимается имя каталога, rootIndex представления устанавливается в узел QModelIndex нажатого каталога, тем самым обновляя представление, чтобы показать содержимое нового каталога.

main.cpp:

int main(int argc, char ** argv)
{
    QApplication app(argc, argv);

    QQuickView view;

    QDirModel model;
    view.rootContext()->setContextProperty("dirModel", &model);

    view.setSource(QUrl::fromLocalFile("view.qml"));
    view.show();

    return app.exec();
}

view.qml:

import QtQuick 2.0
import QtQml.Models 2.2

ListView {
    id: view
    width: 300
    height: 400

    model: DelegateModel {
        model: dirModel

        delegate: Rectangle {
            width: 200; height: 25
            Text { text: filePath }

            MouseArea {
                anchors.fill: parent
                onClicked: {
                    if (model.hasModelChildren)
                        view.model.rootIndex = view.model.modelIndex(index)
                }
            }
        }
    }
}

Если model является подклассом QAbstractItemModel, делегат также может ссылаться на hasModelChildren свойство (необязательно квалифицированное префиксом model.), которое указывает, имеет ли элемент модели делегата какие-либо дочерние узлы.

См. также modelIndex() и parentModelIndex().