Тип QML PathView

Выкладывает элементы, предоставляемые моделью, на траектории. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• cacheItemCount : int
• count : int
• currentIndex : int
• currentItem : Item
• delegate : Component
• dragMargin : real
• dragging : bool
• flickDeceleration : real
• flicking : bool
• highlight : Component
• highlightItem : Item
• highlightMoveDuration : int
• highlightRangeMode : перечисление
• interactive : bool
• maximumFlickVelocity : real
• model : модель
• movementDirection : перечисление
• moving : bool
• offset : real
• path : Path
• pathItemCount : int
• preferredHighlightBegin : real
• preferredHighlightEnd : real
• snapMode : перечисление

Присоединенные свойства

• isCurrentItem : bool
• onPath : bool
• view : PathView

Сигналы

• dragEnded()
• dragStarted()
• flickEnded()
• flickStarted()
• movementEnded()
• movementStarted()

Методы

• decrementCurrentIndex()
• incrementCurrentIndex()
• int indexAt(real x, real y)
• Item itemAt(real x, real y)
• positionViewAtIndex(int index, PositionMode mode)

Подробное описание

PathView отображает данные из моделей, созданных из встроенных типов QML, таких как ListModel и XmlListModel, или пользовательские классы моделей, определенные в C++, которые наследуют от QAbstractListModel.

Представление имеет model, который определяет отображаемые данные, и delegate, который определяет, как должны отображаться данные. delegate создаётся для каждого элемента на path. Элементы могут быть перемещены по траектории.

Например, если в файле ContactModel.qml определена простая модель списка, как это:

import QtQuick 2.0

ListModel {
    ListElement {
        name: "Bill Jones"
        icon: "pics/qtlogo.png"
    }
    ListElement {
        name: "Jane Doe"
        icon: "pics/qtlogo.png"
    }
    ListElement {
        name: "John Smith"
        icon: "pics/qtlogo.png"
    }
}

Эти данные могут быть представлены как PathView, так:

import QtQuick 2.0

Rectangle {
    width: 240; height: 200

    Component {
        id: delegate
        Column {
            id: wrapper
            opacity: PathView.isCurrentItem ? 1 : 0.5
            Image {
                anchors.horizontalCenter: nameText.horizontalCenter
                width: 64; height: 64
                source: icon
            }
            Text {
                id: nameText
                text: name
                font.pointSize: 16
            }
        }
    }

    PathView {
        anchors.fill: parent
        model: ContactModel {}
        delegate: delegate
        path: Path {
            startX: 120; startY: 100
            PathQuad { x: 120; y: 25; controlX: 260; controlY: 75 }
            PathQuad { x: 120; y: 100; controlX: -20; controlY: 75 }
        }
    }
}

(В примере выше используется PathAttribute для масштабирования и изменения непрозрачности элементов при их вращении. Этот дополнительный код можно увидеть в документации PathAttribute.)

PathView не обрабатывает навигацию с клавиатуры автоматически. Это связано с тем, что клавиши для навигации будут зависеть от формы траектории. Навигацию можно добавить довольно просто, установив focus на true и вызвав decrementCurrentIndex() или incrementCurrentIndex(), например, для навигации с помощью клавиш со стрелками влево и вправо:

PathView {
    // ...
    focus: true
    Keys.onLeftPressed: decrementCurrentIndex()
    Keys.onRightPressed: incrementCurrentIndex()
}

Само представление траектории является областью фокуса (см. Фокус клавиатуры в Qt Quick для получения дополнительной информации).

Делегаты создаются по мере необходимости и могут быть уничтожены в любое время. Состояние никогда не должно храниться в делегате.

PathView прикрепляет ряд свойств к корневому элементу делегата, например, PathView.isCurrentItem. В следующем примере корневой элемент делегата может напрямую получить доступ к этому присоединённому свойству как PathView.isCurrentItem, в то время как объект-потомок nameText должен обратиться к этому свойству как wrapper.PathView.isCurrentItem.

    Component {
        id: delegate
        Column {
            id: wrapper
            opacity: PathView.isCurrentItem ? 1 : 0.5
            Image {
                anchors.horizontalCenter: nameText.horizontalCenter
                width: 64; height: 64
                source: icon
            }
            Text {
                id: nameText
                text: name
                font.pointSize: 16
            }
        }
    }

