Тип QML AudioEngine

Организуйте весь ваш 3D аудиоконтент в одном месте. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• categories : карта
• dopplerFactor : вещественное число
• listener : QtAudioEngine::AudioListener
• liveInstances : целое число
• loading : логическое значение
• samples : карта
• sounds : карта
• speedOfSound : вещественное число

Сигналы

• finishedLoading()
• isLoadingChanged()
• liveInstanceCountChanged()
• ready()

Методы

• addAttenuationModel(AttenuationModel attenuationModel)
• addAudioCategory(AudioCategory category)
• addAudioSample(AudioSample sample)
• addSound(Sound sound)

Подробное описание

Rectangle {
    color:"white"
    width: 300
    height: 500

    AudioEngine {
        id:audioengine

        AudioSample {
            name:"explosion"
            source: "explosion-02.wav"
        }

        Sound {
            name:"explosion"
            PlayVariation {
                sample:"explosion"
            }
        }

        dopplerFactor: 1
        speedOfSound: 343.33 // Approximate speed of sound in air at 20 degrees Celsius

        listener.up:"0,0,1"
        listener.position:"0,0,0"
        listener.velocity:"0,0,0"
        listener.direction:"0,1,0"
    }

    MouseArea {
        anchors.fill: parent
        onPressed: {
            audioengine.sounds["explosion"].play();
        }
    }
}

AudioEngine выступает в качестве центральной библиотеки для настройки всего 3D аудиоконтента в приложении, поэтому вам следует определить только один в вашем приложении.

В основном используется как контейнер для доступа к другим типам, таким как AudioCategory, AudioSample и Sound.

См. также AudioCategory, AudioSample, Sound, SoundInstance, AttenuationModelLinear и AttenuationModelInverse.

Документация по свойствам

categories : карта

Контейнер всех экземпляров AudioCategory.

dopplerFactor : вещественное число

Это свойство содержит простое масштабирование для эффекта смещения Доплера.

listener : QtAudioEngine::AudioListener

Это свойство содержит объект прослушивателя. Вы можете изменить различные свойства, чтобы повлиять на 3D позиционирование звуков.

См. также AudioListener.

liveInstances : целое число

Это свойство указывает, сколько активных экземпляров звука существует в данный момент.

loading : логическое значение

Это свойство указывает, загружает ли аудио движок какой-либо аудиообразец в данный момент. Это может быть полезно, если вы указали свойство preloaded в AudioSample и хотите отобразить экран загрузки пользователю перед загрузкой всех аудиообразцов.

/sa finishedLoading, AudioSample::preloaded

samples : карта

Контейнер всех экземпляров AudioSample.

sounds : карта

Контейнер всех экземпляров звука.

speedOfSound : вещественное число

Это свойство содержит эталонное значение скорости звука (в метрах в секунду), которое будет использоваться в расчетах смещения Доплера. Вычисление смещения Доплера используется для моделирования изменения частоты звука, воспринимаемой наблюдателем, когда источник звука движется к наблюдателю или от него. Скорость звука зависит от среды, в которой распространяется звук.

Документация по сигналам

finishedLoading()

Этот сигнал испускается, когда завершается загрузка по loading.

Соответствующий обработчик — onFinishedLoading.

isLoadingChanged()

Этот сигнал испускается, когда изменяется свойство loading.

Соответствующий обработчик — onIsLoadingChanged.

liveInstanceCountChanged()

Этот сигнал испускается, когда изменяется количество активных экземпляров, управляемых AudioEngine.

Соответствующий обработчик — onLiveInstanceCountChanged.

ready()

Этот сигнал испускается, когда AudioEngine готов к использованию.

Соответствующий обработчик — onReady.

Документация по методам

addAttenuationModel(AttenuationModel attenuationModel)

Добавляет данный attenuationModel в движок. Это можно использовать при динамическом создании AttenuationModelLinear / AttenuationModelInverse:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var attenuationModel = Qt.createQmlObject('import QtAudioEngine 1.1; AttenuationModelLinear {}', engine);
        attenuationModel.name ="linear"
        attenuationModel.start = 20
        attenuationModel.end = 180
        engine.addAttenuationModel(attenuationModel);
    }
}

addAudioCategory(AudioCategory category)

Добавляет данный category в движок. Это можно использовать при динамическом создании AudioCategory:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var category = Qt.createQmlObject('import QtAudioEngine 1.1; AudioCategory {}', engine);
        category.name = "sample";
        category.volume = 0.9;
        engine.addAudioCategory(category);
    }
}

addAudioSample(AudioSample sample)

Добавляет данный sample в движок. Это можно использовать при динамическом создании AudioSample:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var sample = Qt.createQmlObject('import QtAudioEngine 1.1; AudioSample {}', engine);
        sample.name = "example";
        sample.source = "example.wav";
        engine.addAudioSample(sample);
    }
}

addSound(Sound sound)

Добавляет данный sound в движок. Это можно использовать при динамическом создании Sound:

import QtAudioEngine 1.1

AudioEngine {
    id: engine

    Component.onCompleted: {
        var sound = Qt.createQmlObject('import QtAudioEngine 1.1; Sound {}', engine);
        sound.name = "example";
        engine.addSound(sound);
    }
}