Тип QML прямоугольника

Рисует заполненный прямоугольник с необязательной границей. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• antialiasing : bool
• border
  • border.width : int
  • border.color : цвет
• color : цвет
• gradient : любой
• radius : вещественное число

Подробное описание

Элементы прямоугольника используются для заполнения областей сплошным цветом или градиентами и/или для создания прямоугольной границы.

Внешний вид

Каждый элемент прямоугольника рисуется сплошным цветом заливки, заданным свойством color, или градиентом, определенным с помощью типа Градиент и заданным с помощью свойства gradient. Если указаны и цвет, и градиент, используется градиент.

Вы можете добавить необязательную границу к прямоугольнику со своим цветом и толщиной, установив свойства border.color и border.width. Установите цвет в «прозрачный», чтобы нарисовать границу без цвета заливки.

Вы также можете создать закругленные прямоугольники с помощью свойства radius. Поскольку это вводит кривые края в углы прямоугольника, может быть целесообразно установить свойство Item::antialiasing для улучшения его отображения.

Пример использования

В следующем примере показано влияние некоторых общих свойств на элемент прямоугольника, который в данном случае используется для создания квадрата:

import QtQuick 2.0

Rectangle {
    width: 100
    height: 100
    color: "red"
    border.color: "black"
    border.width: 5
    radius: 10
}

Производительность

Использование свойства Item::antialiasing улучшает отображение закругленного прямоугольника за счёт снижения производительности рендеринга. Вы должны рассмотреть возможность отключения этого свойства для движущихся прямоугольников и устанавливать его только для стационарных.

См. также Изображение.

Документация по свойствам

antialiasing : bool

Используется для определения, должен ли прямоугольник использовать сглаживание или нет. Сглаживание содержит информацию о последствиях для производительности этого свойства.

По умолчанию равно true для прямоугольников с радиусом и false в противном случае.

border.width : int

Ширина и цвет, используемые для рисования границы прямоугольника.

Ширина 1 создаёт тонкую линию. Для отсутствия линии используйте ширину 0 или прозрачный цвет.

Примечание: Ширина границы прямоугольника не влияет на геометрию самого прямоугольника или его положение относительно других элементов, если используются якоря.

Граница рисуется внутри границ прямоугольника.

color : цвет

Это свойство содержит цвет, используемый для заливки прямоугольника.

Цвет по умолчанию — белый.

В следующем примере показаны прямоугольники с цветами, заданными с использованием шестнадцатеричного и именованного обозначения цвета:

Rectangle {
    color: "#00B000"
    width: 80; height: 80
}

Rectangle {
    color: "steelblue"
    y: 100; width: 80; height: 80
}

Если заданы и градиент, и цвет, будет использоваться градиент.

См. также gradient.

gradient : любой

Градиент для заливки прямоугольника.

Это свойство позволяет создавать простые вертикальные или горизонтальные градиенты. Другие градиенты могут быть сформированы путем добавления поворота к прямоугольнику.

Rectangle {
    y: 0; width: 80; height: 80
    color: "lightsteelblue"
}

Rectangle {
    y: 100; width: 80; height: 80
    gradient: Gradient {
        GradientStop { position: 0.0; color: "lightsteelblue" }
        GradientStop { position: 1.0; color: "blue" }
    }
}

Rectangle {
    y: 200; width: 80; height: 80
    rotation: 90
    gradient: Gradient {
        GradientStop { position: 0.0; color: "lightsteelblue" }
        GradientStop { position: 1.0; color: "blue" }
    }
}

Свойство также принимает предустановки градиентов из QGradient::Preset. Однако имейте в виду, что поскольку прямоугольник поддерживает только простые вертикальные или горизонтальные градиенты, любая предустановка с недопустимым углом вернётся к ближайшему представлению.

Rectangle {
    y: 0; width: 80; height: 80
    gradient: Gradient.NightFade
}

Rectangle {
    y: 0; width: 80; height: 80
    gradient: "NightFade"
}

Если заданы и градиент, и цвет, будет использоваться градиент.

См. также Градиент и color.

radius : вещественное число

Это свойство содержит радиус угла, используемый для рисования закругленного прямоугольника.

Если radius не равен нулю, прямоугольник будет нарисован как закругленный прямоугольник, иначе — как обычный прямоугольник. Один и тот же радиус используется для всех 4 углов; в настоящее время нет способа указать разные радиусы для разных углов.