Тип QML Action

Action предоставляет абстрактное действие пользовательского интерфейса, которое может быть привязано к элементам Подробнее...

• Список всех членов, включая унаследованные члены

Свойства

• checkable : bool
• checked : bool
• enabled : bool
• exclusiveGroup : ExclusiveGroup
• iconName : строка
• iconSource : url
• shortcut : keysequence
• text : строка
• tooltip : строка

Сигналы

• toggled(checked)
• triggered(QObject *source)

Методы

• void trigger(QObject *source)

Подробное описание

Во многих приложениях многие общие команды могут вызываться через меню, кнопки на панели инструментов и сочетания клавиш. Поскольку пользователь ожидает, что каждая команда будет выполняться одинаково независимо от используемого пользовательского интерфейса, полезно представлять каждую команду как действие.

Действие можно привязать к элементу меню и кнопке на панели инструментов, и оно автоматически будет синхронизировать их. Например, в текстовом процессоре, если пользователь нажимает кнопку «Жирный» на панели инструментов, элемент меню «Жирный» автоматически будет помечен.

QtQuick Controls поддерживает действия в Button, ToolButton и MenuItem.

    ...
    Action {
        id: copyAction
        text: "&Copy"
        shortcut: StandardKey.Copy
        iconName: "edit-copy"
        enabled: (!!activeFocusItem && !!activeFocusItem["copy"])
        onTriggered: activeFocusItem.copy()
    }

    Action {
        id: cutAction
        text: "Cu&t"
        shortcut: StandardKey.Cut
        iconName: "edit-cut"
        enabled: (!!activeFocusItem && !!activeFocusItem["cut"])
        onTriggered: activeFocusItem.cut()
    }

    Action {
        id: pasteAction
        text: "&Paste"
        shortcut: StandardKey.Paste
        iconName: "edit-paste"
        enabled: (!!activeFocusItem && !!activeFocusItem["paste"])
        onTriggered: activeFocusItem.paste()
    }

    toolBar: ToolBar {
        RowLayout {
            anchors.fill: parent
            anchors.margins: spacing
            Label {
                text: UI.label
            }
            Item { Layout.fillWidth: true }
            CheckBox {
                id: enabler
                text: "Enabled"
                checked: true
            }
        }
    }

    menuBar: MenuBar {
        Menu {
            title: "&File"
            MenuItem {
                text: "E&xit"
                shortcut: StandardKey.Quit
                onTriggered: Qt.quit()
            }
        }
        Menu {
            title: "&Edit"
            visible: tabView.currentIndex == 2
            MenuItem { action: cutAction }
            MenuItem { action: copyAction }
            MenuItem { action: pasteAction }
        }
        Menu {
            title: "&Help"
            MenuItem {
                text: "About..."
                onTriggered: aboutDialog.open()
            }
        }
    }

    ...

Документация по свойствам

checkable : bool

Определяет, может ли элемент меню быть отмеченным или переключаться. По умолчанию false.

См. также checked и exclusiveGroup.

checked : bool

Если действие checkable, это свойство отражает его состояние выбора. По умолчанию false. Его значение также равно false, когда checkable равно false.

См. также toggled и exclusiveGroup.

enabled : bool

Определяет, разрешено ли действие и может ли оно быть вызвано. По умолчанию true.

См. также trigger() и triggered.

exclusiveGroup : ExclusiveGroup

Если действие можно отмечать, ему может быть прикреплена группа ExclusiveGroup. Все действия, использующие одну и ту же группу исключения, становятся взаимно исключительными, что означает, что только последнее отмеченное действие фактически будет отмечено.

По умолчанию null, что означает, что исключительного поведения ожидать не следует.

См. также checkable и checked.

iconName : строка

Устанавливает имя значка для действия. Это выберет значок с заданным именем из текущей темы.

По умолчанию пустая строка.

iconSource : url

Устанавливает URL-адрес файла или ресурса значка для действия. По умолчанию пустой URL.

shortcut : keysequence

Сочетание клавиш, привязанное к действию. Keysequence может быть строкой или стандартной клавишей.

По умолчанию пустая строка.

Action {
    id: copyAction
    text: qsTr("&Copy")
    shortcut: StandardKey.Copy
}

text : строка

Текст для действия. Этот текст отобразится как текст кнопки или как заголовок в элементе меню.

Мемоники поддерживаются путем добавления префикса & к букве сочетания клавиш. Например, "\&Open" привяжет сочетание клавиш Alt-O к элементу меню "Open". Обратите внимание, что не все платформы поддерживают мемоники.

По умолчанию пустая строка.

tooltip : строка

Подсказка, которая будет отображаться при наведении курсора на элемент управления, привязанный к этому действию. Не все элементы управления поддерживают всплывающие подсказки на всех платформах, особенно MenuItem.

По умолчанию пустая строка.

Документация по сигналам

toggled(checked)

Выдается всякий раз, когда свойство checked действия изменяется. Это обычно происходит одновременно с triggered.

Соответствующий обработчик onToggled.

triggered(QObject *source)

Выдается, когда элемент меню или связанное с ним действие были активированы. Включает объект, который инициировал событие, если это применимо (например, Button или MenuItem). Вам не нужно генерировать этот сигнал; используйте trigger() вместо этого.

Соответствующий обработчик onTriggered.

Документация по методам

void trigger(QObject *source)

Вызовет сигнал triggered, если действие включено. Вы можете указать объект-источник, если действие будет полезно для определения источника вызова (например, для аналитики). Также вызовет сигнал toggled, если оно может быть отмечено.