Примечание: представления не включают clip автоматически. Если представление не обрезается другим элементом или экраном, потребуется установить clip: true, чтобы обеспечить аккуратное обрезание элементов, находящихся вне видимой области.

См. также Path, QML Модели данных, ListView, GridView и Примеры Qt Quick - Представления.

Документация по свойствам

Эти свойства задают предпочтительный диапазон выделения (текущий элемент) в представлении. Предпочтительные значения должны находиться в диапазоне от 0 до 1.

Допустимые значения для highlightRangeMode:

• PathView.NoHighlightRange - диапазон не применяется, и выделение будет свободно перемещаться в пределах представления.
• PathView.ApplyRange - представление попытается поддерживать выделение в диапазоне, однако выделение может перемещаться за пределы диапазона в конце траектории или из-за взаимодействия с мышкой.
• PathView.StrictlyEnforceRange - выделение никогда не выйдет за пределы диапазона. Это означает, что текущий элемент изменится, если действие с клавиатуры или мыши приведет к перемещению выделения за пределы диапазона.

Значение по умолчанию - PathView.StrictlyEnforceRange.

Определение диапазона выделения - правильный способ влиять на то, где находится текущий элемент при перемещении представления. Например, если вы хотите, чтобы текущий выбранный элемент находился посередине траектории, установите диапазон выделения в 0,5, 0,5 и highlightRangeMode в PathView.StrictlyEnforceRange. Затем, когда представление траектории прокручивается, текущим выбранным элементом будет элемент в этой позиции. Это также относится к случаям, когда текущий выбранный элемент меняется - он будет прокручиваться в пределах предпочтительного диапазона выделения. Кроме того, поведение текущего индекса элемента будет происходить независимо от наличия выделения.

Примечание: Для валидного диапазона preferredHighlightEnd должно быть больше или равно preferredHighlightBegin.

cacheItemCount : int

Это свойство содержит максимальное количество элементов для кэширования вне траектории.

Например, PathView с моделью, содержащей 20 элементов, pathItemCount в 10 и cacheItemCount в 4 создаст до 14 элементов, из которых 10 будут видимыми на траектории, а 4 - невидимыми кэшированными элементами.

Кэшированные делегаты создаются асинхронно, что позволяет создавать их на протяжении нескольких кадров и уменьшает вероятность пропуска кадров.

Примечание: Установка этого свойства не заменяет создание эффективных делегатов. Оно может улучшить плавность поведения прокрутки за счёт дополнительного использования памяти. Чем меньше объектов и связей в делегате, тем быстрее представление можно прокручивать. Важно понимать, что установка cacheItemCount только отсрочит проблемы, вызванные медленным загрузкой делегатов, это не решение для такого сценария.

См. также pathItemCount.

count : int

Это свойство содержит количество элементов в модели.

currentIndex : int

Это свойство содержит индекс текущего элемента.

currentItem : Item

Это свойство содержит текущий элемент в представлении.

delegate : Component

Делегат предоставляет шаблон, определяющий каждый элемент, созданный представлением. Индекс показан как доступное index свойство. Свойства модели также доступны в зависимости от типа модели данных.

Количество объектов и связей в делегате напрямую влияет на производительность прокрутки представления, когда указано pathItemCount. Если это возможно, поместите функциональность, которая не требуется для нормального отображения делегата, в Loader, который может загружать дополнительные компоненты при необходимости.

Обратите внимание, что PathView будет размещать элементы на основе размера корневого элемента в делегате.

Вот пример делегата:

    Component {
        id: delegate
        Column {
            id: wrapper
            opacity: PathView.isCurrentItem ? 1 : 0.5
            Image {
                anchors.horizontalCenter: nameText.horizontalCenter
                width: 64; height: 64
                source: icon
            }
            Text {
                id: nameText
                text: name
                font.pointSize: 16
            }
        }
    }

dragMargin : real

Это свойство содержит максимальное расстояние от пути, инициирующего перетаскивание мышью.

По умолчанию путь можно перетаскивать только, щелкнув по элементу. Если dragMargin больше нуля, перетаскивание можно инициировать, щелкнув в пределах dragMargin пикселей от пути.

dragging : bool

Это свойство указывает, перемещается ли представление в данный момент из-за перетаскивания пользователем.

