Тип QML State

Определяет конфигурации объектов и свойств Подробнее...

• Список всех членов, включая унаследованные

Свойства

• changes : список<Change>
• extend : строка
• name : строка
• when : логическое

Подробное описание

State — это набор объединённых изменений по умолчанию.

Все элементы имеют состояние по умолчанию, которое определяет стандартную конфигурацию объектов и значений свойств. Новые состояния могут быть определены путём добавления элементов State в свойство states, что позволяет элементам переключаться между различными конфигурациями. Эти конфигурации могут, например, использоваться для применения различных наборов значений свойств или выполнения различных скриптов.

Следующий пример отображает один прямоугольник. В состоянии по умолчанию прямоугольник окрашен в чёрный цвет. В состоянии «нажатие» объект PropertyChanges изменяет цвет прямоугольника на красный. Нажатие внутри области мыши переключает состояние прямоугольника между состоянием по умолчанию и состоянием «нажатие», тем самым переключая цвет прямоугольника между чёрным и красным.

import QtQuick 2.0

Rectangle {
    id: myRect
    width: 100; height: 100
    color: "black"

    MouseArea {
        id: mouseArea
        anchors.fill: parent
        onClicked: myRect.state == 'clicked' ? myRect.state = "" : myRect.state = 'clicked';
    }

    states: [
        State {
            name: "clicked"
            PropertyChanges { target: myRect; color: "red" }
        }
    ]
}

Обратите внимание, что состояние по умолчанию обозначается пустой строкой ("").

Состояния обычно используются вместе с переходами для обеспечения анимаций при изменении состояний.

Примечание: Установка состояния объекта изнутри другого состояния того же объекта не допускается.

См. также Пример состояний, Состояния Qt Quick, Переходы и Qt QML.

Документация по свойствам

[default] changes : список<Change>

Это свойство содержит изменения, которые необходимо применить для этого состояния.

По умолчанию эти изменения применяются к состоянию по умолчанию. Если состояние расширяет другое состояние, изменения применяются к расширяемому состоянию.

extend : строка

Это свойство содержит состояние, которое расширяет данное состояние.

Когда состояние расширяет другое состояние, оно наследует все изменения этого состояния.

Расширяемое состояние рассматривается как базовое состояние относительно изменений, указанных расширяющим состоянием.

name : строка

Это свойство содержит имя состояния.

Каждое состояние должно иметь уникальное имя в пределах своего элемента.

when : логическое

Это свойство определяет, когда должно быть применено состояние.

Это должно быть выражение, которое вычисляется как true когда вы хотите применить состояние. Например, следующий прямоугольник входит и выходит из состояния «скрытый», когда нажимается область мыши:

Rectangle {
    id: myRect
    width: 100; height: 100
    color: "red"

    MouseArea { id: mouseArea; anchors.fill: parent }

    states: State {
        name: "hidden"; when: mouseArea.pressed
        PropertyChanges { target: myRect; opacity: 0 }
    }
}

Если несколько состояний в группе имеют when условия, которые вычисляются как true одновременно, будет применено первое соответствующее состояние. Например, в следующем фрагменте state1 всегда будет выбрано вместо state2 когда sharedCondition становится true.

Item {
    states: [
        State { name: "state1"; when: sharedCondition },
        State { name: "state2"; when: sharedCondition }
    ]
    // ...
}