Тип QML DelegateModel

Инкапсулирует модель и делегат. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• count : int
• delegate : Component
• filterOnGroup : string
• groups : list<DelegateModelGroup>
• items : DelegateModelGroup
• model : model
• parts : object
• persistedItems : DelegateModelGroup
• rootIndex : QModelIndex

Присоединённые свойства

• groups : stringlist
• inItems : int
• inPersistedItems : int
• isUnresolved : bool
• itemsIndex : int
• model : model
• persistedItemsIndex : int

Методы

• QModelIndex modelIndex(index)
• QModelIndex parentModelIndex()

Подробное описание

Тип DelegateModel инкапсулирует модель и делегат, который будет создан для элементов в модели.

Обычно создавать DelegateModel не требуется. Однако, он может быть полезен для манипулирования и доступа к modelIndex, когда в качестве модели используется подкласс QAbstractItemModel. Также, DelegateModel используется вместе с Package для предоставления делегатов для нескольких представлений, и с DelegateModelGroup для сортировки и фильтрации элементов делегата.

Пример ниже демонстрирует использование DelegateModel с ListView.

import QtQuick 2.0
import QtQml.Models 2.2

Rectangle {
    width: 200; height: 100

    DelegateModel {
        id: visualModel
        model: ListModel {
            ListElement { name: "Apple" }
            ListElement { name: "Orange" }
        }
        delegate: Rectangle {
            height: 25
            width: 100
            Text { text: "Name: " + name}
        }
    }

    ListView {
        anchors.fill: parent
        model: visualModel
    }
}

Документация по свойствам

count : int

delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, созданный представлением. Индекс представлен как доступное index свойство. Свойства модели также доступны в зависимости от типа модели данных.

filterOnGroup : string

Это свойство содержит имя группы, используемой для фильтрации модели делегата.

Только элементы, принадлежащие этой группе, видны представлению.

По умолчанию это группа items.

groups : список<DelegateModelGroup>

Это свойство содержит определения групп модели делегата.

Группы определяют подмножество элементов в модели делегата и могут использоваться для фильтрации модели.

Для каждой группы, определенной в DelegateModel, к каждому элементу делегата добавляются два присоединённых свойства. Первое в форме DelegateModel.inGroupName указывает, принадлежит ли элемент группе, а второе DelegateModel.groupNameIndex содержит индекс элемента в этой группе.

Следующий пример демонстрирует использование групп для выбора элементов в модели.

import QtQuick 2.0
import QtQml.Models 2.2

Rectangle {
    width: 200; height: 100

    DelegateModel {
        id: visualModel
        model: ListModel {
            ListElement { name: "Apple" }
            ListElement { name: "Orange" }
        }

        groups: [
            DelegateModelGroup { name: "selected" }
        ]

        delegate: Rectangle {
            id: item
            height: 25
            width: 200
            Text {
                text: {
                    var text = "Name: " + name
                    if (item.DelegateModel.inSelected)
                        text += " (" + item.DelegateModel.selectedIndex + ")"
                    return text;
                }
            }
            MouseArea {
                anchors.fill: parent
                onClicked: item.DelegateModel.inSelected = !item.DelegateModel.inSelected
            }
        }
    }

    ListView {
        anchors.fill: parent
        model: visualModel
    }
}

items : DelegateModelGroup

Это свойство содержит группу по умолчанию, к которой добавляются все новые элементы.

model : model

Это свойство содержит модель, предоставляющую данные для DelegateModel.

Модель предоставляет набор данных, используемых для создания элементов для представления. Для больших или динамических наборов данных модель обычно предоставляется объектом модели C++. Объект модели C++ должен быть подклассом QAbstractItemModel или простым списком.

Модели также могут создаваться непосредственно в QML, используя ListModel или XmlListModel.

См. также Модели данных.

parts : object

Свойство parts выбирает DelegateModel, который создаёт делегаты из части с указанным именем. Используется совместно с типом Package.

Например, код ниже выбирает модель, которая создаёт делегаты с именем list из Package:

DelegateModel {
    id: visualModel
    delegate: Package {
        Item { Package.name: "list" }
    }
    model: myModel
}

ListView {
    width: 200; height:200
    model: visualModel.parts.list
}

См. также Package.

persistedItems : DelegateModelGroup

Это свойство содержит группу сохранённых элементов модели делегата.

Элементы в этой группе не уничтожаются при освобождении представлением, вместо этого они сохраняются до удаления из группы.

