Spec-Zone.ru › Qt 5.15

Фокусировка клавиатуры в Qt Quick

При нажатии или отпускании клавиши генерируется событие нажатия клавиши, которое передаётся фокусированному элементу Qt Quick Item. Для упрощения создания повторно используемых компонентов и решения некоторых случаев, характерных для интерактивных пользовательских интерфейсов, элементы Qt Quick добавляют расширение на основе области действия к традиционной модели фокуса клавиатуры Qt.

Обзор обработки нажатий клавиш

При нажатии или отпускании клавиши пользователем происходит следующее:

  1. Qt получает действие нажатия клавиши и генерирует событие нажатия клавиши.
  2. Если активным окном является QQuickWindow, событие нажатия клавиши передаётся ему.
  3. Событие нажатия клавиши передаётся сценой элементу Item с активным фокусом. Если ни один элемент не имеет активного фокуса, событие нажатия клавиши игнорируется.
  4. Если элемент QQuickItem с активным фокусом принимает событие нажатия клавиши, распространение останавливается. В противном случае событие отправляется родительскому элементу Item до тех пор, пока событие не будет принято или не будет достигнут корневой элемент.

    Если элемент типа Rectangle в следующем примере имеет активный фокус, и нажата клавиша A, событие не будет распространено дальше. При нажатии клавиши B, событие будет распространено до корневого элемента и, следовательно, будет проигнорировано.

    Rectangle {
    width: 100; height: 100
    focus: true
    Keys.onPressed: {
        if (event.key == Qt.Key_A) {
            console.log('Key A was pressed');
            event.accepted = true;
        }
    }
}
  5. Если достигнут корневой элемент Item, событие нажатия клавиши игнорируется, и продолжается обычная обработка нажатий клавиш Qt.

См. также свойство Keys и свойство KeyNavigation.

Запрос активного элемента фокуса

Можно запросить, имеет ли элемент Item активный фокус, через свойство Item::activeFocus. Например, здесь у нас тип Text, текст которого определяется наличием или отсутствием у него активного фокуса.

    Text {
        text: activeFocus ? "I have active focus!" : "I do not have active focus"
    }

Получение фокуса и области фокуса

Элемент Item запрашивает фокус, установив свойство focus в значение true.

В простых случаях, иногда достаточно просто установить свойство focus. Если запустить следующий пример с помощью qmlscene, мы увидим, что тип keyHandler имеет активный фокус, и нажатие клавиш A, B, или C соответствующим образом изменяет текст.

Rectangle {
    color: "lightsteelblue"; width: 240; height: 25
    Text { id: myText }
    Item {
        id: keyHandler
        focus: true
        Keys.onPressed: {
            if (event.key == Qt.Key_A)
                myText.text = 'Key A was pressed'
            else if (event.key == Qt.Key_B)
                myText.text = 'Key B was pressed'
            else if (event.key == Qt.Key_C)
                myText.text = 'Key C was pressed'
        }
    }
}

Однако, если вышеприведенный пример использовать в качестве повторно используемого или импортируемого компонента, простое использование свойства focus больше не является достаточным.

Для демонстрации создадим два экземпляра ранее определенного компонента и установим фокус на первый. Цель состоит в том, чтобы при нажатии клавиш A, B, или C первый из двух компонентов получал событие и реагировал соответствующим образом.

Код, импортирующий и создающий два экземпляра MyWidget:

//Window code that imports MyWidget
Rectangle {
    id: window
    color: "white"; width: 240; height: 150

    Column {
        anchors.centerIn: parent; spacing: 15

        MyWidget {
            focus: true             //set this MyWidget to receive the focus
            color: "lightblue"
        }
        MyWidget {
            color: "palegreen"
        }
    }
}

Код MyWidget:

Rectangle {
    id: widget
    color: "lightsteelblue"; width: 175; height: 25; radius: 10; antialiasing: true
    Text { id: label; anchors.centerIn: parent}
    focus: true
    Keys.onPressed: {
        if (event.key == Qt.Key_A)
            label.text = 'Key A was pressed'
        else if (event.key == Qt.Key_B)
            label.text = 'Key B was pressed'
        else if (event.key == Qt.Key_C)
            label.text = 'Key C was pressed'
    }
}

Мы хотим, чтобы первый элемент MyWidget имел фокус, поэтому мы устанавливаем его свойство focus в значение true. Однако, выполнив код, мы можем подтвердить, что второй виджет получает фокус.

Глядя на код MyWidget и window, проблема очевидна - существуют три типа, которые устанавливают свойство focus в значение true. Два типа MyWidget устанавливают свойство focus в значение true, и компонент window также устанавливает фокус. В конечном итоге, только один тип может иметь фокус клавиатуры, и система должна решить, какой тип получит фокус. Когда создается второй MyWidget, он получает фокус, потому что он последний тип, установивший свойство focus в значение true.

Эта проблема связана с видимостью. Компонент MyWidget хотел бы иметь фокус, но не может контролировать фокус при импорте или повторном использовании. Аналогично, компонент window не может узнать, запрашивают ли фокус импортированные компоненты.

Для решения этой проблемы QML вводит понятие области фокуса. Для существующих пользователей Qt область фокуса похожа на автоматический прокси фокуса. Область фокуса создаётся путём объявления типа FocusScope.

В следующем примере к компоненту добавлен тип FocusScope, и показан визуальный результат.

