Область видимости и разрешение имен

Связывания свойств QML, встроенные функции и импортированные JavaScript-файлы выполняются в области видимости JavaScript. Область видимости определяет, к каким переменным может получить доступ выражение, и какую переменную следует использовать при конфликте имен.

Поскольку встроенный механизм областей видимости JavaScript очень прост, QML расширяет его, чтобы он лучше соответствовал расширениям языка QML.

Область видимости JavaScript

Расширения областей видимости QML не влияют на естественную систему областей видимости JavaScript. Разработчики JavaScript могут использовать свои существующие знания при программировании функций, связывании свойств или импортированных JavaScript-файлов в QML.

В следующем примере метод addConstant() добавит 13 к переданному параметру, как ожидается от разработчика, независимо от значения свойств объекта QML a и b.

QtObject {
    property int a: 3
    property int b: 9

    function addConstant(b) {
        var a = 13;
        return b + a;
    }
}

То, что QML соблюдает стандартные правила областей видимости JavaScript, относится и к связываниям. Это совершенно ужасное связывание назначит значение 12 свойству объекта QML a.

QtObject {
    property int a

    a: { var a = 12; a; }
}

Каждое JavaScript-выражение, функция или файл в QML имеют собственный уникальный объект переменных. Локальные переменные, объявленные в одном, никогда не будут конфликтовать с локальными переменными, объявленными в другом.

Имена типов и импортированные JavaScript-файлы

Документы QML включают инструкции импорта, которые определяют имена типов и JavaScript-файлы, видимые для документа. В дополнение к их использованию в самом объявлении QML, имена типов используются кодом JavaScript при обращении к присоединённым свойствам и значениям перечислений.

Эффект импорта распространяется на каждое связывание свойств и JavaScript-функцию в документе QML, даже на те, что находятся во вложенных встроенных компонентах. Следующий пример показывает простой QML-файл, который обращается к некоторым значениям перечислений и вызывает импортированную JavaScript-функцию.

import QtQuick 2.0
import "code.js" as Code

ListView {
    snapMode: ListView.SnapToItem

    delegate: Component {
        Text {
            elide: Text.ElideMiddle
            text: "A really, really long string that will require eliding."
            color: Code.defaultColor()
        }
    }
}

Объект области видимости связывания

Объект, имеющий связывание свойства, известен как объект области видимости связывания. В следующем примере объектом области видимости связывания является объект Item.

Item {
    anchors.left: parent.left
}

Связывания имеют доступ к свойствам объекта области видимости без квалификации. В предыдущем примере связывание обращается к свойству Item parent напрямую, без необходимости какого-либо префикса объекта. QML вводит более структурированный, объектно-ориентированный подход к JavaScript и, следовательно, не требует использования JavaScript-свойства this.

При обращении к присоединённым свойствам из связываний необходимо быть осторожными из-за их взаимодействия с объектом области видимости. Понятие присоединённых свойств существует для всех объектов, даже если они влияют только на подмножество этих объектов. Следовательно, неопределённый доступ к присоединённым свойствам всегда будет разрешаться как присоединённое свойство объекта области видимости, что не всегда соответствует намерениям программиста.

Например, тип PathView присоединяет свойства интерполированных значений к своим делегатам в зависимости от их позиции в пути. Поскольку PathView осмысленно присоединяет эти свойства только к корневому объекту в делегате, любой дочерний объект, обращающийся к ним, должен явно указывать корневой объект, как показано ниже.

PathView {
    delegate: Component {
        Rectangle {
            id: root
            Image {
                scale: root.PathView.scale
            }
        }
    }
}

Если объект Image опустит префикс root, он непреднамеренно обратится к неинициализированному присоединённому свойству PathView.scale к самому себе.

Область видимости компонента

Каждый QML-компонент в QML-документе определяет логическую область видимости. Каждый документ имеет по меньшей мере один корневой компонент, но также может иметь и другие встроенные подкомпоненты. Область видимости компонента представляет собой объединение идентификаторов объектов внутри компонента и свойств корневого объекта компонента.

Item {
    property string title

    Text {
        id: titletype
        text: "<b>" + title + "</b>"
        font.pixelSize: 22
        anchors.top: parent.top
    }

    Text {
        text: titletype.text
        font.pixelSize: 18
        anchors.bottom: parent.bottom
    }
}

Приведённый выше пример демонстрирует простой QML-компонент, который отображает строку богатого текста заголовка в верхней части и меньшую копию того же текста в нижней части. Первый тип Text напрямую обращается к свойству компонента title при формировании отображаемого текста. Прямой доступ к свойствам корневого типа упрощает распределение данных по всему компоненту.

