Тип QML ThresholdMask

Маскирует элемент-источник другим элементом и применяет значение порога. Подробнее...

• Список всех членов, включая унаследованные

Свойства

• cached : bool
• maskSource : variant
• source : variant
• spread : real
• threshold : real

Подробное описание

Поведение маскирования можно контролировать с помощью значения threshold для пикселей маски.

Примечание: Этот эффект доступен при работе с OpenGL.

Пример

Следующий пример демонстрирует применение эффекта.

import QtQuick 2.0
import QtGraphicalEffects 1.0

Item {
    width: 300
    height: 300

    Image {
        id: background
        anchors.fill: parent
        source: "images/checker.png"
        smooth: true
        fillMode: Image.Tile
    }

    Image {
        id: bug
        source: "images/bug.jpg"
        sourceSize: Qt.size(parent.width, parent.height)
        smooth: true
        visible: false
    }

    Image {
        id: mask
        source: "images/fog.png"
        sourceSize: Qt.size(parent.width, parent.height)
        smooth: true
        visible: false
    }

    ThresholdMask {
        anchors.fill: bug
        source: bug
        maskSource: mask
        threshold: 0.4
        spread: 0.2
    }
}

Документация по свойствам

cached : bool

Это свойство позволяет кэшировать пиксели выходного эффекта для повышения производительности рендеринга.

Каждый раз при изменении свойств source или effect пиксели в кэше должны быть обновлены. Потребление памяти увеличивается, так как требуется дополнительный буфер памяти для хранения выходных данных эффекта.

Рекомендуется отключить кэширование, когда свойства source или effect анимированы.

По умолчанию свойство установлено в false.

maskSource : variant

Это свойство определяет элемент, который будет использоваться в качестве маски. Элемент маски рендерится в промежуточный буфер пикселей, и значения альфа из результата используются для определения видимости пикселей элемента-источника на дисплее.

Примечание: Не допускается использование эффекта внутри самого себя, например, установкой maskSource на родительский элемент эффекта.

source : variant

Это свойство определяет элемент-источник, который будет замаскирован.

Примечание: Не допускается использование эффекта внутри самого себя, например, установкой source на родительский элемент эффекта.

spread : real

Это свойство определяет плавность краев маски вблизи значения альфа порога threshold. Установка spread в 0.0 использует маску стандартным образом с указанным порогом. Установка более высоких значений spread смягчает переход от прозрачных пикселей маски к непрозрачным, добавляя интерполированные значения между ними.

Значение изменяется от 0.0 (резкий край маски) до 1.0 (плавный край маски). По умолчанию свойство установлено в 0.0.

threshold : real

Это свойство определяет значение порога для пикселей маски. Пиксели маски с значением альфа ниже этого свойства используются для полного маскирования соответствующих пикселей из элемента-источника. Пиксели маски с более высоким значением альфа используются для смешивания по альфа-каналу элемента-источника с дисплеем.

Значение изменяется от 0.0 (значение альфа 0) до 1.0 (значение альфа 255). По умолчанию свойство установлено в 0.0.