Определение типов объектов через QML-документы

Одной из ключевых особенностей QML является возможность лёгкого определения типов QML-объектов в QML-документах, адаптированных к потребностям конкретных приложений QML. Стандартный модуль Qt Quick предоставляет различные типы, такие как Rectangle, Text и Image для построения QML-приложения; помимо этого, вы можете легко определить собственные QML-типы для повторного использования в приложении. Эта возможность создания собственных типов формирует строительные блоки любого QML-приложения.

Определение типа объекта с помощью QML-файла

Именование пользовательских типов QML-объектов

Для создания типа объекта QML-документ должен быть помещён в текстовый файл с именем <TypeName>.qml, где <TypeName> — желаемое имя типа. Имя типа должно удовлетворять следующим требованиям:

• Оно должно состоять из буквенно-цифровых символов или символов подчёркивания.
• Оно должно начинаться с заглавной буквы.

Этот документ автоматически распознаётся движком как определение QML-типа. Кроме того, тип, определённый таким образом, автоматически становится доступным другим QML-файлам в той же директории, так как движок ищет в непосредственной директории при разрешении имён QML-типов.

Определение пользовательского QML-типа

Например, ниже представлен документ, объявляющий Rectangle с дочерним элементом MouseArea. Документ был сохранён в файле с именем SquareButton.qml:

// SquareButton.qml
import QtQuick 2.0

Rectangle {
    property int side: 100
    width: side; height: side
    color: "red"

    MouseArea {
        anchors.fill: parent
        onClicked: console.log("Button clicked!")
    }
}

Поскольку файл называется SquareButton.qml, его теперь можно использовать как тип с именем SquareButton любым другим QML-файлом в той же директории. Например, если в той же директории был файл myapplication.qml, он мог бы ссылаться на тип SquareButton:

// myapplication.qml
import QtQuick 2.0

SquareButton {}

Это создаёт красный Rectangle размером 100x100 с внутренним MouseArea, как определено в SquareButton.qml. При загрузке этого документа myapplication.qml движком, он загружает документ SquareButton.qml как компонент и создаёт объект SquareButton.

Тип SquareButton оборачивает дерево QML-объектов, объявленных в SquareButton.qml. Когда QML-движок создаёт объект SquareButton этого типа, он создаёт объект из дерева Rectangle, объявленного в SquareButton.qml.

Примечание: регистр букв имени файла важен в некоторых файловых системах (особенно UNIX). Рекомендуется, чтобы регистр имени файла точно соответствовал регистру желаемого имени QML-типа — например, Box.qml, а не BoX.qml, независимо от платформы, на которой будет развернут QML-тип.

Импортирование типов, определённых вне текущей директории

Если SquareButton.qml не находился в той же директории, что и myapplication.qml, типу SquareButton потребовалось бы явное указание доступности через инструкцию import в myapplication.qml. Он может быть импортирован из относительного пути в файловой системе или как установленный модуль; см. модуль для получения дополнительной информации.

Доступные атрибуты пользовательских типов

Определение корневого объекта в файле .qml определяет атрибуты, доступные для QML-типа. Все свойства, сигналы и методы, относящиеся к этому корневому объекту — будь то пользовательские объявления или свойства QML-типа корневого объекта — являются внешне доступными и могут быть считываться и изменяться для объектов этого типа.

Например, типом корневого объекта в файле SquareButton.qml выше является Rectangle. Это означает, что любые свойства, определённые типом Rectangle, могут быть изменены для объекта SquareButton. Следующий код определяет три объекта SquareButton с настроенными значениями для некоторых свойств корневого объекта Rectangle типа SquareButton:

// application.qml
import QtQuick 2.0

Column {
    SquareButton { side: 50 }
    SquareButton { x: 50; color: "blue" }
    SquareButton { radius: 10 }
}

Атрибуты, доступные для объектов пользовательского QML-типа, включают любые пользовательские свойства, методы и сигналы, которые дополнительно были определены для объекта. Например, предположим, что Rectangle в SquareButton.qml был определён следующим образом, с дополнительными свойствами, методами и сигналами:

// SquareButton.qml
import QtQuick 2.0

Rectangle {
    id: root

    property bool pressed: mouseArea.pressed

    signal buttonClicked(real xPos, real yPos)

    function randomizeColor() {
        root.color = Qt.rgba(Math.random(), Math.random(), Math.random(), 1)
    }

    property int side: 100
    width: side; height: side
    color: "red"

    MouseArea {
        id: mouseArea
        anchors.fill: parent
        onClicked: root.buttonClicked(mouse.x, mouse.y)
    }
}

Любой объект SquareButton может использовать свойство pressed, сигнал buttonClicked и метод randomizeColor(), которые были добавлены к корневому Rectangle:

// application.qml
import QtQuick 2.0

SquareButton {
    id: squareButton

    onButtonClicked: {
        console.log("Clicked", xPos, yPos)
        randomizeColor()
    }

    Text { text: squareButton.pressed ? "Down" : "Up" }
}

Обратите внимание, что любые значения id , определённые в SquareButton.qml, недоступны для объектов SquareButton, так как значения id доступны только в пределах области видимости компонента, в котором объявлен компонент. Объект SquareButton выше не может ссылаться на mouseArea для ссылки на дочерний элемент MouseArea, и если у него был бы id со значением root вместо squareButton, это не конфликтовало бы со значением id корневого объекта, определённого в SquareButton.qml, поскольку они объявлены в разных областях видимости.