Тип QML Menu

Встроенное меню. Подробнее...

• Список всех членов, включая унаследованные
• Устаревшие члены

Свойства

• data : list<Object>
• enabled : bool
• font : font
• items : list<MenuItem>
• menuBar : MenuBar
• menuItem : MenuItem
• minimumWidth : int
• parentMenu : Menu
• systemTrayIcon : SystemTrayIcon
• title : string
• type : перечисление
• visible : bool

Сигналы

• aboutToHide()
• aboutToShow()

Методы

• void addItem(item)
• void addMenu(submenu)
• void clear()
• void close()
• void insertItem(index, MenuItem item)
• void insertMenu(index, Menu submenu)
• void open(target, MenuItem item)
• void open(item)
• void removeItem(item)
• void removeMenu(submenu)

Подробное описание

Тип Menu предоставляет API QML для всплывающих меню нативной платформы.

Menu можно использовать в MenuBar или как самостоятельное контекстное меню. Следующий пример демонстрирует, как открыть контекстное меню при нажатии правой кнопкой мыши:

MouseArea {
    anchors.fill: parent
    acceptedButtons: Qt.RightButton
    onClicked: zoomMenu.open()
}

Menu {
    id: zoomMenu

    MenuItem {
        text: qsTr("Zoom In")
        shortcut: StandardKey.ZoomIn
        onTriggered: zoomIn()
    }

    MenuItem {
        text: qsTr("Zoom Out")
        shortcut: StandardKey.ZoomOut
        onTriggered: zoomOut()
    }
}

Подменю

Для создания подменю объявите Menu как дочерний элемент другого Menu:

Menu {
    title: qsTr("Edit")

    Menu {
        title: qsTr("Advanced")

        MenuItem {
            text: qsTr("Auto-indent Selection")
            onTriggered: autoIndentSelection()
        }

        MenuItem {
            text: qsTr("Rewrap Paragraph")
            onTriggered: rewrapParagraph()
        }
    }
}

Динамическое создание элементов меню

Возможна динамическая генерация элементов меню. Одним из самых простых способов является использование Instantiator. Например, для реализации подменю «Недавние файлы», где элементы основаны на списке файлов, хранящихся в настройках, можно использовать следующий код:

Menu {
    title: qsTr("File")

    Menu {
        id: recentFilesSubMenu
        title: qsTr("Recent Files")
        enabled: recentFilesInstantiator.count > 0

        Instantiator {
            id: recentFilesInstantiator
            model: settings.recentFiles
            delegate: MenuItem {
                text: settings.displayableFilePath(modelData)
                onTriggered: loadFile(modelData)
            }

            onObjectAdded: recentFilesSubMenu.insertItem(index, object)
            onObjectRemoved: recentFilesSubMenu.removeItem(object)
        }

        MenuSeparator {}

        MenuItem {
            text: qsTr("Clear Recent Files")
            onTriggered: settings.clearRecentFiles()
        }
    }
}

Доступность

В настоящее время меню нативной платформы доступно на следующих платформах:

• macOS
• iOS
• Android
• Linux (доступно только в качестве самостоятельного контекстного меню при запуске с темой платформы GTK+)

Модуль Qt Labs Platform использует Qt Widgets в качестве резервного варианта на платформах, где нет нативного исполнения. Поэтому приложения, использующие типы из модуля Qt Labs Platform, должны быть связаны с QtWidgets и использовать QApplication вместо QGuiApplication.

Для связи с библиотекой QtWidgets добавьте следующее в файл проекта qmake:

QT += widgets

Создайте экземпляр QApplication в main():

#include <QApplication>
#include <QQmlApplicationEngine>

int main(int argc, char *argv[])
{
    QApplication::setAttribute(Qt::AA_EnableHighDpiScaling);
    QApplication app(argc, argv);
    QQmlApplicationEngine engine;
    engine.load(QUrl(QStringLiteral("qrc:/main.qml")));
    return app.exec();
}

Примечание: Типы в модулях Qt.labs не гарантируют сохранение совместимости в будущих версиях.

См. также MenuItem, MenuSeparator и MenuBar.

Документация по свойствам

[по умолчанию] data : list<Object>

Это свойство по умолчанию содержит список всех объектов, объявленных как дочерние элементы меню. Свойство data включает объекты, которые не являются экземплярами MenuItem, такие как Timer и QtObject.

См. также items.

enabled : bool

Это свойство указывает, включено ли меню. Значение по умолчанию равно true.

font : font

Это свойство содержит шрифт меню.

См. также text.

items : list<MenuItem>

Это свойство содержит список элементов в меню.

[только для чтения] menuBar : MenuBar

Это свойство содержит панель меню, к которой принадлежит меню, или null если меню не находится на панели меню.

[только для чтения] menuItem : MenuItem

Это свойство содержит элемент, представляющий меню (в родительском меню).

minimumWidth : int

Это свойство содержит минимальную ширину меню. Значение по умолчанию равно -1 (минимальная ширина не задана).

[только для чтения] parentMenu : Menu

Это свойство содержит родительское меню, к которому принадлежит меню, или null если меню не является подменю.

[только для чтения] systemTrayIcon : SystemTrayIcon

Это свойство содержит значок системного трея, к которому принадлежит меню, или null если меню не находится в значке системного трея.

title : string

Это свойство содержит заголовок меню.

type : перечисление

Это свойство содержит тип меню.

Доступные значения:

visible : bool

Это свойство указывает, отображается ли меню. Значение по умолчанию равно true.

Документация по сигналам

aboutToHide()

Этот сигнал генерируется, когда меню готовится к скрытию от пользователя.

aboutToShow()

Этот сигнал генерируется, когда меню готовится к отображению пользователю.

Документация по методам

void addItem(item)

Добавляет item в конец меню.

void addMenu(submenu)

Добавляет submenu в конец меню.

void clear()

Удаляет все элементы из меню.

void close()

Закрывает меню.

void insertItem(index, MenuItem item)

Вставляет item в указанный index в меню.

void insertMenu(index, Menu submenu)

Вставляет submenu в указанный index в меню.

void open(target, MenuItem item)

Открывает меню в указанном элементе target, в зависимости от элемента item.

void open(item)

Открывает меню в текущей позиции курсора мыши, необязательно выравнивая его с элементом меню.

void removeItem(item)

Удаляет элемент меню из меню.

void removeMenu(submenu)

Удаляет подменю из меню.