Класс QMacNativeWidget

Класс QMacNativeWidget предоставляет виджет для macOS, который обеспечивает способ размещения виджетов Qt в иерархии Cocoa. Подробнее...

Этот класс был представлен в Qt 4.5.

• Список всех членов, включая унаследованные

Открытые функции

Переопределённые открытые функции

Переопределённые защищённые функции

Подробное описание

В macOS существует различие между окном и представлением; обычно выражаемые как виджеты в Qt. Qt делает предположения о своей иерархии родитель-потомки, что усложняет размещение произвольного виджета Qt в иерархии «обычных» представлений из фреймворков Apple. QMacNativeWidget устраняет разрыв между представлениями и окнами и позволяет разместить иерархию виджетов Qt в окне или представлении, не являющемся Qt.

QMacNativeWidget имитирует окно (т.е. isWindow() вернёт true), но не может быть показано самостоятельно. Оно должно быть размещено в окне при создании или позже через вызов нативного кода.

Вот пример, показывающий, как поместить QPushButton в NSWindow:

    NSAutoreleasePool *pool = [[NSAutoreleasePool alloc] init];
    NSWindow *window = [[NSWindow alloc] initWithContentRect:NSMakeRect(200, app.desktop()->height() - 200, 239, 200)
                        styleMask:NSTitledWindowMask | NSClosableWindowMask
                                  | NSMiniaturizableWindowMask | NSResizableWindowMask
                        backing:NSBackingStoreBuffered defer:NO];

    QMacNativeWidget *nativeWidget = new QMacNativeWidget();
    nativeWidget->move(0, 0);
    nativeWidget->setPalette(QPalette(Qt::red));
    nativeWidget->setAutoFillBackground(true);
    QVBoxLayout *layout = new QVBoxLayout();
    QPushButton *pushButton = new QPushButton("An Embedded Qt Button!", nativeWidget);
    pushButton->setAttribute(Qt::WA_LayoutUsesWidgetRect); // Don't use the layout rect calculated from QMacStyle.
    layout->addWidget(pushButton);
    nativeWidget->setLayout(layout);

    // Adjust Cocoa layouts
    NSView *nativeWidgetView = reinterpret_cast<NSView *>(nativeWidget->winId());
    NSView *contentView = [window contentView];
    [contentView setAutoresizesSubviews:YES];
    [nativeWidgetView setAutoresizingMask:NSViewWidthSizable | NSViewHeightSizable];
    [nativeWidgetView setAutoresizesSubviews:YES];
    NSView *pushButtonView = reinterpret_cast<NSView *>(pushButton->winId());
    [pushButtonView setAutoresizingMask:NSViewWidthSizable];

    // Add the nativeWidget to the window.
    [contentView addSubview:nativeWidgetView positioned:NSWindowAbove relativeTo:nil];
    nativeWidget->show();
    pushButton->show();

    // Show the window.
    [window makeKeyAndOrderFront:window];
    [pool release];

Обратите внимание, что QMacNativeWidget требует знаний Cocoa. Всё, что он делает, — это помещает иерархию Qt в окно, не принадлежащее Qt. Затем программист отвечает за правильное размещение в окне и корректную обработку событий.

Документация по членам функций

QMacNativeWidget::QMacNativeWidget(NSView *parentView = nullptr)

Создаёт QMacNativeWidget с parentView в качестве его «родительского представления» (т.е. родителя). parentView — указатель NSView.

[virtual] QMacNativeWidget::~QMacNativeWidget()

Уничтожает QMacNativeWidget.

[override virtual protected] bool QMacNativeWidget::event(QEvent *ev)

Переопределяет: QWidget::event(QEvent *event).

NSView *QMacNativeWidget::nativeView() const

Возвращает нативное представление, поддерживающее QMacNativeWidget.

[override virtual] QSize QMacNativeWidget::sizeHint() const

Переопределяет функцию доступа к свойству: QWidget::sizeHint.