Тип QML ScrollBar

Вертикальная или горизонтальная интерактивная полоса прокрутки. Подробнее...

• Список всех членов, включая наследуемые члены

Свойства

• active : bool
• horizontal : bool
• interactive : bool
• minimumSize : real
• orientation : перечисление
• policy : перечисление
• position : real
• pressed : bool
• size : real
• snapMode : перечисление
• stepSize : real
• vertical : bool
• visualPosition : real
• visualSize : real

Присоединенные свойства

• horizontal : ScrollBar
• vertical : ScrollBar

Методы

• void decrease()
• void increase()

Подробное описание

ScrollBar — это интерактивная полоса, которая может использоваться для прокрутки до определённой позиции. Полоса прокрутки может быть либо вертикальной, либо горизонтальной и может быть прикреплена к любому Flickable, например, ListView и GridView.

Flickable {
    // ...
    ScrollBar.vertical: ScrollBar { }
}

Присоединение ScrollBar к Flickable

Когда ScrollBar присоединена вертикально или горизонтально к Flickable, её геометрия и следующие свойства автоматически устанавливаются и обновляются как требуется:

• orientation
• position
• size
• active

Присоединённый ScrollBar переродится в целевой Flickable. Вертикально присоединённый ScrollBar изменяет свой размер на высоту Flickable и позиционируется по обе стороны от него в зависимости от направления макета. Горизонтально присоединённый ScrollBar изменяет свой размер на ширину Flickable и позиционируется внизу. Автоматическое управление геометрией можно отключить, указав другой родитель для присоединённого ScrollBar. Это может быть полезно, например, если ScrollBar должна быть расположена вне обрезающего Flickable. Это показано в следующем примере:

Flickable {
    id: flickable
    clip: true
    // ...
    ScrollBar.vertical: ScrollBar {
        parent: flickable.parent
        anchors.top: flickable.top
        anchors.left: flickable.right
        anchors.bottom: flickable.bottom
    }
}

Обратите внимание, что ScrollBar не фильтрует события нажатия клавиш Flickable, к которому она прикреплена. Следующий пример иллюстрирует, как реализовать прокрутку клавишами вверх и вниз:

Flickable {
    focus: true

    Keys.onUpPressed: scrollBar.decrease()
    Keys.onDownPressed: scrollBar.increase()

    ScrollBar.vertical: ScrollBar { id: scrollBar }
}

Связывание состояния активность горизонтальных и вертикальных полос прокрутки

Горизонтальная и вертикальная полосы прокрутки по умолчанию не разделяют состояние active друг с другом. Для сохранения видимости обеих полос при прокрутке в любом направлении установите двунаправленную привязку к состояниям активность, как показано в следующем примере:

Flickable {
    anchors.fill: parent

    contentWidth: parent.width * 2
    contentHeight: parent.height * 2

    ScrollBar.horizontal: ScrollBar { id: hbar; active: vbar.active }
    ScrollBar.vertical: ScrollBar { id: vbar; active: hbar.active }
}

Неприсоединённые полосы прокрутки

Можно создать экземпляр ScrollBar без использования API присоединённых свойств. Это полезно, когда поведение присоединённой полосы прокрутки недостаточно или Flickable не используется. В следующем примере горизонтальные и вертикальные полосы прокрутки используются для прокрутки текста без использования Flickable:

Rectangle {
    id: frame
    clip: true
    width: 160
    height: 160
    border.color: "black"
    anchors.centerIn: parent

    Text {
        id: content
        text: "ABC"
        font.pixelSize: 160
        x: -hbar.position * width
        y: -vbar.position * height
    }

    ScrollBar {
        id: vbar
        hoverEnabled: true
        active: hovered || pressed
        orientation: Qt.Vertical
        size: frame.height / content.height
        anchors.top: parent.top
        anchors.right: parent.right
        anchors.bottom: parent.bottom
    }

    ScrollBar {
        id: hbar
        hoverEnabled: true
        active: hovered || pressed
        orientation: Qt.Horizontal
        size: frame.width / content.width
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.bottom: parent.bottom
    }
}

При использовании неприсоединённой ScrollBar необходимо выполнить следующие действия вручную:

• Разместить полосу прокрутки (с помощью свойства x и y или свойств якорных точек, например).
• Установить свойства size и position, чтобы определить размер и положение полосы прокрутки относительно элемента, подлежащего прокрутке.
• Установить свойство active, чтобы определить, когда полоса прокрутки будет отображаться.

См. также ScrollIndicator, Настройка ScrollBar и Управляющие элементы индикатора.

Документация по свойствам

active : bool

Это свойство указывает, активна ли полоса прокрутки, т. е. когда она pressed или присоединённый Flickable находится в moving состоянии.