Второй тип Text использует идентификатор для прямого доступа к тексту первого. Идентификаторы явно указываются программистом QML, поэтому они всегда имеют приоритет над другими именами свойств (за исключением тех, что находятся в области видимости JavaScript).

Например, в маловероятном случае, если объект области видимости связывания объект области видимости имел свойство titletype в предыдущем примере, идентификатор titletype по-прежнему будет иметь приоритет.

Иерархия экземпляров компонента

В QML экземпляры компонента связывают свои области видимости компонента, образуя иерархию областей видимости. Экземпляры компонента могут напрямую обращаться к областям видимости компонента своих предков.

Проще всего продемонстрировать это на примере встроенных подкомпонентов, области видимости которых неявно задаются как дочерние элементы внешнего компонента.

Item {
    property color defaultColor: "blue"

    ListView {
        delegate: Component {
            Rectangle {
                color: defaultColor
            }
        }
    }
}

Иерархия экземпляров компонента позволяет экземплярам компонента делегата получать доступ к свойству defaultColor типа Item. Конечно, если бы компонент делегата имел свойство с именем defaultColor, оно имело бы приоритет.

Иерархия областей видимости экземпляров компонента распространяется и на вневложенные компоненты. В следующем примере компонент TitlePage.qml создаёт два экземпляра TitleText. Несмотря на то, что тип TitleText находится в отдельном файле, он по-прежнему имеет доступ к свойству title при использовании внутри TitlePage. QML — язык с динамической областью видимости; в зависимости от места использования свойство title может быть разрешено по-разному.

// TitlePage.qml
import QtQuick 2.0
Item {
    property string title

    TitleText {
        size: 22
        anchors.top: parent.top
    }

    TitleText {
        size: 18
        anchors.bottom: parent.bottom
    }
}

// TitleText.qml
import QtQuick 2.0
Text {
    property int size
    text: "<b>" + title + "</b>"
    font.pixelSize: size
}

Динамическая область видимости очень мощная, но ею необходимо пользоваться осторожно, чтобы поведение кода QML не стало трудно предсказуемым. Как правило, её следует использовать только в тех случаях, когда два компонента уже тесно связаны другим способом. При создании многократно используемых компонентов предпочтительнее использовать интерфейсы свойств, например, так:

// TitlePage.qml
import QtQuick 2.0
Item {
    id: root
    property string title

    TitleText {
        title: root.title
        size: 22
        anchors.top: parent.top
    }

    TitleText {
        title: root.title
        size: 18
        anchors.bottom: parent.bottom
    }
}

// TitleText.qml
import QtQuick 2.0
Text {
    property string title
    property int size

    text: "<b>" + title + "</b>"
    font.pixelSize: size
}

Переопределённые свойства

QML позволяет именам свойств, определённых в объявлении объекта, переопределяться свойствами, объявленными в другом объявлении объекта, которое расширяет первый. Например:

// Displayable.qml
import QtQuick 2.0
Item {
    property string title
    property string detail

    Text {
        text: "<b>" + title + "</b><br>" + detail
    }

    function getTitle() { return title }
    function setTitle(newTitle) { title = newTitle }
}

// Person.qml
import QtQuick 2.0
Displayable {
    property string title
    property string firstName
    property string lastName

    function fullName()  { return title + " " + firstName + " " + lastName }
}

Здесь имя title присвоено как заголовку выходного текста для Displayable, так и почётной должности объекта Person.

Переопределённое свойство разрешается в зависимости от области видимости, в которой оно упоминается. В области видимости компонента Person или из внешней области видимости, ссылающейся на экземпляр компонента Person, title разрешается как свойство, объявленное в Person.qml. Функция fullName будет ссылаться на свойство title , объявленное в Person.

Однако внутри компонента Displayable title ссылается на свойство, объявленное в Displayable.qml. Функции getTitle() и setTitle() и связывание свойства text объекта Text будут ссылаться на свойство title , объявленное в компоненте Displayable.

Несмотря на одинаковое имя, эти два свойства полностью независимы. Обработчик сигнала onChanged для одного из свойств не будет срабатывать при изменении другого свойства с тем же именем. Псевдоним для любого свойства будет ссылаться на то или другое, но не на оба.

Объект глобальной области видимости JavaScript

QML запрещает имена типов, идентификаторов и свойств, которые конфликтуют со свойствами глобального объекта, чтобы избежать путаницы. Программисты могут быть уверены, что Math.min(10, 9) всегда будет работать как ожидается!

Дополнительную информацию см. в разделе JavaScript Host Environment.