Тип компонента QML

Инкапсулирует определение компонента QML Подробнее...

• Список всех членов, включая унаследованные

Свойства

• progress : вещественное число
• status : перечисление
• url : url

Присоединённые сигналы

• completed()
• destruction()

Методы

• объект createObject(QtObject parent, объект properties)
• строка errorString()
• объект incubateObject(Item parent, объект properties, перечисление mode)

Подробное описание

Компоненты — это многократно используемые, инкапсулированные типы QML с хорошо определёнными интерфейсами.

Компоненты часто определяются файлами компонентов — это, то есть .qml файлы. Тип Component в основном позволяет определять компоненты QML непосредственно в QML-документе, а не как отдельный QML-файл. Это может быть полезно для повторного использования небольшого компонента в QML-файле или для определения компонента, логически относящегося к другим компонентам QML в файле.

Например, вот компонент, используемый несколькими объектами Loader. Он содержит один элемент, Rectangle:

import QtQuick 2.0

Item {
    width: 100; height: 100

    Component {
        id: redSquare

        Rectangle {
            color: "red"
            width: 10
            height: 10
        }
    }

    Loader { sourceComponent: redSquare }
    Loader { sourceComponent: redSquare; x: 20 }
}

Обратите внимание, что, хотя Rectangle сам по себе будет автоматически отрисовываться и отображаться, это не так для прямоугольника выше, так как он определён внутри Component. Компонент инкапсулирует типы QML внутри, как если бы они были определены в отдельном QML-файле, и загружается только по запросу (в данном случае, двумя объектами Loader). Поскольку Component не наследуется от Item, вы не можете к нему привязывать элементы.

Определение Component аналогично определению QML-документа. QML-документ имеет один верхний элемент, определяющий поведение и свойства этого компонента, и не может определять свойства или поведение вне этого верхнего элемента. Точно так же определение Component содержит один верхний элемент (который в примере выше является Rectangle) и не может определять какие-либо данные за пределами этого элемента, за исключением id (который в примере выше — redSquare).

Тип Component обычно используется для предоставления графических компонентов для представлений. Например, свойство ListView::delegate требует Component для указания того, как должен отображаться каждый элемент списка.

Component объекты также можно создавать динамически с помощью Qt.createComponent().

Контекст создания

Контекст создания компонента соответствует контексту, где компонент был объявлен. Этот контекст используется как родительский контекст (создание иерархии контекстов) при создании экземпляра компонента объектом, например, ListView или Loader.

В следующем примере comp1 создаётся в корневом контексте MyItem.qml, и любые объекты, созданные из этого компонента, будут иметь доступ к идентификаторам и свойствам в этом контексте, таким как internalSettings.color. Когда comp1 используется в качестве делегата ListView в другом контексте (как в main.qml ниже), он по-прежнему будет иметь доступ к свойствам своего контекста создания (которые в противном случае были бы закрыты для внешнего пользователя).

Item {
    property Component mycomponent: comp1

    QtObject {
        id: internalSettings
        property color color: "green"
    }

    Component {
        id: comp1
        Rectangle { color: internalSettings.color; width: 400; height: 50 }
    }
}

ListView {
    width: 400; height: 400
    model: 5
    delegate: myItem.mycomponent    //will create green Rectangles

    MyItem { id: myItem }
}

Документация по свойствам

progress : вещественное число

Прогресс загрузки компонента от 0,0 (ничего не загружено) до 1,0 (загрузка завершена).

status : перечисление

Это свойство содержит статус загрузки компонента. Статус может быть одним из следующих:

• Component.Null — данные для компонента недоступны
• Component.Ready — компонент загружен и может быть использован для создания экземпляров.
• Component.Loading — компонент в настоящее время загружается
• Component.Error — при загрузке компонента произошла ошибка. Вызов errorString() предоставит удобочитаемое описание любых ошибок.

url : url

URL компонента. Это URL, который использовался для создания компонента.

Документация по присоединённым сигналам

completed()

Вызывается после того, как объект был создан. Это можно использовать для выполнения кода скрипта при запуске, после установления полной QML-среды.

Соответствующий обработчик — onCompleted. Он может быть объявлен для любого объекта. Порядок выполнения onCompleted обработчиков не определён.

Rectangle {
    Component.onCompleted: console.log("Completed Running!")
    Rectangle {
        Component.onCompleted: console.log("Nested Completed Running!")
    }
}

destruction()

Вызывается при начале уничтожения объекта. Это можно использовать для отмены работ, выполненных в ответ на сигнал completed() или другого императивного кода в вашем приложении.

