Тип QML ActionGroup

Группирует действия вместе. Подробнее...

• Список всех членов, включая наследуемые

Свойства

• actions : list<Action>
• checkedAction : Action
• enabled : bool
• exclusive : bool

Прикрепленные свойства

• group : ActionGroup

Сигналы

• triggered(action)

Методы

• void addAction(action)
• void removeAction(action)

Подробное описание

ActionGroup — это невизуальная группа действий. Взаимоисключающая группа действий используется для действий, где можно выбрать только один вариант одновременно.

Наиболее простой способ использования ActionGroup — объявление действий в качестве дочерних элементов группы.

ActionGroup {
    id: alignmentGroup

    Action {
        checked: true
        checkable: true
        text: qsTr("Left")
    }

    Action {
        checkable: true
        text: qsTr("Center")
    }

    Action {
        checkable: true
        text: qsTr("Right")
    }
}

В качестве альтернативы, прикреплённое свойство group позволяет объявлять действия в другом месте и назначать их конкретной группе.

ActionGroup { id: alignmentGroup }

Action {
    checked: true
    checkable: true
    text: qsTr("Left")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Center")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Right")
    ActionGroup.group: alignmentGroup
}

Более сложные случаи могут быть обработаны с помощью методов addAction() и removeAction().

См. также Action и ButtonGroup.

Документация по свойствам

[default] actions : list<Action>

Это свойство содержит список действий в группе.

См. также group.

checkedAction : Action

Это свойство содержит текущее выбранное действие в исключающей группе, или null если его нет или группа не исключающая.

По умолчанию это первое отмеченное действие, добавленное в исключающую группу действий.

См. также exclusive.

enabled : bool

Это свойство определяет, включена ли группа действий. Значение по умолчанию — true.

Если это свойство false, то все действия в группе отключены. Если это свойство true, все действия в группе включены, если явно не отключены.

exclusive : bool

Это свойство определяет, является ли группа действий исключающей. Значение по умолчанию — true.

Если это свойство true, то только одно действие в группе может быть отмечено в любой момент времени. Пользователь может вызвать любое действие для его отметки, и это действие заменит существующее в качестве выделенного действия в группе.

В исключающей группе пользователь не может снять отметку с текущего выделенного действия, вызвав его; вместо этого, должно быть вызвано другое действие в группе, чтобы установить новое выделенное действие для этой группы.

В неисключающей группе отметка и снятие отметки с действий не влияют на другие действия в группе. Кроме того, значение свойства checkedAction равно null.

Документация по прикрепленным свойствам

ActionGroup.group : ActionGroup

Это свойство прикрепляет действие к группе действий.

ActionGroup { id: group }

Action {
    checked: true
    text: qsTr("Option A")
    ActionGroup.group: group
}

Action {
    text: qsTr("Option B")
    ActionGroup.group: group
}

См. также actions.

Документация по сигналам

triggered(action)

Этот сигнал излучается, когда действие action в группе было вызвано.

Этот сигнал удобен для реализации обработчика общего сигнала для всех действий в одной группе.

ActionGroup {
    onTriggered: console.log("triggered:", action.text)

    Action { text: "First" }
    Action { text: "Second" }
    Action { text: "Third" }
}

См. также Action::triggered().

Документация по методам

void addAction(action)

Добавляет действие action в группу действий.

Примечание: Ручное добавление объектов в группу действий обычно не требуется. Свойство actions и прикреплённое свойство group обеспечивают удобный и декларативный синтаксис.

См. также actions и group.

void removeAction(action)

Удаляет действие action из группы действий.

Примечание: Ручное удаление объектов из группы действий обычно не требуется. Свойство actions и прикреплённое свойство group обеспечивают удобный и декларативный синтаксис.

См. также actions и group.