Элемент может быть удален из группы persistedItems, установив свойство DelegateModel.inPersistedItems в значение false. Если элемент не используется представлением в этот момент, он будет уничтожен. Добавление элемента в эту группу не создаёт новый экземпляр.

Элементы, возвращаемые функцией QtQml.Models::DelegateModelGroup::create(), автоматически добавляются в эту группу.

rootIndex : QModelIndex

QAbstractItemModel предоставляет иерархическое дерево данных, в то время как QML работает только со списком данных. rootIndex позволяет предоставить потомков любого узла в QAbstractItemModel с помощью этой модели.

Это свойство влияет только на модели типа QAbstractItemModel, которые являются иерархическими (например, модель дерева).

Например, вот простой интерактивный файловый браузер. Когда кликают по имени каталога, rootIndex представления устанавливается в узел QModelIndex нажатого каталога, обновляя представление, чтобы показать содержимое нового каталога.

main.cpp:

int main(int argc, char ** argv)
{
    QApplication app(argc, argv);

    QQuickView view;

    QDirModel model;
    view.rootContext()->setContextProperty("dirModel", &model);

    view.setSource(QUrl::fromLocalFile("view.qml"));
    view.show();

    return app.exec();
}

view.qml:

import QtQuick 2.0
import QtQml.Models 2.2

ListView {
    id: view
    width: 300
    height: 400

    model: DelegateModel {
        model: dirModel

        delegate: Rectangle {
            width: 200; height: 25
            Text { text: filePath }

            MouseArea {
                anchors.fill: parent
                onClicked: {
                    if (model.hasModelChildren)
                        view.model.rootIndex = view.model.modelIndex(index)
                }
            }
        }
    }
}

Если model — подкласс QAbstractItemModel, делегат также может ссылаться на hasModelChildren свойство (опционально с префиксом model.), которое указывает, есть ли у элемента модели делегата дочерние узлы.

См. также modelIndex() и parentModelIndex().

Документация по присоединённым свойствам

DelegateModel.groups : stringlist

Это присоединённое свойство содержит имена DelegateModelGroups, к которым принадлежит элемент.

Оно присоединяется к каждому экземпляру делегата.

DelegateModel.inItems : int

Это присоединённое свойство содержит значение, указывающее, принадлежит ли элемент группе по умолчанию items DelegateModelGroup.

Изменение этого свойства добавит или удалит элемент из группы items.

Оно присоединяется к каждому экземпляру делегата.

DelegateModel.inPersistedItems : int

Это присоединённое свойство содержит значение, указывающее, принадлежит ли элемент группе persistedItems DelegateModelGroup.

Изменение этого свойства добавит или удалит элемент из группы items. Изменяйте осторожно, так как удаление элемента из группы persistedItems уничтожит текущий экземпляр, если он не используется моделью.

Оно присоединяется к каждому экземпляру делегата.

DelegateModel.isUnresolved : bool

Это присоединённое свойство указывает, связан ли визуальный элемент с индексом модели данных. Возвращает true, если элемент не связан с моделью, и false, если связан.

Неразрешённый элемент может быть связан с моделью данных с помощью функции DelegateModelGroup::resolve().

Оно присоединяется к каждому экземпляру делегата.

DelegateModel.itemsIndex : int

Это присоединённое свойство содержит индекс элемента в стандартной группе items DelegateModelGroup.

Оно присоединено к каждому экземпляру делегата.

DelegateModel.model : model

Это присоединённое свойство содержит модель данных, к которой относится этот экземпляр делегата.

Оно присоединено к каждому экземпляру делегата.

DelegateModel.persistedItemsIndex : int

Это присоединённое свойство содержит индекс элемента в группе persistedItems DelegateModelGroup.

Оно присоединено к каждому экземпляру делегата.

Документация по методам

QModelIndex modelIndex(index)

QAbstractItemModel предоставляет иерархическое дерево данных, тогда как QML работает только со списками данных. Эта функция помогает использовать модели дерева в QML.

Возвращает QModelIndex для указанного index. Это значение можно присвоить rootIndex.

См. также rootIndex.

QModelIndex parentModelIndex()

QAbstractItemModel предоставляет иерархическое дерево данных, тогда как QML работает только со списками данных. Эта функция помогает использовать модели дерева в QML.

Возвращает QModelIndex для родительского элемента текущего rootIndex. Это значение можно присвоить rootIndex.

См. также rootIndex.