FocusScope {

    //FocusScope needs to bind to visual properties of the Rectangle
    property alias color: rectangle.color
    x: rectangle.x; y: rectangle.y
    width: rectangle.width; height: rectangle.height

    Rectangle {
        id: rectangle
        anchors.centerIn: parent
        color: "lightsteelblue"; width: 175; height: 25; radius: 10; antialiasing: true
        Text { id: label; anchors.centerIn: parent }
        focus: true
        Keys.onPressed: {
            if (event.key == Qt.Key_A)
                label.text = 'Key A was pressed'
            else if (event.key == Qt.Key_B)
                label.text = 'Key B was pressed'
            else if (event.key == Qt.Key_C)
                label.text = 'Key C was pressed'
        }
    }
}

Понятие области фокуса довольно просто.

  • В каждой области фокуса один объект может иметь свойство Item::focus установленным в значение true. Если у нескольких элементов Item установлено свойство focus, последний тип, установивший свойство focus, получит фокус, а остальные будут сброшены, аналогично случаям без областей фокуса.
  • Когда область фокуса получает активный фокус, содержащийся тип с установленным свойством focus (если таковой имеется) также получает активный фокус. Если этот тип также является типом FocusScope, поведение проксирования продолжается. И область фокуса, и подфокусированный элемент будут иметь установленное свойство activeFocus.

Обратите внимание, что, поскольку тип FocusScope не является визуальным типом, свойства его дочерних элементов должны быть доступны родительскому элементу FocusScope. Макеты и типы позиционирования будут использовать эти визуальные и стилистические свойства для создания макета. В нашем примере, тип Column не может правильно отобразить два виджета, потому что у FocusScope нет собственных визуальных свойств. Компонент MyWidget напрямую связывается со свойствами rectangle для того, чтобы тип Column смог создать макет, содержащий дочерние элементы FocusScope.

В этом примере второй компонент статически выбран. Теперь тривиально расширить этот компонент, сделав его кликабельным и добавив его в исходное приложение. Мы по-прежнему устанавливаем фокус на один из виджетов по умолчанию. Теперь при нажатии на любой из виджетов MyClickableWidget, фокус переключается на него, а у другого виджета фокус снимается.

Код, импортирующий и создающий два экземпляра MyClickableWidget:

Rectangle {
    id: window

    color: "white"; width: 240; height: 150

    Column {
        anchors.centerIn: parent; spacing: 15

        MyClickableWidget {
            focus: true             //set this MyWidget to receive the focus
            color: "lightblue"
        }
        MyClickableWidget {
            color: "palegreen"
        }
    }

}

Код MyClickableWidget:

FocusScope {

    id: scope

    //FocusScope needs to bind to visual properties of the children
    property alias color: rectangle.color
    x: rectangle.x; y: rectangle.y
    width: rectangle.width; height: rectangle.height

    Rectangle {
        id: rectangle
        anchors.centerIn: parent
        color: "lightsteelblue"; width: 175; height: 25; radius: 10; antialiasing: true
        Text { id: label; anchors.centerIn: parent }
        focus: true
        Keys.onPressed: {
            if (event.key == Qt.Key_A)
                label.text = 'Key A was pressed'
            else if (event.key == Qt.Key_B)
                label.text = 'Key B was pressed'
            else if (event.key == Qt.Key_C)
                label.text = 'Key C was pressed'
        }
    }
    MouseArea { anchors.fill: parent; onClicked: { scope.focus = true } }
}

Когда QML Item явно отказывается от фокуса (устанавливая свойство focus в значение false при наличии активного фокуса), система не автоматически выбирает другой тип для получения фокуса. То есть, возможно, что активный фокус отсутствует.

См. Примеры Qt Quick - Взаимодействие с клавиатурой для демонстрации перемещения фокуса клавиатуры между несколькими областями с использованием типов FocusScope.

Расширенное использование областей фокуса

Области фокуса позволяют легко разделить распределение фокуса. Несколько QML элементов используют его с этой целью.

ListView, например, сам является областью фокуса. Обычно это незаметно, так как ListView обычно не имеет вручную добавленных визуальных дочерних элементов. Будучи областью фокуса, ListView может сфокусироваться на текущем элементе списка, не беспокоясь о том, как это повлияет на остальную часть приложения. Это позволяет делегату текущего элемента реагировать на нажатия клавиш.

Этот искусственный пример демонстрирует, как это работает. Нажатие клавиши Return выведет имя текущего элемента списка.

Rectangle {
    color: "lightsteelblue"; width: 100; height: 50

    ListView {
        anchors.fill: parent
        focus: true

        model: ListModel {
            ListElement { name: "Bob" }
            ListElement { name: "John" }
            ListElement { name: "Michael" }
        }

        delegate: FocusScope {
                width: childrenRect.width; height: childrenRect.height
                x:childrenRect.x; y: childrenRect.y
                TextInput {
                    focus: true
                    text: name
                    Keys.onReturnPressed: console.log(name)
                }
        }
    }
}

Хотя пример прост, за кулисами происходит много. Всякий раз, когда изменяется текущий элемент, ListView устанавливает свойство делегата Item::focus. Поскольку ListView является областью фокуса, это не влияет на остальную часть приложения. Однако, если ListView сам имеет активный фокус, это приводит к тому, что сам делегат получает активный фокус. В этом примере корневой тип делегата также является областью фокуса, что, в свою очередь, даёт активный фокус типу Text, который фактически выполняет работу по обработке клавиши Return.

Все классы QML-представлений, такие как PathView и GridView, ведут себя аналогичным образом, что позволяет обрабатывать нажатия клавиш в соответствующих делегатах.

© The Qt Company Ltd
Licensed under the GNU Free Documentation License, Version 1.3.
https://doc.qt.io/qt-5.15/qtquick-input-focus.html

Spec-Zone.ru

Настройки Оффлайн Что нового Помощь О нас
Spec-Zone .ru
спецификации, руководства, описания, API