flickDeceleration : real

Это свойство содержит скорость замедления прокрутки.

По умолчанию значение равно 100.

flicking : bool

Это свойство указывает, перемещается ли представление в данный момент из-за прокрутки пользователем.

highlight : Component

Это свойство содержит компонент, используемый в качестве выделения.

Экземпляр компонента выделения будет создан для каждого представления. Геометрия созданного экземпляра компонента будет управлять представлением, чтобы оставаться с текущим элементом.

Ниже приведён пример создания простого выделения. Обратите внимание на использование присоединённого свойства PathView.onPath для обеспечения того, что выделение скрыто, когда оно прокручено в сторону от пути.

Component {
    Rectangle {
        visible: PathView.onPath
        // ...
    }
}

См. также highlightItem и highlightRangeMode.

highlightItem : Item

highlightItem содержит выделенный элемент, созданный из компонента highlight.

См. также highlight.

highlightMoveDuration : int

Это свойство содержит продолжительность анимации перемещения выделения.

Если highlightRangeMode равняется StrictlyEnforceRange, это свойство определяет скорость перемещения элементов по пути.

Значение по умолчанию для продолжительности — 300 мс.

interactive : bool

Пользователь не может перетаскивать или прокручивать PathView, который не является интерактивным.

Это свойство полезно для временного отключения прокрутки. Это позволяет выполнять специальные действия с элементами PathView.

maximumFlickVelocity : real

Это свойство содержит приблизительную максимальную скорость, с которой пользователь может прокрутить представление в пикселях/секунду.

Значение по умолчанию зависит от платформы.

model : model

Это свойство содержит модель, предоставляющую данные для представления.

Модель предоставляет набор данных, используемых для создания элементов представления. Для больших или динамических наборов данных модель обычно предоставляется объектом модели C++. Модели также могут быть созданы непосредственно в QML, используя тип ListModel.

Примечание: изменение модели сбросит смещение и currentIndex до 0.

См. также Модели данных.

movementDirection : enumeration

Это свойство определяет направление движения элементов при установке текущего индекса. Возможные значения:

• PathView.Shortest (по умолчанию) — элементы перемещаются в направлении, требующем наименьшего перемещения, что может быть либо Negative , либо Positive.
• PathView.Negative — элементы перемещаются назад к своему пункту назначения.
• PathView.Positive — элементы перемещаются вперёд к своему пункту назначения.

Например, предположим, что в модели есть 5 элементов, и currentIndex равен 0. Если currentIndex устанавливается в 2,

• направление движения Positive приведёт к следующему порядку: 0, 1, 2
• направление движения Negative приведёт к следующему порядку: 0, 5, 4, 3, 2
• направление движения Shortest приведёт к тому же порядку, что и Positive.

Примечание: это свойство не влияет на перемещение incrementCurrentIndex() и decrementCurrentIndex().

Это свойство было добавлено в Qt 5.7.

moving : bool

Это свойство указывает, перемещается ли представление в данный момент из-за перетаскивания или прокрутки пользователем.

offset : real

Смещение указывает, насколько далеко по пути элементы находятся от своего начального положения. Это вещественное число, которое варьируется от 0 до количества элементов в модели.

path : Path

Это свойство содержит путь, используемый для размещения элементов. Для получения дополнительной информации см. документацию по Path.

pathItemCount : int

Это свойство содержит количество видимых элементов на пути в любой момент времени.

Указание pathItemCount как undefined отобразит все элементы на пути.

snapMode : enumeration

Это свойство определяет, как элементы установятся после перетаскивания или прокрутки. Возможные значения:

• PathView.NoSnap (по умолчанию) — элементы останавливаются где угодно на пути.
• PathView.SnapToItem — элементы устанавливаются так, что элемент выровнен с preferredHighlightBegin.
• PathView.SnapOneItem — элементы устанавливаются не дальше чем на один элемент от элемента, ближайшего к preferredHighlightBegin в момент отпускания нажатия. Этот режим особенно полезен для перемещения по одной странице за раз.

snapMode не влияет на currentIndex. Чтобы обновить currentIndex по мере перемещения представления, установите highlightRangeMode в PathView.StrictlyEnforceRange (по умолчанию для PathView).

См. также highlightRangeMode.

