Тип QML PathAttribute

Определяет, как установить атрибут в заданной позиции в пути. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• name : строка
• value : вещественное число

Подробное описание

Объект PathAttribute позволяет задавать атрибуты, состоящие из имени и значения, для различных точек вдоль пути. Атрибуты доступны делегату как Присоединенные свойства. Значение атрибута в любой конкретной точке вдоль пути интерполируется из PathAttributes, ограничивающих эту точку.

Пример ниже демонстрирует путь с элементами, масштабированными до 30% с непрозрачностью 50% в верхней части пути и масштабированными на 100% с непрозрачностью 100% в нижней части. Обратите внимание на использование присоединенных свойств PathView.iconScale и PathView.iconOpacity для установки масштаба и непрозрачности делегата.

import QtQuick 2.0

Rectangle {
    width: 240; height: 200

    Component {
        id: delegate
        Item {
            width: 80; height: 80
            scale: PathView.iconScale
            opacity: PathView.iconOpacity
            Column {
                Image { anchors.horizontalCenter: nameText.horizontalCenter; width: 64; height: 64; source: icon }
                Text { id: nameText; text: name; font.pointSize: 16 }
            }
        }
    }

    PathView {
        anchors.fill: parent
        model: ContactModel {}
        delegate: delegate
        path: Path {
            startX: 120; startY: 100
            PathAttribute { name: "iconScale"; value: 1.0 }
            PathAttribute { name: "iconOpacity"; value: 1.0 }
            PathQuad { x: 120; y: 25; controlX: 260; controlY: 75 }
            PathAttribute { name: "iconScale"; value: 0.3 }
            PathAttribute { name: "iconOpacity"; value: 0.5 }
            PathQuad { x: 120; y: 100; controlX: -20; controlY: 75 }
        }
    }
}

См. такжеPath.

Документация по свойствам

name : строка

Это свойство содержит имя атрибута, который нужно изменить.

Этот атрибут будет доступен делегату как PathView.<name>

Важно отметить, что разрешается использовать имя существующего свойства элемента, например, "opacity", в качестве атрибута. Это потому, что атрибуты пути добавляют новое Присоединенное свойство, которое никак не конфликтует с существующими свойствами.

value : вещественное число

Это свойство содержит значение для атрибута.

Указанное значение может быть использовано для влияния на визуальный вид элемента вдоль пути. Например, следующий путь задает атрибут с именем itemRotation, который имеет значение 0 в начале пути и значение 90 в конце пути.

Path {
    startX: 0
    startY: 0
    PathAttribute { name: "itemRotation"; value: 0 }
    PathLine { x: 100; y: 100 }
    PathAttribute { name: "itemRotation"; value: 90 }
}

В нашем делегате мы затем можем связать свойство rotation с Присоединенным свойством PathView.itemRotation, созданным для этого атрибута.

Rectangle {
    width: 10; height: 10
    rotation: PathView.itemRotation
}

Поскольку каждый элемент позиционируется вдоль пути, он будет поворачиваться соответственно: элемент в начале пути не будет повернут, элемент в конце пути будет повернут на 90 градусов, а элемент посередине пути будет повернут на 45 градусов.