Тип QML Action

Action предоставляет абстрактное действие пользовательского интерфейса, которое может быть привязано к элементам Подробнее...

• Список всех членов, включая унаследованные

Свойства

• checkable : bool
• checked : bool
• enabled : bool
• exclusiveGroup : ExclusiveGroup
• iconName : строка
• iconSource : url
• shortcut : keysequence
• text : строка
• tooltip : строка

Сигналы

• toggled(checked)
• triggered(QObject *source)

Методы

• void trigger(QObject *source)

Подробное описание

Во многих приложениях многие распространенные команды могут вызываться через меню, кнопки панели инструментов и сочетания клавиш. Поскольку пользователь ожидает, что каждая команда будет выполняться одинаково, независимо от используемого пользовательского интерфейса, полезно представлять каждую команду как действие.

Действие может быть привязано к пункту меню и кнопке панели инструментов, и оно автоматически будет их синхронизировать. Например, в текстовом редакторе, если пользователь нажмет кнопку «Полужирный» на панели инструментов, пункт меню «Полужирный» автоматически будет отмечен.

QtQuick Controls поддерживает действия в Button, ToolButton и MenuItem.

    ...
    Action {
        id: copyAction
        text: "&Copy"
        shortcut: StandardKey.Copy
        iconName: "edit-copy"
        enabled: (!!activeFocusItem && !!activeFocusItem["copy"])
        onTriggered: activeFocusItem.copy()
    }

    Action {
        id: cutAction
        text: "Cu&t"
        shortcut: StandardKey.Cut
        iconName: "edit-cut"
        enabled: (!!activeFocusItem && !!activeFocusItem["cut"])
        onTriggered: activeFocusItem.cut()
    }

    Action {
        id: pasteAction
        text: "&Paste"
        shortcut: StandardKey.Paste
        iconName: "edit-paste"
        enabled: (!!activeFocusItem && !!activeFocusItem["paste"])
        onTriggered: activeFocusItem.paste()
    }

    toolBar: ToolBar {
        RowLayout {
            anchors.fill: parent
            anchors.margins: spacing
            Label {
                text: UI.label
            }
            Item { Layout.fillWidth: true }
            CheckBox {
                id: enabler
                text: "Enabled"
                checked: true
            }
        }
    }

    menuBar: MenuBar {
        Menu {
            title: "&File"
            MenuItem {
                text: "E&xit"
                shortcut: StandardKey.Quit
                onTriggered: Qt.quit()
            }
        }
        Menu {
            title: "&Edit"
            visible: tabView.currentIndex == 2
            MenuItem { action: cutAction }
            MenuItem { action: copyAction }
            MenuItem { action: pasteAction }
        }
        Menu {
            title: "&Help"
            MenuItem {
                text: "About..."
                onTriggered: aboutDialog.open()
            }
        }
    }

    ...

Документация по свойствам

checkable : bool

Определяет, можно ли отметить или переключить элемент меню. По умолчанию false.

См. также checked и exclusiveGroup.

checked : bool

Если действие checkable, данное свойство отражает его состояние выбора. По умолчанию false. Его значение также равно false, если checkable равно false.

См. также toggled и exclusiveGroup.

enabled : bool

Определяет, активен ли элемент действия и может ли он быть инициирован. По умолчанию true.

См. также trigger() и triggered.

exclusiveGroup : ExclusiveGroup

Если действие может быть выбрано, к нему можно прикрепить ExclusiveGroup. Все действия, использующие одну и ту же группу исключений, становятся взаимоисключающими по выбору, что означает, что только последнее отмеченное действие фактически будет отмечено.

По умолчанию null, что означает, что исключительного поведения ожидать не стоит.

См. также checkable и checked.

iconName : строка

Устанавливает имя значка для действия. Это выберет значок с заданным именем из текущей темы.

По умолчанию пустая строка.

Примечание: Для этого свойства требуется QApplication.

iconSource : url

Устанавливает URL-адрес файла значка или ресурса для действия. По умолчанию пустая URL-адрес.

shortcut : keysequence

Сочетание клавиш, привязанное к действию. Сочетание клавиш может быть строкой или стандартной клавишей.

По умолчанию пустая строка.

Action {
    id: copyAction
    text: qsTr("&Copy")
    shortcut: StandardKey.Copy
}

text : строка

Текст для действия. Этот текст будет отображаться как текст кнопки или как заголовок в пункте меню.

Мемоники поддерживаются путем добавления префикса & к букве сочетания клавиш. Например, "\&Open" привяжет сочетание клавиш Alt-O к пункту меню "Open". Обратите внимание, что не все платформы поддерживают мемоники.

По умолчанию пустая строка.

tooltip : строка

Подсказка, которая будет отображаться при наведении указателя мыши на элемент управления, привязанный к этому действию. Не все элементы управления поддерживают подсказки на всех платформах, особенно MenuItem.

По умолчанию пустая строка.

Документация по сигналам

toggled(checked)

Выдается всякий раз, когда свойство checked действия изменяется. Это обычно происходит одновременно с triggered.

Соответствующий обработчик — onToggled.

triggered(QObject *source)

Выдается, когда пункт меню или связанное с ним действие активизированы. Включает объект, который инициировал событие, если это необходимо (например, Button или MenuItem). Вам не нужно посылать этот сигнал, используйте trigger() вместо этого.

Соответствующий обработчик — onTriggered.

Документация по методам

void trigger(QObject *source)

Вызовет сигнал triggered, если действие активно. Вы можете указать объект источника, если действие будет полезно знать источник запуска (например, для аналитики). Также вызовет сигнал toggled, если оно может быть выбрано.