Тип QML Action

Action предоставляет абстрактное действие пользовательского интерфейса, которое может быть привязано к элементам. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• checkable : bool
• checked : bool
• enabled : bool
• exclusiveGroup : ExclusiveGroup
• iconName : string
• iconSource : url
• shortcut : keysequence
• text : string
• tooltip : string

Сигналы

• toggled(checked)
• triggered(source)

Методы

• void trigger(source)

Подробное описание

Во многих приложениях многие общие команды могут вызываться через меню, кнопки панели инструментов и сочетания клавиш. Поскольку пользователь ожидает, что каждая команда будет выполняться одинаково независимо от используемого пользовательского интерфейса, полезно представлять каждую команду как действие.

Действие может быть привязано к элементу меню и кнопке панели инструментов, и оно автоматически будет поддерживать их синхронизацию. Например, в текстовом процессоре, если пользователь нажимает кнопку «Полужирный» на панели инструментов, элемент меню «Полужирный» автоматически будет отмечен.

QtQuick Controls поддерживает действия в Button, ToolButton и MenuItem.

    ...
    Action {
        id: copyAction
        text: "&Copy"
        shortcut: StandardKey.Copy
        iconName: "edit-copy"
        enabled: (!!activeFocusItem && !!activeFocusItem["copy"])
        onTriggered: activeFocusItem.copy()
    }

    Action {
        id: cutAction
        text: "Cu&t"
        shortcut: StandardKey.Cut
        iconName: "edit-cut"
        enabled: (!!activeFocusItem && !!activeFocusItem["cut"])
        onTriggered: activeFocusItem.cut()
    }

    Action {
        id: pasteAction
        text: "&Paste"
        shortcut: StandardKey.Paste
        iconName: "edit-paste"
        enabled: (!!activeFocusItem && !!activeFocusItem["paste"])
        onTriggered: activeFocusItem.paste()
    }

    toolBar: ToolBar {
        RowLayout {
            anchors.fill: parent
            anchors.margins: spacing
            Label {
                text: UI.label
            }
            Item { Layout.fillWidth: true }
            CheckBox {
                id: enabler
                text: "Enabled"
                checked: true
            }
        }
    }

    menuBar: MenuBar {
        Menu {
            title: "&File"
            MenuItem {
                text: "E&xit"
                shortcut: StandardKey.Quit
                onTriggered: Qt.quit()
            }
        }
        Menu {
            title: "&Edit"
            visible: tabView.currentIndex == 2
            MenuItem { action: cutAction }
            MenuItem { action: copyAction }
            MenuItem { action: pasteAction }
        }
        Menu {
            title: "&Help"
            MenuItem {
                text: "About..."
                onTriggered: aboutDialog.open()
            }
        }
    }
    ...

Документация по свойствам

checkable : bool

Указывает, может ли элемент меню быть отмеченным или переключаться. По умолчанию false.

См. также checked и exclusiveGroup.

checked : bool

Если действие checkable, это свойство отражает его состояние. По умолчанию false. Его значение также ложно, пока checkable ложно.

См. также toggled и exclusiveGroup.

enabled : bool

Указывает, включено ли действие и может ли оно быть выполнено. По умолчанию true.

См. также trigger() и triggered.

exclusiveGroup : ExclusiveGroup

Если действие checkable, к нему может быть прикреплена группа ExclusiveGroup. Все действия, которые используют одну и ту же группу исключений, становятся взаимоисключающими и выбираемыми, что означает, что только последнее отмеченное действие фактически будет отмечено.

По умолчанию null, что означает, что не ожидается исключительное поведение.

См. также checkable и checked.

iconName : string

Устанавливает имя значка для действия. Это выберет значок с заданным именем из текущей темы.

По умолчанию пустая строка.

Примечание: для этого свойства требуется QApplication.

iconSource : url

Устанавливает URL-адрес файла или ресурса значка для действия. По умолчанию пустой URL.

shortcut : keysequence

Сочетание клавиш, привязанное к действию. Сочетание клавиш может быть строкой или стандартной клавишей.

По умолчанию пустая строка.

Action {
    id: copyAction
    text: qsTr("&Copy")
    shortcut: StandardKey.Copy
}

text : string

Текст для действия. Этот текст будет отображаться как текст кнопки или как заголовок в элементе меню.

Мемоники поддерживаются путем добавления префикса & к букве сочетания клавиш. Например, "\&Open" привяжет сочетание клавиш Alt-O к элементу меню "Open". Обратите внимание, что не все платформы поддерживают мемоники.

По умолчанию пустая строка.

tooltip : string

Подсказка, которая будет отображаться при наведении курсора на элемент управления, привязанный к этому действию. Не все элементы управления поддерживают подсказки на всех платформах, особенно MenuItem.

По умолчанию пустая строка.

Документация по сигналам

toggled(checked)

Вызывается всякий раз, когда свойство checked действия изменяется. Это обычно происходит одновременно с triggered.

Соответствующий обработчик — onToggled.

См. также checked.

triggered(source)

Вызывается, когда элемент меню или связанное с ним действие активируются. Включает объект (source), который вызвал событие, если это актуально (например, Button или MenuItem). Вам не нужно вызывать этот сигнал, используйте trigger() вместо этого.

Соответствующий обработчик — onTriggered.

Документация по методам

void trigger(source)

Вызовет сигнал triggered в source, если действие включено. Вы можете указать объект-источник, если действие получит выгоду от знания источника запуска (например, для аналитики). Также вызовет сигнал toggled, если оно checkable.