Соответствующий обработчик — onDestruction. Он может быть объявлен для любого объекта. Порядок выполнения onDestruction обработчиков не определён.

Rectangle {
    Component.onDestruction: console.log("Destruction Beginning!")
    Rectangle {
        Component.onDestruction: console.log("Nested Destruction Beginning!")
    }
}

См. также Qt QML.

Документация по методам

объект createObject(QtObject parent, объект properties)

Создаёт и возвращает экземпляр объекта этого компонента, который будет иметь заданного parent и properties. Аргумент properties необязателен. Возвращает null, если создание объекта завершилось неудачей.

Объект будет создан в том же контексте, что и компонент. Эта функция всегда вернёт null при вызове для компонентов, которые не были созданы в QML.

Если вы хотите создать объект без родителя, укажите null для значения parent. Обратите внимание, что если возвращаемый объект должен быть отображён, вы должны указать действительное значение parent или установить свойство родителя возвращаемого объекта parent, иначе объект не будет виден.

Если parent не предоставляется для createObject(), ссылка на возвращаемый объект должна храниться, чтобы он не уничтожался сборщиком мусора. Это верно независимо от того, установлено ли свойство Item::parent позже, так как изменение родителя Item не меняет владения объектом. Меняется только графический родитель.

Начиная с QtQuick 1.1, этот метод принимает необязательный аргумент properties, который определяет карту начальных значений свойств создаваемого объекта. Эти значения применяются до завершения создания объекта. Это более эффективно, чем установка значений свойств после создания объекта, особенно там, где определены большие наборы значений свойств, а также позволяет настроить привязки свойств (используя Qt.binding) до создания объекта.

Аргумент properties задаётся в виде карты элементов свойство-значение. Например, код ниже создаёт объект с начальными x и y значениями 100 и 100 соответственно:

var component = Qt.createComponent("Button.qml");
if (component.status == Component.Ready)
    component.createObject(parent, {"x": 100, "y": 100});

Динамически созданные экземпляры можно удалить с помощью destroy() метода. См. Динамическое создание объектов QML из JavaScript для получения дополнительной информации.

См. также incubateObject().

строка errorString()

Возвращает удобочитаемое описание любой ошибки.

Строка включает файл, расположение и описание каждой ошибки. Если присутствуют несколько ошибок, они разделяются символом новой строки.

Если ошибок нет, возвращается пустая строка.

объект incubateObject(Item parent, объект properties, перечисление mode)

Создаёт инкубатор для экземпляра этого компонента. Инкубаторы позволяют создавать новые экземпляры компонентов асинхронно и не вызывают зависания пользовательского интерфейса.

Аргумент parent определяет родителя создаваемого экземпляра. Пропуск параметра или передача null создаст объект без родителя. В этом случае ссылка на созданный объект должна храниться, чтобы он не уничтожался сборщиком мусора.

Аргумент properties задаётся как карта элементов свойство-значение, которые будут установлены на создаваемый объект во время его построения. mode может быть Qt.Synchronous или Qt.Asynchronous и управляет тем, создаётся ли экземпляр синхронно или асинхронно. По умолчанию — асинхронно. В некоторых случаях, даже если указан Qt.Synchronous, инкубатор может создать объект асинхронно. Это происходит, если компонент, вызывающий incubateObject(), сам создаётся асинхронно.

Все три аргумента необязательны.

В случае успеха метод возвращает инкубатор, в противном случае null. Инкубатор имеет следующие свойства:

• status Статус инкубатора. Допустимые значения: Component.Ready, Component.Loading и Component.Error.
• object Созданный экземпляр объекта. Будет доступен только после того, как инкубатор перейдет в состояние Ready.
• onStatusChanged Указывает функцию обратного вызова, которая вызывается при изменении статуса. Статус передается в качестве параметра в функцию обратного вызова.
• forceCompletion() Вызов для синхронного завершения инкубации.

Следующий пример демонстрирует использование инкубатора:

var component = Qt.createComponent("Button.qml");

var incubator = component.incubateObject(parent, { x: 10, y: 10 });
if (incubator.status != Component.Ready) {
    incubator.onStatusChanged = function(status) {
        if (status == Component.Ready) {
            print ("Object", incubator.object, "is now ready!");
        }
    }
} else {
    print ("Object", incubator.object, "is ready immediately!");
}

Динамически созданные экземпляры могут быть удалены с помощью метода destroy(). Подробнее см. Динамическое создание QML-объектов из JavaScript.

См. также createObject().