Группа кнопок QML

Исключительная группа управляющих элементов, которые можно выбирать. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• buttons : список<AbstractButton>
• current : AbstractButton

Прикреплённые свойства

• group : Группа кнопок

Методы

• void addButton(AbstractButton button)
• void removeButton(AbstractButton button)

Подробное описание

ButtonGroup — это невидимая взаимоисключающая группа кнопок. Она используется с такими элементами управления, как RadioButton, где только одно из вариантов может быть выбрано одновременно.

Самый простой способ использовать ButtonGroup — это назначить список кнопок. Например, список дочерних элементов позиционера или макета, управляющего группой взаимоисключающих кнопок.

ButtonGroup {
    buttons: column.children
}

Column {
    id: column

    RadioButton {
        checked: true
        text: qsTr("DAB")
    }

    RadioButton {
        text: qsTr("FM")
    }

    RadioButton {
        text: qsTr("AM")
    }
}

Взаимоисключающие кнопки не всегда разделяют один и тот же родительский элемент, или родительский макет иногда может содержать элементы, которые не должны включаться в группу кнопок. Такие случаи лучше всего обрабатывать с помощью прикреплённого свойства group.

ButtonGroup { id: radioGroup }

Column {
    Label {
        text: qsTr("Radio:")
    }

    RadioButton {
        checked: true
        text: qsTr("DAB")
        ButtonGroup.group: radioGroup
    }

    RadioButton {
        text: qsTr("FM")
        ButtonGroup.group: radioGroup
    }

    RadioButton {
        text: qsTr("AM")
        ButtonGroup.group: radioGroup
    }
}

Более сложные случаи использования можно обрабатывать с помощью методов addButton() и removeButton().

Примечание: Типы в модуле Qt.labs не гарантируют сохранение совместимости в будущих версиях.

См. также RadioButton.

Документация по свойствам

[default] buttons : список<AbstractButton>

Это свойство содержит список кнопок.

ButtonGroup {
    buttons: column.children
}

Column {
    id: column

    RadioButton {
        checked: true
        text: qsTr("Option A")
    }

    RadioButton {
        text: qsTr("Option B")
    }
}

См. также group.

current : AbstractButton

Это свойство содержит текущую выбранную кнопку или null , если таковой нет.

По умолчанию это первая отмеченная кнопка, добавленная в группу кнопок.

Документация по прикреплённым свойствам

ButtonGroup.group : ButtonGroup

Это свойство прикрепляет кнопку к группе кнопок.

ButtonGroup { id: group }

RadioButton {
    checked: true
    text: qsTr("Option A")
    ButtonGroup.group: group
}

RadioButton {
    text: qsTr("Option B")
    ButtonGroup.group: group
}

См. также buttons.

Документация по методам

void addButton(AbstractButton button)

Добавляет кнопку в группу кнопок.

Примечание: Ручная добавка объектов в группу кнопок обычно не требуется. Свойство buttons и прикреплённое свойство group обеспечивают удобный и декларативный синтаксис.

См. также buttons и group.

void removeButton(AbstractButton button)

Удаляет кнопку из группы кнопок.

Примечание: Ручное удаление объектов из группы кнопок обычно не требуется. Свойство buttons и прикреплённое свойство group обеспечивают удобный и декларативный синтаксис.

См. также buttons и group.