Тип PieMenu QML

Поп-меню, которое отображает несколько пунктов меню по дуге. Подробнее...

• Список всех членов, включая унаследованные
• Устаревшие члены

Свойства

• boundingItem : Item
• currentIndex : int
• currentItem : int
• menuItems : список<MenuItem>
• selectionAngle : вещественное
• title : строка
• triggerMode : int

Методы

• void addItem(строка text)
• void insertItem(int before, строка text)
• void popup(вещественное x, вещественное y)
• void removeItem(item)

Подробное описание

PieMenu предоставляет радиальное контекстное меню в качестве альтернативы традиционному меню. Все элементы в PieMenu находятся на одинаковом расстоянии от центра элемента управления.

Заполнение меню

Для создания меню определите как минимум один MenuItem в качестве дочернего элемента:

PieMenu {
    id: pieMenu

    MenuItem {
        text: "Action 1"
        onTriggered: print("Action 1")
    }
    MenuItem {
        text: "Action 2"
        onTriggered: print("Action 2")
    }
    MenuItem {
        text: "Action 3"
        onTriggered: print("Action 3")
    }
}

По умолчанию отображается только текст текущего выбранного элемента над меню. Чтобы предоставить текст, который всегда отображается, когда нет текущего элемента, задайте свойство title.

Отображение меню

Типичный случай использования меню — открытие в точке курсора мыши после щелчка правой кнопкой мыши. Для этого определите MouseArea, который охватывает область, в которой щелчки должны открывать меню. При щелчке правой кнопкой мыши в MouseArea вызовите функцию popup():

MouseArea {
    anchors.fill: parent
    acceptedButtons: Qt.RightButton

    onClicked: pieMenu.popup(mouseX, mouseY)
}

Если меню открывается в позиции, где некоторые его элементы меню будут находиться за пределами boundingItem, оно автоматически перемещается в позицию, где они не будут скрыты. По умолчанию boundingItem задаётся родительским элементом меню. Его также можно задать null , чтобы предотвратить это поведение.

PieMenu может отображаться в любой позиции на экране. При традиционном контекстном меню меню позиционируется с его верхним левым углом в позиции щелчка правой кнопкой мыши, но поскольку PieMenu радиальное, мы позиционируем его по центру над позицией щелчка правой кнопкой мыши.

Чтобы создать PieMenu, который открывается после длительного нажатия и выбирает элементы при отпускании, вы можете объединить ActivationMode.ActivateOnRelease с MouseArea с использованием таймера:

MouseArea {
    id: touchArea
    anchors.fill: parent

    Timer {
        id: pressAndHoldTimer
        interval: 300
        onTriggered: pieMenu.popup(touchArea.mouseX, touchArea.mouseY);
    }

    onPressed: pressAndHoldTimer.start()
    onReleased: pressAndHoldTimer.stop();
}

PieMenu {
    id: pieMenu

    triggerMode: TriggerMode.TriggerOnRelease

    MenuItem {
        text: "Action 1"
        onTriggered: print("Action 1")
    }
    MenuItem {
        text: "Action 2"
        onTriggered: print("Action 2")
    }
    MenuItem {
        text: "Action 3"
        onTriggered: print("Action 3")
    }
}

Вы можете скрыть отдельные элементы меню, установив их свойство visible в false. Скрытие элементов не влияет на startAngle или endAngle; оставшиеся элементы будут увеличиваться, чтобы заполнить доступное пространство.

Вы можете создать пользовательский вид PieMenu, назначив PieMenuStyle

Документация по свойствам

boundingItem : Item

Элемент, в пределах которого должно оставаться меню.

Типичный случай использования PieMenu включает:

• MouseArea, которая определяет область нажатия, в пределах которой можно открыть меню.
• Границы, за пределы которых меню не должно выходить.

Хотя они звучат похоже, у них разные цели. Рассмотрим пример ниже:

Пользователь может открыть меню только в пределах внутреннего прямоугольника. В этом случае они открыли меню на краю MouseArea, но не было бы достаточно места для отображения всего меню по центру курсора, поэтому его передвинули влево.

Если по какой-то причине мы не хотели этого ограничения, мы можем установить boundingItem в null:

По умолчанию, родитель меню — boundingItem.

[только для чтения] currentIndex : int

Индекс элемента меню, который сейчас находится под курсором мыши, или -1 если такого элемента нет.

[только для чтения] currentItem : int

Элемент меню, который сейчас находится под курсором мыши, или null если такого элемента нет.

[значение по умолчанию] menuItems : список<MenuItem>

Список элементов меню, отображаемых этим меню.

Вы можете назначить элементы меню, объявив их как дочерние элементы PieMenu:

PieMenu {
    MenuItem {
        text: "Action 1"
        onTriggered: function() { print("Action 1"); }
    }
    MenuItem {
        text: "Action 2"
        onTriggered: function() { print("Action 2"); }
    }
    MenuItem {
        text: "Action 3"
        onTriggered: function() { print("Action 3"); }
    }
}

[только для чтения] selectionAngle : вещественное

Это свойство отражает угол (в радианах), образованный воображаемой линией от центра меню до позиции курсора.

Его значение не определено, когда меню не отображается.

title : строка

Это свойство определяет текст, отображаемый над меню, когда нет текущего элемента меню (currentIndex равен -1).

Значение по умолчанию — "" (пустая строка).

triggerMode : int

Это свойство определяет метод выбора элементов в меню.

• triggerMode со значением TriggerMode.TriggerOnPress означает, что элементы меню будут выбираться только при возникновении события нажатия мыши над ними.
• triggerMode со значением TriggerMode.TriggerOnRelease означает, что элементы меню будут выбираться только при возникновении события отпускания мыши над ними. Это означает, что пользователь должен удерживать кнопку мыши после открытия меню и отпустить мышь над элементом, который он хочет выбрать.
• triggerMode со значением TriggerMode.TriggerOnClick означает, что элементы меню будут выбираться только при однократном щелчке пользователя над ними.

Предупреждение: Изменение triggerMode во время отображения меню приведет к неопределенному поведению.

Документация по методам

void addItem(строка text)

Добавляет элемент text в конец элементов меню.

Эквивалентно вызову insertItem(menuItems.length, text).

Возвращает только что добавленный элемент.

void insertItem(int before, строка text)

Вставляет MenuItem с text перед индексом before.

Чтобы вставить элемент в конец, передайте menuItems.length.

Возвращает только что вставленный элемент или null если before недопустим.

void popup(вещественное x, вещественное y)

Открывает меню по координатам x, y.

void removeItem(item)

Удаляет item из меню.