Определение JavaScript-ресурсов в QML

Логика программы для приложения QML может быть определена на JavaScript. Код JavaScript может быть определён непосредственно в документах QML или разделен на JavaScript-файлы (известные как JavaScript Resources в QML).

В QML поддерживаются два разных типа JavaScript-ресурсов: файлы реализации кода-за-сценой и общие (библиотечные) файлы. Оба типа JavaScript-ресурсов могут быть импортированы другими JavaScript-ресурсами или включены в QML-модули.

Ресурс реализации кода-за-сценой

Большинство JavaScript-файлов, импортированных в QML-документ, являются реализациями с состоянием для QML-документа, их импортирующего. В этих случаях каждый экземпляр типа QML-объекта, определённого в документе, требует отдельной копии JavaScript-объектов и состояния для корректной работы.

По умолчанию, при импорте JavaScript-файлов создаётся уникальная, изолированная копия для каждого экземпляра QML-компонента. Если этот JavaScript-файл не импортирует никаких ресурсов или модулей с инструкцией .import, его код будет выполняться в том же контексте, что и экземпляр QML-компонента, и, следовательно, сможет обращаться к объектам и свойствам, объявленным в этом QML-компоненте и изменять их. В противном случае у него будет свой уникальный контекст, и объекты и свойства QML-компонента должны передаваться функциям JavaScript-файла в качестве параметров, если они требуются.

Следующий пример реализации ресурса кода-за-сценой:

// MyButton.qml
import QtQuick 2.0
import "my_button_impl.js" as Logic // A new instance of this JavaScript resource
                                    // is loaded for each instance of Button.qml.

Rectangle {
    id: rect
    width: 200
    height: 100
    color: "red"

    MouseArea {
        id: mousearea
        anchors.fill: parent
        onClicked: Logic.onClicked(rect)
    }
}

// my_button_impl.js
var clickCount = 0;   // this state is separate for each instance of MyButton
function onClicked(button) {
    clickCount += 1;
    if ((clickCount % 5) == 0) {
        button.color = Qt.rgba(1,0,0,1);
    } else {
        button.color = Qt.rgba(0,1,0,1);
    }
}

В общем случае, простую логику следует определять непосредственно в QML-файле, но более сложную логику следует отделять в ресурсы реализации кода-за-сценой для поддержания и улучшения читаемости.

Общие JavaScript-ресурсы (библиотеки)

По умолчанию, JavaScript-файлы, импортированные из QML, разделяют свой контекст с QML-компонентом. Это означает, что JavaScript-файлы имеют доступ к тем же QML-объектам и могут их изменять. Как следствие, каждый импорт должен иметь уникальную копию этих файлов.

Предыдущий раздел охватывает импорты JavaScript-файлов с состоянием. Однако некоторые JavaScript-файлы являются бессостоятельными и ведут себя больше как многократно используемые библиотеки, предоставляя набор вспомогательных функций, не требующих ничего из места импорта. Вы можете значительно сэкономить память и ускорить создание экземпляров QML-компонентов, если пометите такие библиотеки специальным пragma, как показано в следующем примере.

// factorial.js
.pragma library

var factorialCount = 0;

function factorial(a) {
    a = parseInt(a);

    // factorial recursion
    if (a > 0)
        return a * factorial(a - 1);

    // shared state
    factorialCount += 1;

    // recursion base-case.
    return 1;
}

function factorialCallCount() {
    return factorialCount;
}

Декларация пragma должна появляться перед любым JavaScript-кодом, за исключением комментариев.

Обратите внимание, что несколько QML-документов могут импортировать "factorial.js" и вызывать функции factorial и factorialCallCount, которые он предоставляет. Состояние JavaScript-импорта разделяется между QML-документами, которые его импортируют, и, следовательно, возвращаемое значение функции factorialCallCount может быть отличным от нуля при вызове внутри QML-документа, который никогда не вызывал функцию factorial.

Например:

// Calculator.qml
import QtQuick 2.0
import "factorial.js" as FactorialCalculator // This JavaScript resource is only
                                             // ever loaded once by the engine,
                                             // even if multiple instances of
                                             // Calculator.qml are created.

Text {
    width: 500
    height: 100
    property int input: 17
    text: "The factorial of " + input + " is: " + FactorialCalculator.factorial(input)
}

Поскольку они общие, файлы с .pragma library не могут напрямую получать доступ к объектам или свойствам экземпляра QML-компонента, хотя QML-значения могут передаваться в качестве параметров функций.