Документация по присоединённым свойствам

PathView.isCurrentItem : bool

Это присоединённое свойство равно true, если этот делегат является текущим элементом; иначе false.

Оно присоединяется к каждому экземпляру делегата.

Это свойство может использоваться для изменения внешнего вида текущего элемента.

    Component {
        id: delegate
        Column {
            id: wrapper
            opacity: PathView.isCurrentItem ? 1 : 0.5
            Image {
                anchors.horizontalCenter: nameText.horizontalCenter
                width: 64; height: 64
                source: icon
            }
            Text {
                id: nameText
                text: name
                font.pointSize: 16
            }
        }
    }

PathView.onPath : bool

Это присоединённое свойство указывает, находится ли элемент в данный момент на пути.

Если установлено pathItemCount, возможно, некоторые элементы будут созданы, но не будут считаться в данный момент находящимися на пути. Обычно эти элементы будут установлены невидимыми, например:

Component {
    Rectangle {
        visible: PathView.onPath
        // ...
    }
}

Это присоединённое свойство присоединяется к каждому экземпляру делегата.

PathView.view : PathView

Это присоединённое свойство содержит представление, которое управляет этим экземпляром делегата.

Оно присоединяется к каждому экземпляру делегата.

Документация по сигналам

dragEnded()

Этот сигнал испускается, когда пользователь прекращает перетаскивание представления.

Если скорость перетаскивания достаточно велика в момент отпускания сенсорной кнопки/кнопки мыши, начнётся прокрутка.

Примечание: Соответствующий обработчик — onDragEnded.

dragStarted()

Этот сигнал испускается, когда представление начинает перетаскиваться из-за взаимодействия пользователя.

Примечание: Соответствующий обработчик — onDragStarted.

flickEnded()

Этот сигнал испускается, когда представление перестаёт двигаться из-за прокрутки.

Примечание: Соответствующий обработчик — onFlickEnded.

flickStarted()

Этот сигнал испускается, когда представление пролистывается. Пролистывание начинается с точки, в которой кнопка мыши или касание отпускаются, а движение ещё продолжается.

Примечание: Соответствующий обработчик — onFlickStarted.

movementEnded()

Этот сигнал испускается, когда движение представления останавливается из-за взаимодействия пользователя. Если было выполнено пролистывание, этот сигнал будет испущен, когда пролистывание закончится. Если пролистывание не было выполнено, этот сигнал будет испущен, когда пользователь прекратит перетаскивание — т.е. при отпускании кнопки мыши или касания.

Примечание: Соответствующий обработчик — onMovementEnded.

movementStarted()

Этот сигнал испускается, когда движение представления начинается из-за взаимодействия пользователя.

Примечание: Соответствующий обработчик — onMovementStarted.

Документация по методам

decrementCurrentIndex()

Уменьшает текущий индекс.

Примечание: методы следует вызывать только после завершения компонента.

incrementCurrentIndex()

Увеличивает текущий индекс.

Примечание: методы следует вызывать только после завершения компонента.

int indexAt(real x, real y)

Возвращает индекс элемента, содержащего точку x, y в координатах содержимого. Если в указанной точке нет элемента, возвращается -1.

Примечание: методы следует вызывать только после завершения компонента.

Item itemAt(real x, real y)

Возвращает элемент, содержащий точку x, y в координатах содержимого. Если в указанной точке нет элемента, возвращается null.

Примечание: методы следует вызывать только после завершения компонента.

positionViewAtIndex(int index, PositionMode mode)

Размещает представление таким образом, что элемент с индексом index находится в позиции, заданной mode:

• PathView.Начало — размещение элемента в начале пути.
• PathView.Центр — размещение элемента в центре пути.
• PathView.Конец — размещение элемента в конце пути.
• PathView.Содержать — гарантировать размещение элемента на пути.
• PathView.ТочкаФиксации — размещение элемента в preferredHighlightBegin. Этот режим допустим только если highlightRangeMode равен StrictlyEnforceRange или фиксирование включено через snapMode.

Примечание: методы следует вызывать только после завершения компонента. Для размещения представления при запуске этот метод следует вызвать с помощью Component.onCompleted. Например, для размещения представления в конце:

Component.onCompleted: positionViewAtIndex(count - 1, PathView.End)