Тип QML CheckBox

Кнопка выбора, которая может быть переключена в включенное или выключенное состояние. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• checkState : перечисление
• nextCheckState : функция
• tristate : bool

Подробное описание

CheckBox представляет собой кнопку выбора, которая может быть переключена в включенное (выбрано) или выключенное (не выбрано) состояние. Кнопки выбора обычно используются для выбора одного или нескольких вариантов из набора вариантов. Для больших наборов вариантов, таких как те, что в списке, вместо этого следует использовать CheckDelegate.

CheckBox наследует свой API от AbstractButton. Например, состояние CheckBox можно установить свойством checked.

Помимо включенного и выключенного состояний, существует третье состояние: частично включено. Состояние частичного включения может быть включено с помощью свойства tristate. Это состояние указывает, что обычное состояние включено/выключено не может быть определено; обычно из-за других состояний, которые влияют на CheckBox. Это состояние полезно, например, при выборе нескольких дочерних узлов в дереве.

ColumnLayout {
    CheckBox {
        checked: true
        text: qsTr("First")
    }
    CheckBox {
        text: qsTr("Second")
    }
    CheckBox {
        checked: true
        text: qsTr("Third")
    }
}

Иерархические группы кнопок выбора можно управлять с помощью неисключающей ButtonGroup.

Следующий пример демонстрирует, как комбинированное состояние выбора дочерних элементов может быть привязано к состоянию выбора родительского CheckBox:

Column {
    ButtonGroup {
        id: childGroup
        exclusive: false
        checkState: parentBox.checkState
    }

    CheckBox {
        id: parentBox
        text: qsTr("Parent")
        checkState: childGroup.checkState
    }

    CheckBox {
        checked: true
        text: qsTr("Child 1")
        leftPadding: indicator.width
        ButtonGroup.group: childGroup
    }

    CheckBox {
        text: qsTr("Child 2")
        leftPadding: indicator.width
        ButtonGroup.group: childGroup
    }
}

См. также Настройка CheckBox, ButtonGroup и Кнопки управления.

Документация по свойствам

checkState : перечисление

Это свойство содержит состояние выбора CheckBox.

Доступные состояния:

См. также tristate и checked.

nextCheckState : функция

Это свойство содержит функцию обратного вызова, которая вызывается для определения следующего состояния выбора, когда пользователь интерактивно переключает CheckBox с помощью касания, мыши или клавиатуры.

По умолчанию обычный CheckBox циклически переключается между состояниями Qt.Unchecked и Qt.Checked, а CheckBox с тремя состояниями циклически переключается между состояниями Qt.Unchecked, Qt.PartiallyChecked, и Qt.Checked.

Функция обратного вызова nextCheckState может переопределить стандартное поведение. Следующий пример реализует CheckBox с тремя состояниями, который может отображать частично выбранное состояние в зависимости от внешних условий, но никогда не переключается в частично выбранное состояние при интерактивном переключении пользователем.

CheckBox {
    tristate: true
    checkState: allChildrenChecked ? Qt.Checked :
                   anyChildChecked ? Qt.PartiallyChecked : Qt.Unchecked

    nextCheckState: function() {
        if (checkState === Qt.Checked)
            return Qt.Unchecked
        else
            return Qt.Checked
    }
}

Это свойство было введено в QtQuick.Controls 2.4 (Qt 5.11).

tristate : bool

Это свойство определяет, является ли CheckBox CheckBox с тремя состояниями.

На анимации ниже первый CheckBox имеет три состояния:

По умолчанию это false, т.е. CheckBox имеет только два состояния.