Тип QML Tumbler

Поворачиваемое колесо элементов, которые можно выбрать. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• count : int
• currentIndex : int
• currentItem : Item
• delegate : Component
• model : variant
• moving : bool
• visibleItemCount : int
• wrap : bool

Присоединенные свойства

• displacement : real
• tumbler : Tumbler

Методы

• void positionViewAtIndex(index, PositionMode mode)

Подробное описание

Tumbler {
    model: 5
    // ...
}

Tumbler позволяет пользователю выбирать вариант из вращающегося "колеса" элементов. Он полезен, когда вариантов слишком много для использования, например, RadioButton, и слишком мало для использования редактируемого SpinBox. Он удобен тем, что не требует использования клавиатуры и перематывает элементы в начале и конце при большом количестве элементов.

API аналогичен представлениям, таким как ListView и PathView; можно задать модель и представление, а свойства count и currentItem обеспечивают чтение информации о представлении. Для позиционирования представления в определенном индексе используйте positionViewAtIndex().

В отличие от представлений, таких как PathView и ListView, всегда есть текущий элемент (если модель не пуста). Это означает, что когда count равен 0, currentIndex будет -1. Во всех остальных случаях он будет больше или равен 0.

По умолчанию Tumbler перематывается при достижении верха и низа, если в модели больше элементов, чем видимых; то есть, когда count больше visibleItemCount:

import QtQuick 2.12
import QtQuick.Window 2.2
import QtQuick.Controls 2.12

Rectangle {
    width: frame.implicitWidth + 10
    height: frame.implicitHeight + 10

    function formatText(count, modelData) {
        var data = count === 12 ? modelData + 1 : modelData;
        return data.toString().length < 2 ? "0" + data : data;
    }

    FontMetrics {
        id: fontMetrics
    }

    Component {
        id: delegateComponent

        Label {
            text: formatText(Tumbler.tumbler.count, modelData)
            opacity: 1.0 - Math.abs(Tumbler.displacement) / (Tumbler.tumbler.visibleItemCount / 2)
            horizontalAlignment: Text.AlignHCenter
            verticalAlignment: Text.AlignVCenter
            font.pixelSize: fontMetrics.font.pixelSize * 1.25
        }
    }

    Frame {
        id: frame
        padding: 0
        anchors.centerIn: parent

        Row {
            id: row

            Tumbler {
                id: hoursTumbler
                model: 12
                delegate: delegateComponent
            }

            Tumbler {
                id: minutesTumbler
                model: 60
                delegate: delegateComponent
            }

            Tumbler {
                id: amPmTumbler
                model: ["AM", "PM"]
                delegate: delegateComponent
            }
        }
    }
}

См. также Настройка Tumbler и Элементы управления вводом.

Документация по свойствам

[только для чтения] count : int

Это свойство содержит количество элементов в модели.

currentIndex : int

Это свойство содержит индекс текущего элемента.

Значение этого свойства равно -1 когда count равен 0. Во всех остальных случаях он будет больше или равен 0.

См. также currentItem и positionViewAtIndex().

[только для чтения] currentItem : Item

Это свойство содержит элемент в текущем индексе.

См. также currentIndex и positionViewAtIndex().

delegate : Component

Это свойство содержит представление, используемое для отображения каждого элемента.

model : variant

Это свойство содержит модель, которая предоставляет данные для этого регулятора.

moving : bool

Это свойство описывает, перемещается ли в данный момент регулятор из-за перетаскивания или пощёлкивания пользователем.

Это свойство было добавлено в QtQuick.Controls 2.2 (Qt 5.9).

visibleItemCount : int

Это свойство содержит количество видимых элементов в регуляторе. Оно должно быть нечётным числом, поскольку текущий элемент всегда находится по вертикали посередине.

wrap : bool

Это свойство определяет, перематывается ли регулятор при достижении начала или конца.

Значение по умолчанию равно false когда count меньше visibleItemCount, так как взаимодействие с неперематывающимся регулятором проще при небольшом количестве элементов. Чтобы переопределить это поведение, явно задайте значение этого свойства. Чтобы вернуться к поведению по умолчанию, задайте это свойство в undefined.

Это свойство было добавлено в QtQuick.Controls 2.1 (Qt 5.8).

Документация по присоединенному свойству

[только для чтения] Tumbler.displacement : real

Это присоединенное свойство содержит значение от -visibleItemCount / 2 до visibleItemCount / 2, которое представляет, насколько далеко этот элемент находится от текущего элемента, при 0 является полностью текущим.

Например, элемент будет на 40% непрозрачным, когда он не является текущим элементом, и перейдёт к 100% непрозрачности, когда станет текущим элементом:

delegate: Text {
    text: modelData
    opacity: 0.4 + Math.max(0, 1 - Math.abs(Tumbler.displacement)) * 0.6
}

[только для чтения] Tumbler.tumbler : Tumbler

Это присоединенное свойство содержит регулятор. Свойство можно прикрепить к представлению регулятора. Значение равно null если элемент не является представлением регулятора.

Документация по методам

void positionViewAtIndex(index, PositionMode mode)

Позиционирует представление так, чтобы index находился в позиции, указанной mode.

Например:

positionViewAtIndex(10, Tumbler.Center)

Если wrap равно true (по умолчанию), доступны режимы, доступные для функции PathView's positionViewAtIndex(), в противном случае доступны режимы, доступные для функции ListView's positionViewAtIndex().

Примечание: Существует известное ограничение, что использование Tumbler.Beginning когда wrap равно true приведёт к неправильному позиционированию элемента в верхней части представления. В качестве обходного решения передайте index - 1.

Этот метод был добавлен в QtQuick.Controls 2.5 (Qt 5.12).

См. также currentIndex.