Тип QML SwipeDelegate

Делегат элемента, который можно свайпить влево или вправо. Используется как делегат в таких представлениях, как ListView. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• swipe
  • swipe.position : real
  • swipe.complete : bool
  • swipe.enabled : bool
  • swipe.left : Component
  • swipe.behind : Component
  • swipe.right : Component
  • swipe.leftItem : Item
  • swipe.behindItem : Item
  • swipe.rightItem : Item
  • swipe.transition : Transition

Присоединенные свойства

• pressed : bool

Сигналы

• void swipe.closed()
• void swipe.completed()
• void swipe.opened()

Присоединенные сигналы

• clicked()

Методы

• void swipe.close()
• void swipe.open(перечисление side)

Подробное описание

SwipeDelegate представляет элемент представления, который можно свайпить влево или вправо, чтобы открыть больше опций или информации. Он используется в качестве делегата в таких представлениях, как ListView.

В следующем примере SwipeDelegate используется в ListView, чтобы разрешить удаление элементов из него путем свайпа влево:

ListView {
    id: listView
    anchors.fill: parent
    model: ListModel {
        ListElement { sender: "Bob Bobbleton"; title: "How are you going?" }
        ListElement { sender: "Rug Emporium"; title: "SALE! All rugs MUST go!" }
        ListElement { sender: "Electric Co."; title: "Electricity bill 15/07/2016 overdue" }
        ListElement { sender: "Tips"; title: "Five ways this tip will save your life" }
    }
    delegate: SwipeDelegate {
        id: swipeDelegate
        text: model.sender + " - " + model.title
        width: parent.width

        ListView.onRemove: SequentialAnimation {
            PropertyAction {
                target: swipeDelegate
                property: "ListView.delayRemove"
                value: true
            }
            NumberAnimation {
                target: swipeDelegate
                property: "height"
                to: 0
                easing.type: Easing.InOutQuad
            }
            PropertyAction {
                target: swipeDelegate
                property: "ListView.delayRemove"
                value: false
            }
        }

        swipe.right: Label {
            id: deleteLabel
            text: qsTr("Delete")
            color: "white"
            verticalAlignment: Label.AlignVCenter
            padding: 12
            height: parent.height
            anchors.right: parent.right

            SwipeDelegate.onClicked: listView.model.remove(index)

            background: Rectangle {
                color: deleteLabel.SwipeDelegate.pressed ? Qt.darker("tomato", 1.1) : "tomato"
            }
        }
    }
}

SwipeDelegate наследует свой API от ItemDelegate, который наследуется от AbstractButton. Например, вы можете установить text и реагировать на щелчки, используя API AbstractButton.

Информация о прогрессе свайпа, а также компоненты, которые должны отображаться при свайпе, доступны через сгруппированный свойство-объект swipe. Например, swipe.position содержит положение свайпа в диапазоне от -1.0 до 1.0. Свойство swipe.left определяет, какой элемент будет отображаться при свайпе вправо, и наоборот для swipe.right. Размещение этих компонентов остается на усмотрение приложений. Например, без указания позиции для swipe.left или swipe.right, произойдет следующее:

Если swipe.left и swipe.right закреплены слева и справа от элемента background (соответственно), они будут вести себя так:

При использовании swipe.left и swipe.right, элемент нельзя свайпить за крайние левые и правые края. Чтобы получить такое поведение "завертывания", установите swipe.behind. Это приведет к отображению того же элемента независимо от направления свайпа. Например, на изображении ниже мы установили swipe.behind, а затем многократно свайпим элемент в обоих направлениях:

См. также Настройка SwipeDelegate, Делегатские элементы управления и Пример свайпа для удаления.

Документация по свойствам

swipe.position : real

SwipeDelegate {
    swipe.transition: Transition {
        SmoothedAnimation { velocity: 3; easing.type: Easing.InOutCubic }
    }
}

См. такжеcontentItem, background, swipe.open() и swipe.close().

Документация присоединенных свойств

[только для чтения] SwipeDelegate.pressed : bool

Это свойство можно присоединить к неинтерактивному элементу, объявленному в swipe.left, swipe.right, или swipe.behind, для определения, нажат ли он. Элементы могут быть нажаты только тогда, когда swipe.complete равно true.

Например:

