Тип QML WorkerScript

Разрешает использование потоков в приложении Qt Quick. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• source : url

Сигналы

• message(msg)

Методы

• sendMessage(message)

Подробное описание

Используйте WorkerScript для выполнения операций в новом потоке. Это полезно для выполнения операций в фоновом режиме, чтобы основной поток GUI не блокировался.

Сообщения могут передаваться между новым потоком и родительским потоком с помощью sendMessage() и обработчика onMessage().

Пример:

import QtQuick 2.0

Rectangle {
    width: 300; height: 300

    Text {
        id: myText
        text: 'Click anywhere'
    }

    WorkerScript {
        id: myWorker
        source: "script.mjs"

        onMessage: myText.text = messageObject.reply
    }

    MouseArea {
        anchors.fill: parent
        onClicked: myWorker.sendMessage({ 'x': mouse.x, 'y': mouse.y })
    }
}

Вышеприведенный скрипт работ определяет файл JavaScript, "script.mjs", который обрабатывает операции, выполняемые в новом потоке. Вот script.mjs:

WorkerScript.onMessage = function(message) {
    // ... long-running operations and calculations are done here
    WorkerScript.sendMessage({ 'reply': 'Mouse is at ' + message.x + ',' + message.y })
}

При щелчке пользователем в любом месте прямоугольника вызывается sendMessage(), что запускает обработчик WorkerScript.onMessage() в script.mjs. Это, в свою очередь, отправляет сообщение с ответом, которое затем получает обработчик onMessage() объекта myWorker.

В примере используется скрипт, который является модулем ECMAScript, поскольку у него расширение ".mjs". Он может использовать инструкции import для доступа к функциональности из других модулей, и он выполняется в строгом режиме JavaScript.

Если скрипт работ имеет расширение ".js" вместо этого, то он считается содержащим обычные операторы JavaScript и выполняется в нестрогом режиме.

Примечание: Каждый элемент WorkerScript будет создавать отдельный движок JavaScript для обеспечения идеальной изоляции и безопасности потоков. Если это оказывает слишком большое влияние на потребление памяти в вашей среде, рассмотрите возможность совместного использования элемента WorkerScript.

Ограничения

Поскольку функция WorkerScript.onMessage() выполняется в отдельном потоке, файл JavaScript оценивается в контексте, отличном от основного движка QML. Это означает, что в отличие от обычного файла JavaScript, импортированного в QML, script.mjs в приведенном выше примере не может получить доступ к свойствам, методам или другим атрибутам элемента QML, а также не может получить доступ к каким-либо контекстным свойствам, заданным на объекте QML через QQmlContext.

Кроме того, существуют ограничения на типы значений, которые могут передаваться в скрипт работ и из него. Подробности см. в документации к sendMessage().

Скрипты работ, являющиеся обычными источниками JavaScript, не могут использовать синтаксис .import. Скрипты, которые являются модулями ECMAScript, могут свободно использовать инструкции import и export.

См. также Примеры Qt Quick — Потоки и Пример Threaded ListModel.

Документация свойств

source : url

Здесь хранится URL-адрес файла JavaScript, который реализует обработчик WorkerScript.onMessage() для операций в потоке.

Если компонент имени файла в URL-адресе заканчивается на ".mjs", то скрипт анализируется как модуль ECMAScript и выполняется в строгом режиме. В противном случае он рассматривается как обычный скрипт.

Документация сигналов

message(msg)

Этот сигнал излучается, когда сообщение msg получено от скрипта работ в другом потоке через вызов sendMessage().

Соответствующий обработчик — onMessage.

Документация методов

sendMessage(message)

Отправляет указанное message в обработчик скрипта работ в другом потоке. Другой обработчик скрипта работ может получить это сообщение через обработчик onMessage().

Объект message может содержать только значения следующих типов:

• boolean, number, string
• объекты и массивы JavaScript
• объекты ListModel (любой другой тип QObject* не разрешен)

Все объекты и массивы копируются в message. За исключением объектов ListModel, любые изменения, внесенные другим потоком в объект, переданный в message, не будут отражены в исходном объекте.