Плагин Qt Location Mapbox GL

Обзор

Этот плагин геосервисов позволяет приложениям получать доступ к сервисам картографии Mapbox с помощью API Qt Location. Использование этих сервисов регулируется условиями предоставления услуг Mapbox.

Этот плагин отличается от плагина Mapbox, так как он использует движок карты Mapbox GL для отрисовки растровых и векторных тайлов в реальном времени. Преимуществами являются: текст, отображаемый правильно, антиалиасинг шрифтов, плавное перемещение по уровням масштабирования, плавные панорамирование, наклонение, поворот и непрерывное масштабирование.

Внешний вид и поведение векторных карт можно настроить, создав пользовательские стили карты. Это можно сделать с помощью инструментов, таких как Mapbox Studio.

Плагин геосервисов Mapbox GL можно загрузить, используя ключ плагина "mapboxgl".

Оба плагина геосервисов Mapbox требуют токен доступа для доступа к стилям карты и тайлам, размещенным на серверах Mapbox. Чтобы создать учетную запись Mapbox, посетите https://www.mapbox.com/pricing.

Примечание: API этого плагина представлен в Qt 5.9 в качестве превью-технологии.

Поддержка платформ

Плагин Qt Location Mapbox GL поддерживает следующие платформы:

• Microsoft Windows (win32) - Поддерживается, требуется MinGW 5.0+
• Linux X11 - Поддерживается, требуется GCC 4.9+
• macOS - Поддерживается
• Android - Поддерживается
• Встроенный Linux - Поддерживается, требуется GCC 4.9+
• iOS - Поддерживается
• WinRT - Не поддерживается

Параметры

Дополнительные параметры плагина

В следующей таблице перечислены дополнительные параметры, которые можно передать плагину Mapbox.

Дополнительные параметры карты

Элемент Map, использующий этот плагин, также можно настроить, используя MapParameters, что позволяет изменять стиль и данные карты во время выполнения.

Примеры того, что в настоящее время можно контролировать с помощью MapParameter:

• Скрывать и показывать части карты, такие как дороги и здания.
• Изменять свойства рисования, такие как цвет и непрозрачность различных частей карты.
• Изменять свойства макета, такие как толщина и соединения линий.
• Добавлять данные на карту.
• Добавлять спрайты на карту.

За исключением свойств экструзии и стиля на основе данных, каждое свойство, описанное в Спецификации стиля Mapbox, можно изменить во время выполнения.

У MapParameters, используемых для управления стилем карты во время выполнения, всегда есть свойство type, за которым следуют пользовательские свойства, которые пытаются соответствовать наименованиям Спецификации стиля Mapbox настолько, насколько это возможно, заменяя дефисы на верблюжью нотацию для технических причин (например, line-cap будет переведено в lineCap).

Пример использования

В этом примере добавляются данные GeoJSON во встроенном виде на карту. Простого добавления source недостаточно для отображения данных. Также необходимо создать layer на основе этого источника. После добавления слоя, нам также нужно стилизовать его paint и layout свойства. В данном случае мы меняем цвет линии на синий, а ширину линии на 8 пикселей, а также устанавливаем круглые соединения и концы линий.

Map {
    plugin: Plugin { name: "mapboxgl" }

    center: QtPositioning.coordinate(60.170448, 24.942046) // Helsinki
    zoomLevel: 12

    MapParameter {
        type: "source"

        property var name: "routeSource"
        property var sourceType: "geojson"
        property var data: '{ "type": "FeatureCollection", "features": \
            [{ "type": "Feature", "properties": {}, "geometry": { \
            "type": "LineString", "coordinates": [[ 24.934938848018646, \
            60.16830257086771 ], [ 24.943315386772156, 60.16227776476442 ]]}}]}'
    }

    MapParameter {
        type: "layer"

        property var name: "route"
        property var layerType: "line"
        property var source: "routeSource"

        // Draw under the first road label layer
        // of the mapbox-streets style.
        property var before: "road-label-small"
    }

    MapParameter {
        type: "paint"

        property var layer: "route"
        property var lineColor: "blue"
        property var lineWidth: 8.0
    }

    MapParameter {
        type: "layout"

        property var layer: "route"
        property var lineJoin: "round"
        property var lineCap: "round"
    }
}

Обратите внимание, что порядок добавления параметров важен, так как между ними существует зависимость. Добавление слоя перед добавлением источника приведет к созданию некорректного слоя, то же самое относится к добавлению свойства paint для слоя, который еще не существует.

Свойства paint и layout также могут использоваться для стилизации существующих слоев текущего стиля, а не только слоев, созданных во время выполнения. Mapbox Studio можно использовать для проверки слоев данного стиля.