Тип QML ActionGroup

Группирует действия вместе. Подробнее...

• Список всех членов, включая наследуемые члены

Свойства

• actions : список<Action>
• checkedAction : Action
• enabled : bool
• exclusive : bool

Присоединенные свойства

• group : ActionGroup

Сигналы

• triggered(action)

Методы

• void addAction(action)
• void removeAction(action)

Подробное описание

ActionGroup — это невидимая группа действий. Взаимоисключающая группа действий используется с действиями, где можно выбрать только один вариант за раз.

Самый простой способ использования ActionGroup — объявление действий как дочерних элементов группы.

ActionGroup {
    id: alignmentGroup

    Action {
        checked: true
        checkable: true
        text: qsTr("Left")
    }

    Action {
        checkable: true
        text: qsTr("Center")
    }

    Action {
        checkable: true
        text: qsTr("Right")
    }
}

В качестве альтернативы, присоединенное свойство group позволяет объявлять действия в других местах и назначать их определенной группе.

ActionGroup { id: alignmentGroup }

Action {
    checked: true
    checkable: true
    text: qsTr("Left")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Center")
    ActionGroup.group: alignmentGroup
}

Action {
    checkable: true
    text: qsTr("Right")
    ActionGroup.group: alignmentGroup
}

Более сложные случаи можно обработать, используя методы addAction() и removeAction().

См. также Action и ButtonGroup.

Документация по свойствам

[default] actions : список<Action>

Это свойство содержит список действий в группе.

См. также group.

checkedAction : Action

Это свойство содержит текущее выбранное действие в исключающей группе или null, если такового нет или группа не является исключающей.

По умолчанию это первое выбранное действие, добавленное в исключающую группу действий.

См. также exclusive.

enabled : bool

Это свойство содержит информацию о том, включена ли группа действий. Значение по умолчанию — true.

Если это свойство false, то все действия в группе отключены. Если это свойство true, все действия в группе включены, если явно не отключены.

exclusive : bool

Это свойство содержит информацию о том, является ли группа действий исключающей. Значение по умолчанию — true.

Если это свойство true, то только одно действие в группе может быть выбрано в любой момент. Пользователь может активировать любое действие для его выбора, и это действие заменит существующее как выбранное действие в группе.

В исключающей группе пользователь не может снять выбор с текущего выбранного действия, активируя его; вместо этого необходимо активировать другое действие в группе, чтобы установить новое выбранное действие для этой группы.

В неисключающей группе проверка и снятие проверки действия не влияют на другие действия в группе. Кроме того, значение свойства checkedAction равно null.

Документация по присоединенному свойству

ActionGroup.group : ActionGroup

Это свойство присоединяет действие к группе действий.

ActionGroup { id: group }

Action {
    checked: true
    text: qsTr("Option A")
    ActionGroup.group: group
}

Action {
    text: qsTr("Option B")
    ActionGroup.group: group
}

См. также actions.

Документация по сигналам

triggered(action)

Этот сигнал отправляется, когда действие action в группе было активировано.

Этот сигнал удобен для реализации обработчика общего сигнала для всех действий в одной группе.

ActionGroup {
    onTriggered: console.log("triggered:", action.text)

    Action { text: "First" }
    Action { text: "Second" }
    Action { text: "Third" }
}

См. также Action::triggered().

Документация по методам

void addAction(action)

Добавляет действие action в группу действий.

Примечание: Ручное добавление объектов в группу действий обычно не требуется. Свойства actions и присоединенное свойство group обеспечивают удобный и декларативный синтаксис.

См. также actions и group.

void removeAction(action)

Удаляет действие action из группы действий.

Примечание: Ручное удаление объектов из группы действий обычно не требуется. Свойства actions и присоединенное свойство group обеспечивают удобный и декларативный синтаксис.

См. также actions и group.