Тип действия QML

Action предоставляет абстрактное действие пользовательского интерфейса, которое может быть привязано к элементам. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• checkable : bool
• checked : bool
• enabled : bool
• exclusiveGroup : ExclusiveGroup
• iconName : строка
• iconSource : url
• shortcut : keysequence
• text : строка
• tooltip : строка

Сигналы

• toggled(checked)
• triggered( *source)

Методы

• void trigger( *source)

Подробное описание

Во многих приложениях многие общие команды могут быть вызваны через меню, кнопки панели инструментов и сочетания клавиш. Поскольку пользователь ожидает, что каждая команда будет выполнена одинаково, независимо от используемого пользовательского интерфейса, полезно представить каждую команду как действие.

Действие может быть привязано к пункту меню и кнопке панели инструментов, и оно будет автоматически поддерживать их синхронизацию. Например, в текстовом редакторе, если пользователь нажмёт кнопку «Жирный» на панели инструментов, пункт меню «Жирный» будет автоматически отмечен.

QtQuick Controls поддерживает действия в Button, ToolButton и MenuItem.

    ...
    Action {
        id: copyAction
        text: "&Copy"
        shortcut: StandardKey.Copy
        iconName: "edit-copy"
        enabled: (!!activeFocusItem && !!activeFocusItem["copy"])
        onTriggered: activeFocusItem.copy()
    }

    Action {
        id: cutAction
        text: "Cu&t"
        shortcut: StandardKey.Cut
        iconName: "edit-cut"
        enabled: (!!activeFocusItem && !!activeFocusItem["cut"])
        onTriggered: activeFocusItem.cut()
    }

    Action {
        id: pasteAction
        text: "&Paste"
        shortcut: StandardKey.Paste
        iconName: "edit-paste"
        enabled: (!!activeFocusItem && !!activeFocusItem["paste"])
        onTriggered: activeFocusItem.paste()
    }

    toolBar: ToolBar {
        RowLayout {
            anchors.fill: parent
            anchors.margins: spacing
            Label {
                text: UI.label
            }
            Item { Layout.fillWidth: true }
            CheckBox {
                id: enabler
                text: "Enabled"
                checked: true
            }
        }
    }

    menuBar: MenuBar {
        Menu {
            title: "&File"
            MenuItem {
                text: "E&xit"
                shortcut: StandardKey.Quit
                onTriggered: Qt.quit()
            }
        }
        Menu {
            title: "&Edit"
            visible: tabView.currentIndex == 2
            MenuItem { action: cutAction }
            MenuItem { action: copyAction }
            MenuItem { action: pasteAction }
        }
        Menu {
            title: "&Help"
            MenuItem {
                text: "About..."
                onTriggered: aboutDialog.open()
            }
        }
    }
    ...

Документация свойств

checkable : bool

Определяет, может ли элемент меню быть отмечен или переключён. По умолчанию false.

См. также checked и exclusiveGroup.

checked : bool

Если действие checkable, это свойство отражает его состояние выбора. По умолчанию false. Его значение также равно false, когда checkable равно false.

См. также toggled и exclusiveGroup.

enabled : bool

Определяет, активировано ли действие и может ли оно быть запущено. По умолчанию true.

См. также trigger() и triggered.

exclusiveGroup : ExclusiveGroup

Если действие checkable, к нему можно прикрепить ExclusiveGroup. Все действия, использующие одну и ту же группу exclusive, становятся взаимоисключающими, то есть только последнее выбранное действие фактически будет выбрано.

По умолчанию null, что означает, что исключительное поведение не ожидается.

См. также checkable и checked.

iconName : string

Устанавливает имя значка для действия. Это выберет значок с заданным именем из текущей темы.

По умолчанию пустая строка.

Примечание: Это свойство требует QApplication.

iconSource : url

Устанавливает URL-адрес файла или ресурса значка для действия. По умолчанию пустой URL.

shortcut : keysequence

Сочетание клавиш, привязанное к действию. Keysequence может быть строкой или стандартной клавишей.

По умолчанию пустая строка.

Action {
    id: copyAction
    text: qsTr("&Copy")
    shortcut: StandardKey.Copy
}

text : string

Текст для действия. Этот текст отобразится как текст кнопки или как заголовок в пункте меню.

Мемоники поддерживаются путём добавления префикса & к букве сочетания клавиш. Например, "\&Open" привяжет сочетание клавиш Alt-O к пункту меню "Open". Обратите внимание, что не все платформы поддерживают мемоники.

По умолчанию пустая строка.

tooltip : string

Подсказка, которая будет отображаться при наведении указателя на элемент управления, привязанный к этому действию. Не все элементы управления поддерживают подсказки на всех платформах, особенно MenuItem.

По умолчанию пустая строка.

Документация сигналов

toggled(checked)

Выдаётся всякий раз, когда свойство checked действия изменяется. Обычно это происходит одновременно с triggered.

Соответствующий обработчик onToggled.

triggered( *source)

Выдаётся, когда пункт меню или привязанное к нему действие были активированы. Включает объект, который вызвал событие, если это применимо (например, Button или MenuItem). Вам не нужно издавать этот сигнал, вместо этого используйте trigger().

Соответствующий обработчик onTriggered.

Документация методов

void trigger( *source)

Издаёт сигнал triggered, если действие активировано. Вы можете предоставить объект источника, если действие выиграет от знания происхождения запуска (например, для аналитики). Также издаёт сигнал toggled, если оно checkable.