Тип QML AudioEngine

Организуйте все ваши 3D аудиоданные в одном месте. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• categories : карта
• dopplerFactor : вещественное число
• listener : QtAudioEngine::AudioListener
• liveInstances : целое число
• loading : логическое значение
• samples : карта
• sounds : карта
• speedOfSound : вещественное число

Сигналы

• finishedLoading()
• isLoadingChanged()
• liveInstanceCountChanged()
• ready()

Методы

• addAttenuationModel(AttenuationModel attenuationModel)
• addAudioCategory(AudioCategory category)
• addAudioSample(AudioSample sample)
• addSound(Sound sound)

Подробное описание

Rectangle {
    color:"white"
    width: 300
    height: 500

    AudioEngine {
        id:audioengine

        AudioSample {
            name:"explosion"
            source: "explosion-02.wav"
        }

        Sound {
            name:"explosion"
            PlayVariation {
                sample:"explosion"
            }
        }

        dopplerFactor: 1
        speedOfSound: 343.33 // Approximate speed of sound in air at 20 degrees Celsius

        listener.up:"0,0,1"
        listener.position:"0,0,0"
        listener.velocity:"0,0,0"
        listener.direction:"0,1,0"
    }

    MouseArea {
        anchors.fill: parent
        onPressed: {
            audioengine.sounds["explosion"].play();
        }
    }
}

AudioEngine служит центральной библиотекой для настройки всех 3D аудиоданных в приложении, поэтому вам следует определить только одну в вашем приложении.

В основном используется в качестве контейнера для доступа к другим типам, таким как AudioCategory, AudioSample и Sound.

См. также AudioCategory, AudioSample, Звук, SoundInstance, AttenuationModelLinear и AttenuationModelInverse.

Документация по свойствам

categories : карта

Контейнер всех экземпляров AudioCategory.

dopplerFactor : вещественное число

Это свойство содержит простое масштабирование для эффекта эффекта Доплера.

listener : QtAudioEngine::AudioListener

Это свойство содержит объект слушателя. Вы можете изменить различные свойства, чтобы повлиять на 3D позиционирование звуков.

См. также AudioListener.

liveInstances : целое число

Это свойство указывает, сколько активных экземпляров звука существует в данный момент.

loading : логическое значение

Это свойство указывает, загружает ли в данный момент аудио движок какую-либо аудиовыборку. Это может быть полезно, если вы указали свойство preloaded в AudioSample и хотели бы отобразить экран загрузки пользователю, прежде чем все аудиовыборки будут загружены.

/sa finishedLoading, AudioSample::preloaded

samples : карта

Контейнер всех экземпляров AudioSample.

sounds : карта

Контейнер всех экземпляров Sound.

speedOfSound : вещественное число

Это свойство содержит эталонное значение скорости звука (в метрах в секунду), которое будет использоваться в расчетах смещения Доплера. Расчет смещения Доплера используется для эмуляции изменения частоты звука, воспринимаемого наблюдателем, когда источник звука движется к наблюдателю или от него. Скорость звука зависит от среды, в которой распространяется звук.

Документация по сигналам

finishedLoading()

Этот сигнал излучается, когда завершается загрузка loading.

Соответствующий обработчик — onFinishedLoading.

isLoadingChanged()

Этот сигнал излучается, когда изменяется свойство loading.

Соответствующий обработчик — onIsLoadingChanged.

liveInstanceCountChanged()

Этот сигнал излучается, когда изменяется количество активных экземпляров, управляемых AudioEngine.

Соответствующий обработчик — onLiveInstanceCountChanged.

ready()

Этот сигнал излучается, когда AudioEngine готов к использованию.

Соответствующий обработчик — onReady.

Документация по методам

addAttenuationModel(AttenuationModel attenuationModel)

Добавляет заданный attenuationModel в движок. Это можно использовать, когда AttenuationModelLinear / AttenuationModelInverse создается динамически:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var attenuationModel = Qt.createQmlObject('import QtAudioEngine 1.1; AttenuationModelLinear {}', engine);
        attenuationModel.name ="linear"
        attenuationModel.start = 20
        attenuationModel.end = 180
        engine.addAttenuationModel(attenuationModel);
    }
}

addAudioCategory(AudioCategory category)

Добавляет заданный category в движок. Это можно использовать, когда AudioCategory создается динамически:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var category = Qt.createQmlObject('import QtAudioEngine 1.1; AudioCategory {}', engine);
        category.name = "sample";
        category.volume = 0.9;
        engine.addAudioCategory(category);
    }
}

addAudioSample(AudioSample sample)

Добавляет заданный sample в движок. Это можно использовать, когда AudioSample создается динамически:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var sample = Qt.createQmlObject('import QtAudioEngine 1.1; AudioSample {}', engine);
        sample.name = "example";
        sample.source = "example.wav";
        engine.addAudioSample(sample);
    }
}

addSound(Sound sound)

Добавляет заданный sound в движок. Это можно использовать, когда Sound создается динамически:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var sound = Qt.createQmlObject('import QtAudioEngine 1.1; Sound {}', engine);
        sound.name = "example";
        engine.addSound(sound);
    }
}