Тип QML ActionGroup

Группирует действия вместе. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• actions : список<Action>
• checkedAction : Action
• enabled : bool
• exclusive : bool

Прикреплённые свойства

• group : ActionGroup

Сигналы

• triggered(Действие action)

Методы

• void addAction(Действие action)
• void removeAction(Действие action)

Подробное описание

ActionGroup — это невидимая группа действий. Взаимоисключающая группа действий используется с действиями, где можно выбрать только один вариант.

Самый простой способ использовать ActionGroup — объявлять действия как дочерние элементы группы.

ActionGroup {
    id: alignmentGroup

    Action {
        checked: true
        checkable: true
        text: qsTr("Left")
    }

    Action {
        checkable: true
        text: qsTr("Center")
    }

    Action {
        checkable: true
        text: qsTr("Right")
    }
}

В качестве альтернативы, прикреплённое свойство group позволяет объявить действия в другом месте и присвоить их конкретной группе.

ActionGroup { id: alignmentGroup }

Action {
    checked: true
    checkable: true
    text: qsTr("Left")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Center")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Right")
    ActionGroup.group: alignmentGroup
}

Более сложные случаи использования можно обработать с помощью методов addAction() и removeAction().

См. также Action и ButtonGroup.

Документация по свойствам

[default] actions : список<Action>

Это свойство содержит список действий в группе.

См. также group.

checkedAction : Action

Это свойство содержит текущее выбранное действие в исключающей группе или null если такового нет или группа не исключающая.

По умолчанию это первое отмеченное действие, добавленное в исключающую группу действий.

См. также exclusive.

enabled : bool

Это свойство указывает, включена ли группа действий. Значение по умолчанию — true.

Если это свойство false, то все действия в группе отключены. Если это свойство true, все действия в группе включены, если явно не отключены.

exclusive : bool

Это свойство указывает, является ли группа действий исключающей. Значение по умолчанию — true.

Если это свойство true, то только одно действие в группе может быть отмечено в любой момент. Пользователь может активировать любое действие, чтобы отметить его, и это действие заменит существующее отмеченное действие в группе.

В исключающей группе пользователь не может снять отметку с текущего отмеченного действия, активировав его; вместо этого необходимо активировать другое действие в группе, чтобы установить новое отмеченное действие для этой группы.

В неисключающей группе проверка и снятие отметки с действий не влияет на другие действия в группе. Кроме того, значение свойства checkedAction равно null.

Документация по прикреплённым свойствам

ActionGroup.group : ActionGroup

Это свойство прикрепляет действие к группе действий.

ActionGroup { id: group }

Action {
    checked: true
    text: qsTr("Option A")
    ActionGroup.group: group
}

Action {
    text: qsTr("Option B")
    ActionGroup.group: group
}

См. также actions.

Документация по сигналам

triggered(Action action)

Этот сигнал испускается, когда действие action в группе было активировано.

Этот сигнал удобен для реализации обработчика общего сигнала для всех действий в одной группе.

ActionGroup {
    onTriggered: console.log("triggered:", action.text)

    Action { text: "First" }
    Action { text: "Second" }
    Action { text: "Third" }
}

См. также Action::triggered().

Документация по методам

void addAction(Action action)

Добавляет action в группу действий.

Примечание: Ручное добавление объектов в группу действий обычно не требуется. Свойство actions и прикреплённое свойство group предоставляют удобный и декларативный синтаксис.

См. также actions и group.

void removeAction(Action action)

Удаляет action из группы действий.

Примечание: Ручное удаление объектов из группы действий обычно не требуется. Свойство actions и прикреплённое свойство group предоставляют удобный и декларативный синтаксис.

См. также actions и group.