Тип QML ProgressBarStyle

Предоставляет настраиваемую стилизацию для ProgressBar. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• background : Компонент
• control : ProgressBar
• currentProgress : вещественный
• panel : Компонент
• progress : Компонент

Подробное описание

Пример:

ProgressBar {
    value: slider.value
    style: ProgressBarStyle {
        background: Rectangle {
            radius: 2
            color: "lightgray"
            border.color: "gray"
            border.width: 1
            implicitWidth: 200
            implicitHeight: 24
        }
        progress: Rectangle {
            color: "lightsteelblue"
            border.color: "steelblue"
        }
    }
}

Обратите внимание, что приведенный выше пример несколько упрощен и не будет анимировать неопределенную полосу прогресса. Следующий фрагмент демонстрирует, как вы можете включить пользовательскую анимацию для неопределенного состояния.

progress: Rectangle {
    border.color: "steelblue"
    color: "lightsteelblue"

    // Indeterminate animation by animating alternating stripes:
    Item {
        anchors.fill: parent
        anchors.margins: 1
        visible: control.indeterminate
        clip: true
        Row {
            Repeater {
                Rectangle {
                    color: index % 2 ? "steelblue" : "lightsteelblue"
                    width: 20 ; height: control.height
                }
                model: control.width / 20 + 2
            }
            XAnimator on x {
                from: 0 ; to: -40
                loops: Animation.Infinite
                running: control.indeterminate
            }
        }
    }
}

Документация по свойствам

background : Component

Компонент фона для данного стиля.

Примечание: неявная ширина и неявная высота компонента background должны быть заданы.

[только для чтения] control : ProgressBar

ProgressBar, к которому прикреплен этот стиль.

[только для чтения] currentProgress : real

Значение в диапазоне [0-1], указывающее текущую степень выполнения.

panel : Component

Компонент панели для данного стиля.

progress : Component

Компонент прогресса для данного стиля.