Тип QML ParentAnimation

Анимирует изменения значений родительских элементов. Подробнее...

• Список всех членов, включая наследуемые члены

Свойства

• newParent : Item
• target : Item
• via : Item

Подробное описание

ParentAnimation используется для анимации изменения родительского элемента для Item.

Например, следующий ParentChange изменяет blueRect для того, чтобы стать потомком redRect при нажатии. Включение ParentAnimation, которое определяет NumberAnimation, который применяется во время перехода, гарантирует плавную анимацию элемента при перемещении к новому родителю:

import QtQuick 2.0

Item {
    width: 200; height: 100

    Rectangle {
        id: redRect
        width: 100; height: 100
        color: "red"
    }

    Rectangle {
        id: blueRect
        x: redRect.width
        width: 50; height: 50
        color: "blue"

        states: State {
            name: "reparented"
            ParentChange { target: blueRect; parent: redRect; x: 10; y: 10 }
        }

        transitions: Transition {
            ParentAnimation {
                NumberAnimation { properties: "x,y"; duration: 1000 }
            }
        }

        MouseArea { anchors.fill: parent; onClicked: blueRect.state = "reparented" }
    }
}

ParentAnimation может содержать любое количество анимаций. Эти анимации будут выполняться параллельно; для последовательного выполнения определите их внутри SequentialAnimation.

В некоторых случаях, например, при повторной установке родителя между элементами с включенным обрезанием, полезно анимировать изменение родительского элемента с помощью другого элемента, у которого не включено обрезание. Такой элемент можно установить с помощью свойства via.

ParentAnimation обычно используется в Transition в сочетании с ParentChange. При использовании таким образом, он анимирует все ParentChange, произошедшие во время изменения состояния. Это можно переопределить, задав конкретный целевой элемент с помощью свойства target.

См. также Анимация и переходы в Qt Quick и Примеры Qt Quick - Анимация.

Документация по свойствам

newParent : Item

Новый родитель, к которому следует выполнить анимацию.

Если ParentAnimation определен в Transition, это значение по умолчанию соответствует значению, определенному в конечном состоянии Transition.

target : Item

Элемент, который необходимо изменить родителя.

При использовании в переходе, если целевой элемент не указан, все случаи ParentChange анимируются с помощью ParentAnimation.

via : Item

Элемент, через который необходимо переместить. Это предоставляет способ выполнить анимацию без обрезания, когда старый родитель и новый родитель имеют включенное обрезание.

ParentAnimation {
    target: myItem
    via: topLevelItem
    // ...
}

Примечание: Это работает только тогда, когда ParentAnimation используется в Transition в сочетании с ParentChange.