Тип QML CalendarStyle

Обеспечивает настраиваемую стилизацию для Календаря Подробнее...

Заявление об импорте:	import QtQuick.Controls.Styles 1.4
С момента:	Qt 5.3

Список всех членов, включая унаследованные

Свойства

background : Компонент
control : Календарь
dayDelegate : Компонент
dayOfWeekDelegate : Компонент
gridColor : цвет
gridVisible : bool
navigationBar : Компонент
weekNumberDelegate : Компонент

Подробное описание

Карта компонентов

В календаре есть следующие стилизуемые компоненты:

	background	Заполняет весь элемент управления.
	navigationBar
	dayOfWeekDelegate	Один экземпляр на каждый день недели.
	weekNumberDelegate	Один экземпляр на каждую неделю.
	dayDelegate	Один экземпляр на каждый день месяца.

Пример пользовательской стилизации

Calendar {
    anchors.centerIn: parent

    style: CalendarStyle {
        gridVisible: false
        dayDelegate: Rectangle {
            gradient: Gradient {
                GradientStop {
                    position: 0.00
                    color: styleData.selected ? "#111" : (styleData.visibleMonth && styleData.valid ? "#444" : "#666");
                }
                GradientStop {
                    position: 1.00
                    color: styleData.selected ? "#444" : (styleData.visibleMonth && styleData.valid ? "#111" : "#666");
                }
                GradientStop {
                    position: 1.00
                    color: styleData.selected ? "#777" : (styleData.visibleMonth && styleData.valid ? "#111" : "#666");
                }
            }

            Label {
                text: styleData.date.getDate()
                anchors.centerIn: parent
                color: styleData.valid ? "white" : "grey"
            }

            Rectangle {
                width: parent.width
                height: 1
                color: "#555"
                anchors.bottom: parent.bottom
            }

            Rectangle {
                width: 1
                height: parent.height
                color: "#555"
                anchors.right: parent.right
            }
        }
    }
}

Документация по свойствам

background : Component

Фон календаря.

Неявный размер календаря рассчитывается на основе неявного размера делегата фона.

[только для чтения] control : Calendar

Календарь, к которому прикреплен этот стиль.

dayDelegate : Component

Делегат, который стилизует каждую дату в календаре.

Свойства, предоставляемые каждому делегату:

readonly property date styleData.date	Дата, которую представляет этот делегат.
readonly property bool styleData.selected	`true` если это выбранная дата.
readonly property int styleData.index	Индекс этого делегата.
readonly property bool styleData.valid	`true` если эта дата больше или равна minimumDate и меньше или равна maximumDate.
readonly property bool styleData.today	`true` если эта дата совпадает с сегодняшней датой.
readonly property bool styleData.visibleMonth	`true` если месяц в этой дате — видимый месяц.
readonly property bool styleData.hovered	`true` если курсор находится над этой ячейкой. Примечание: Это свойство `true` даже при наведении курсора мыши на недействительную дату.
readonly property bool styleData.pressed	`true` если на эту ячейку нажата кнопка мыши. Примечание: Это свойство `true` даже при нажатии кнопки мыши на недействительную дату.

dayOfWeekDelegate : Component

Делегат, который стилизует каждый день недели.

Высота строки дней недели рассчитывается на основе максимальной неявной высоты делегатов.

Свойства, предоставляемые каждому делегату:

readonly property int styleData.index	Индекс (0-6) делегата.
readonly property int styleData.dayOfWeek	День недели, который представляет этот делегат. Возможные значения: `Locale.Sunday` `Locale.Monday` `Locale.Tuesday` `Locale.Wednesday` `Locale.Thursday` `Locale.Friday` `Locale.Saturday`

gridColor : цвет

Цвет линий сетки.

gridVisible : bool

Это свойство определяет видимость сетки.

Значение по умолчанию — true.

navigationBar : Component

Панель навигации календаря.

Стилизует панель в верхней части календаря, содержащую кнопки «следующий месяц»/«предыдущий месяц» и метку выбранной даты.

Свойства, предоставляемые делегату:

readonly property string styleData.title

Заголовок календаря.

weekNumberDelegate : Component

Делегат, который стилизует каждый номер недели.

Ширина столбца номера недели рассчитывается на основе максимальной неявной ширины делегатов.

Свойства, предоставляемые каждому делегату:

readonly property int styleData.index	Индекс (0-5) делегата.
readonly property int styleData.weekNumber	Номер недели, которую представляет этот делегат.

© The Qt Company Ltd
Licensed under the GNU Free Documentation License, Version 1.3.
https://doc.qt.io/qt-5.9/qml-qtquick-controls-styles-calendarstyle.html