swipe.right: Label {
    anchors.right: parent.right
    height: parent.height
    text: "Action"
    color: "white"
    padding: 12
    background: Rectangle {
        color: SwipeDelegate.pressed ? Qt.darker("tomato", 1.1) : "tomato"
    }
}

Возможны несколько элементов, которые индивидуально получают события мыши и касания. Например, чтобы иметь два действия в элементе swipe.right, используйте следующий код:

swipe.right: Row {
    anchors.right: parent.right
    height: parent.height

    Label {
        id: moveLabel
        text: qsTr("Move")
        color: "white"
        verticalAlignment: Label.AlignVCenter
        padding: 12
        height: parent.height

        SwipeDelegate.onClicked: console.log("Moving...")

        background: Rectangle {
            color: moveLabel.SwipeDelegate.pressed ? Qt.darker("#ffbf47", 1.1) : "#ffbf47"
        }
    }
    Label {
        id: deleteLabel
        text: qsTr("Delete")
        color: "white"
        verticalAlignment: Label.AlignVCenter
        padding: 12
        height: parent.height

        SwipeDelegate.onClicked: console.log("Deleting...")

        background: Rectangle {
            color: deleteLabel.SwipeDelegate.pressed ? Qt.darker("tomato", 1.1) : "tomato"
        }
    }
}

Обратите внимание, как присвоение color в каждом элементе background квалифицирует присоединенное свойство с помощью id метки. Это важно; использование присоединенных свойств к элементу заставляет этот элемент принимать события. Предположим, что мы исключили id в предыдущем примере:

color: SwipeDelegate.pressed ? Qt.darker("tomato", 1.1) : "tomato"

Элемент Rectangle background является дочерним элементом метки, поэтому он естественным образом получает события раньше. На практике это означает, что цвет фона изменится, но обработчик onClicked в метке никогда не будет вызван.

Для интерактивных элементов управления (например, Button), объявленных в этих элементах, используйте соответствующее свойство pressed.

Для нажатий на сам SwipeDelegate используйте свойство pressed.

Это свойство было введено в QtQuick.Controls 2.1 (Qt 5.8).

См. такжеclicked().

Документация сигналов

void swipe.closed()

Этот сигнал испускается, когда делегат свайпнут в закрытое положение и анимация завершена.

Это полезно для выполнения какого-либо действия при отмене свайпа. Например, это можно использовать для отмены удаления делегата из списка.

Этот сигнал был введен в QtQuick.Controls 2.2 (Qt 5.9).

См. также swipe и swipe.opened().

void swipe.completed()

Этот сигнал испускается, когда swipe.complete становится true.

Это полезно для выполнения какого-либо действия при завершении свайпа. Например, это можно использовать для удаления делегата из списка.

Этот сигнал был введен в QtQuick.Controls 2.1 (Qt 5.8).

См. также swipe.

void swipe.opened()

Этот сигнал испускается, когда делегат свайпнут в открытое положение и анимация завершена.

Это полезно для выполнения какого-либо действия при завершении свайпа. Например, это можно использовать для удаления делегата из списка.

Этот сигнал был введен в QtQuick.Controls 2.2 (Qt 5.9).

См. также swipe и swipe.closed().

Документация присоединенных сигналов

clicked()

Этот сигнал можно присоединить к неинтерактивному элементу, объявленному в swipe.left, swipe.right, или swipe.behind, для реакции на щелчки. Элементы могут быть нажаты только тогда, когда swipe.complete равно true.

Для интерактивных элементов управления (например, Button), объявленных в этих элементах, используйте соответствующий сигнал clicked().

Для реакции на щелчки по самому SwipeDelegate используйте его сигнал clicked().

Примечание: См. документацию к pressed для получения информации о правильном использовании связанных свойств событий.

Этот сигнал был введен в QtQuick.Controls 2.1 (Qt 5.8).

См. также pressed.

Документация методов

void swipe.close()

Этот метод устанавливает position свайпа в 0. Любые анимации, определенные для положения x contentItem и background, будут запущены.

Этот метод был введен в QtQuick.Controls 2.1 (Qt 5.8).

См. также swipe и swipe.open().

void swipe.open(enumeration side)

Этот метод устанавливает position свайпа таким образом, чтобы он открывался со стороны side.

Доступные значения:

Любые анимации, определенные для позиции x элемента contentItem и background, будут активированы.

Этот метод был представлен в QtQuick.Controls 2.2 (Qt 5.9).

См. также swipe и swipe.close().