Можно сохранить видимость обеих горизонтальных и вертикальных полос во время прокрутки в любом направлении.

Это свойство автоматически устанавливается, когда полоса прокрутки присоединена к flickable.

[только для чтения] horizontal : bool

Это свойство указывает, является ли полоса прокрутки горизонтальной.

Это свойство было введено в QtQuick.Controls 2.3 (Qt 5.10).

См. также orientation.

interactive : bool

Это свойство указывает, является ли полоса прокрутки интерактивной. Значение по умолчанию — true.

Неинтерактивная полоса прокрутки визуально и по поведению похожа на ScrollIndicator. Это свойство полезно для переключения между типичными пользовательскими интерфейсами для мыши и сенсорных экранов с интерактивными и неинтерактивными полосами прокрутки соответственно.

Это свойство было введено в QtQuick.Controls 2.2 (Qt 5.9).

minimumSize : real

Это свойство содержит минимальный размер полосы прокрутки, масштабированный к 0.0 - 1.0.

Это свойство было введено в QtQuick.Controls 2.4 (Qt 5.11).

См. также size, visualSize и visualPosition.

orientation : перечисление

Это свойство содержит ориентацию полосы прокрутки.

Возможные значения:

Это свойство автоматически устанавливается, когда полоса прокрутки присоединена к flickable.

См. также horizontal и vertical.

policy : перечисление

Это свойство содержит политику полосы прокрутки. Политика по умолчанию — ScrollBar.AsNeeded.

Возможные значения:

Следующий пример поддерживает постоянное отображение вертикальной полосы прокрутки:

Flickable {
    contentHeight: 2000
    ScrollBar.vertical: ScrollBar {
        policy: ScrollBar.AlwaysOn
    }
}

Это свойство было введено в QtQuick.Controls 2.2 (Qt 5.9).

position : real

Это свойство содержит позицию полосы прокрутки, масштабированную к 0.0 - 1.0.

Это свойство автоматически устанавливается, когда полоса прокрутки прикреплена к Flickable.

См. также Flickable::visibleArea и visualPosition.

pressed : bool

Это свойство содержит значение, указывающее, нажата ли полоса прокрутки.

size : real

Это свойство содержит размер полосы прокрутки, масштабированный до 0.0 - 1.0.

Это свойство автоматически устанавливается, когда полоса прокрутки прикреплена к Flickable.

См. также Flickable::visibleArea, minimumSize и visualSize.

snapMode : enumeration

Это свойство содержит режим привязки.

Возможные значения:

В следующей таблице различные режимы проиллюстрированы с помощью анимаций. Движение и stepSize (0.25) идентичны в каждой анимации.

Значение	Пример
ScrollBar.NoSnap
ScrollBar.SnapAlways
ScrollBar.SnapOnRelease

Это свойство было добавлено в QtQuick.Controls 2.2 (Qt 5.9).

См. также stepSize.

stepSize : real

Это свойство содержит размер шага. Значение по умолчанию — 0.0.

См. также snapMode, increase() и decrease().

[только для чтения] vertical : bool

Это свойство содержит значение, указывающее, является ли полоса прокрутки вертикальной.

Это свойство было добавлено в QtQuick.Controls 2.3 (Qt 5.10).

См. также orientation.

visualPosition : real

Это свойство содержит эффективное визуальное положение полосы прокрутки, которое может быть ограничено минимальным размером.

Это свойство было добавлено в QtQuick.Controls 2.4 (Qt 5.11).

См. также position и minimumSize.

visualSize : real

Это свойство содержит эффективный визуальный размер полосы прокрутки, который может быть ограничен минимальным размером.

Это свойство было добавлено в QtQuick.Controls 2.4 (Qt 5.11).

См. также size и minimumSize.

Документация по прикрепленным свойствам

ScrollBar.horizontal : ScrollBar

Это свойство прикрепляет горизонтальную полосу прокрутки к Flickable.

Flickable {
    contentWidth: 2000
    ScrollBar.horizontal: ScrollBar { }
}

См. также Прикрепление полосы прокрутки к Flickable.

ScrollBar.vertical : ScrollBar

Это свойство прикрепляет вертикальную полосу прокрутки к Flickable.

Flickable {
    contentHeight: 2000
    ScrollBar.vertical: ScrollBar { }
}

См. также Прикрепление полосы прокрутки к Flickable.

Документация по методам

void decrease()

Уменьшает позицию на stepSize или 0.1 если stepSize равен 0.0.

См. также stepSize.

void increase()

Увеличивает позицию на stepSize или 0.1 если stepSize равен 0.0.

См. также stepSize.