Тип QML InputPanel

Обеспечивает интерфейс виртуальной клавиатуры. Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• active : bool
• externalLanguageSwitchEnabled : bool

Сигналы

• externalLanguageSwitch(var localeList, int currentIndex)

Подробное описание

Размер клавиатуры автоматически вычисляется на основе доступной ширины; то есть клавиатура сохраняет соотношение сторон, заданное текущим стилем. Поэтому приложение должно устанавливать только width и y координаты InputPanel, а не height.

Как и для всех других типов QML, предоставляемых модулем, переменная среды QT_IM_MODULE должна быть установлена в qtvirtualkeyboard перед использованием InputPanel. Для получения дополнительной информации см. Загрузка плагина.

Описание свойств

active : bool

Это свойство отражает активный статус панели ввода. Клавиатура должна быть отображена пользователю, когда это свойство true.

Это свойство было добавлено в QtQuick.VirtualKeyboard 2.0.

externalLanguageSwitchEnabled : bool

Это свойство включает механизм внешнего переключения языка. Когда это свойство true, виртуальная клавиатура не будет показывать встроенное всплывающее окно выбора языка, а вместо этого будет генерировать сигнал externalLanguageSwitch. Приложение может обработать этот сигнал и отобразить собственное диалоговое окно выбора языка.

Это свойство было добавлено в QtQuick.VirtualKeyboard 2.4.

Описание сигналов

externalLanguageSwitch(var localeList, int currentIndex)

Этот сигнал генерируется, когда externalLanguageSwitchEnabled true и пользователь нажимает клавишу переключения языка.

Он служит зацепкой для отображения пользовательского диалогового окна выбора языка вместо встроенного всплывающего окна выбора языка в виртуальной клавиатуре.

Параметр localeList содержит список имен языковых стандартов на выбор. Чтобы получить дополнительную информацию о конкретном языке, используйте функцию Qt.locale(). currentIndex — это индекс текущего языкового стандарта в localeList. Этот элемент должен быть выделен как текущий элемент в интерфейсе.

Чтобы выбрать новый язык, используйте свойство VirtualKeyboardSettings.locale.

Ниже приведен пример, демонстрирующий реализацию пользовательского диалогового окна выбора языка:

Dialog {
    id: languageDialog
    title: "Select Input Language"
    modality: Qt.ApplicationModal

    function show(localeList, currentIndex) {
        languageListModel.clear()
        for (var i = 0; i < localeList.length; i++) {
            languageListModel.append({localeName: localeList[i], displayName: Qt.locale(localeList[i]).nativeLanguageName})
        }
        languageListView.currentIndex = currentIndex
        languageListView.positionViewAtIndex(currentIndex, ListView.Center)
        languageDialog.visible = true
    }

    contentItem: ListView {
        id: languageListView
        model: ListModel {
            id: languageListModel
            function selectItem(index) {
                VirtualKeyboardSettings.locale = languageListModel.get(index).localeName
                languageDialog.visible = false
            }
        }
        delegate: Item {
            id: languageListItem
            width: languageNameTextMetrics.width * 17
            height: languageNameTextMetrics.height + languageListLabel.anchors.topMargin + languageListLabel.anchors.bottomMargin
            Text {
                id: languageListLabel
                anchors.left: parent.left
                anchors.top: parent.top
                anchors.leftMargin: languageNameTextMetrics.height / 2
                anchors.rightMargin: anchors.leftMargin
                anchors.topMargin: languageNameTextMetrics.height / 3
                anchors.bottomMargin: anchors.topMargin
                text: languageNameFormatter.elidedText
                color: "#5CAA15"
                font {
                    weight: Font.Normal
                    pixelSize: 28
                }
            }
            TextMetrics {
                id: languageNameTextMetrics
                font {
                    weight: Font.Normal
                    pixelSize: 28
                }
                text: "X"
            }
            TextMetrics {
                id: languageNameFormatter
                font {
                    weight: Font.Normal
                    pixelSize: 28
                }
                elide: Text.ElideRight
                elideWidth: languageListItem.width - languageListLabel.anchors.leftMargin - languageListLabel.anchors.rightMargin
                text: displayName
            }
            MouseArea {
                anchors.fill: parent
                hoverEnabled: true
                onClicked: {
                    if (index === -1)
                        return
                    parent.ListView.view.currentIndex = index
                    parent.ListView.view.model.selectItem(index)
                }
            }
            states: State {
                name: "current"
                when: languageListItem.ListView.isCurrentItem
                PropertyChanges {
                    target: languageListLabel
                    color: "black"
                }
            }
        }
    }
}

Затем диалоговое окно будет объявлено:

LanguageDialog {
    id: languageDialog
    width: 400
    height: 400
}

В InputPanel приложения добавьте следующий код:

InputPanel {
    id: inputPanel
    externalLanguageSwitchEnabled: true
    onExternalLanguageSwitch: languageDialog.show(localeList, currentIndex)
    // ...
}

Теперь пользовательское диалоговое окно будет отображаться при нажатии клавиши переключения языка.

Примечание: Соответствующий обработчик — onExternalLanguageSwitch.

Этот сигнал был добавлен в QtQuick.VirtualKeyboard 2.4.